libexec/rtld-elf/i386/rtld_start.S

   1 /*-
   2  * Copyright 1996-1998 John D. Polstra.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  15  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  16  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  17  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  18  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  19  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  20  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  21  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  22  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  23  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24  *
  25  * $FreeBSD$
  26  */
  27
  28         .text
  29         .align  4
  30         .globl  resident_start
  31         .globl  .rtld_start
  32         .type   .rtld_start,@function
  33 resident_start:
  34 .rtld_start:
  35         xorl    %ebp,%ebp               # Clear frame pointer for good form
  36         movl    %esp,%eax               # Save initial stack pointer
  37         subl    $8,%esp                 # A place to store exit procedure addr
  38         movl    %esp,%ebx               # save address of exit proc
  39         movl    %esp,%ecx               # construct address of obj_main
  40         addl    $4,%ecx
  41         pushl   %ecx                    # Pass address of obj_main
  42         pushl   %ebx                    # Pass address of exit proc
  43         pushl   %eax                    # Pass initial stack pointer to rtld
  44         call    _rtld@PLT               # Call rtld(sp); returns entry point
  45         addl    $12,%esp                # Remove arguments from stack
  46         popl    %edx                    # Get exit procedure address
  47         addl    $4,%esp                 # Ignore obj_main
  48 /*
  49  * At this point, %eax contains the entry point of the main program, and
  50  * %edx contains a pointer to a termination function that should be
  51  * registered with atexit().  (crt1.o registers it.)
  52  */
  53 .globl .rtld_goto_main
  54 .rtld_goto_main:        # This symbol exists just to make debugging easier.
  55         jmp     *%eax                   # Enter main program
  56
  57
  58 /*
  59  * Binder entry point.  Control is transferred to here by code in the PLT.
  60  * On entry, there are two arguments on the stack.  In ascending address
  61  * order, they are (1) "obj", a pointer to the calling object's Obj_Entry,
  62  * and (2) "reloff", the byte offset of the appropriate relocation entry
  63  * in the PLT relocation table.
  64  *
  65  * We are careful to preserve all registers, even the caller-save
  66  * registers.  That is because this code may be invoked by low-level
  67  * assembly-language code that is not ABI-compliant.
  68  */
  69         .align  4
  70         .globl  _rtld_bind_start
  71         .type   _rtld_bind_start,@function
  72 _rtld_bind_start:
  73         pushf                           # Save eflags
  74         pushl   %eax                    # Save %eax
  75         pushl   %edx                    # Save %edx
  76         pushl   %ecx                    # Save %ecx
  77         leal    24(%esp),%eax           # Calculate original stack addr
  78         pushl   %eax                    # Pass stack addr as 3. arg
  79         pushl   24(%esp)                # Copy reloff argument
  80         pushl   24(%esp)                # Copy obj argument
  81
  82         call    _rtld_bind@PLT          # Transfer control to the binder
  83         /* Now %eax contains the entry point of the function being called. */
  84
  85         addl    $12,%esp                # Discard binder arguments
  86         movl    %eax,20(%esp)           # Store target over obj argument
  87         popl    %ecx                    # Restore %ecx
  88         popl    %edx                    # Restore %edx
  89         popl    %eax                    # Restore %eax
  90         popf                            # Restore eflags
  91         leal    4(%esp),%esp            # Discard reloff, do not change eflags
  92         ret                             # "Return" to target address
  93
  94         .section .note.GNU-stack,"",%progbits