contrib/binutils-2.25/ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2014 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "sysdep.h"
  26 #include "bfd.h"
  27 #include "safe-ctype.h"
  28 #include "bfdlink.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.
  44    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  45 unsigned int lineno = 1;
  46
  47 /* The string we are currently lexing, or NULL if we are reading a
  48    file.  */
  49 const char *lex_string = NULL;
  50
  51 /* Support for flex reading from more than one input file (stream).
  52    `include_stack' is flex's input state for each open file;
  53    `file_name_stack' is the file names.  `lineno_stack' is the current
  54    line numbers.
  55
  56    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  57    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  58
  59 #undef YY_INPUT
  60 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  61
  62 #ifndef YY_NO_UNPUT
  63 #define YY_NO_UNPUT
  64 #endif
  65
  66 #define MAX_INCLUDE_DEPTH 10
  67 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  68 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  71 static unsigned int include_stack_ptr = 0;
  72 static int vers_node_nesting = 0;
  73
  74 static int yy_input (char *, int);
  75 static void comment (void);
  76 static void lex_warn_invalid (char *where, char *what);
  77
  78 /* STATES
  79         EXPRESSION      definitely in an expression
  80         SCRIPT          definitely in a script
  81         INPUTLIST       definitely in a script, a filename-list
  82         BOTH            either EXPRESSION or SCRIPT
  83         DEFSYMEXP       in an argument to -defsym
  84         MRI             in an MRI script
  85         VERS_START      starting a Sun style mapfile
  86         VERS_SCRIPT     a Sun style mapfile
  87         VERS_NODE       a node within a Sun style mapfile
  88 */
  89 #define RTOKEN(x)  {  yylval.token = x; return x; }
  90
  91 /* Some versions of flex want this.  */
  92 #ifndef yywrap
  93 int yywrap (void) { return 1; }
  94 #endif
  95 %}
  96
  97 %a 4000
  98 %o 5000
  99
 100 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 101 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 102 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 103 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 104 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 105 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 106 WHITE           [ \t\n\r]+
 107
 108 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 109
 110 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 111 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 112
 113 %s SCRIPT
 114 %s INPUTLIST
 115 %s EXPRESSION
 116 %s BOTH
 117 %s DEFSYMEXP
 118 %s MRI
 119 %s VERS_START
 120 %s VERS_SCRIPT
 121 %s VERS_NODE
 122 %%
 123
 124   if (parser_input != input_selected)
 125     {
 126       /* The first token of the input determines the initial parser state.  */
 127       input_type t = parser_input;
 128       parser_input = input_selected;
 129       switch (t)
 130         {
 131         case input_script: return INPUT_SCRIPT; break;
 132         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 133         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 134         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 135         case input_defsym: return INPUT_DEFSYM; break;
 136         default: abort ();
 137         }
 138     }
 139
 140 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 141
 142
 143 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 144 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 145 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 146 <DEFSYMEXP>"="                  { RTOKEN('='); }
 147
 148 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 149                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 150                                 yylval.bigint.str = NULL;
 151                                 return INT;
 152                         }
 153
 154 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 155                                    int ibase ;
 156                                    switch (yytext[yyleng - 1]) {
 157                                     case 'X':
 158                                     case 'x':
 159                                     case 'H':
 160                                     case 'h':
 161                                      ibase = 16;
 162                                      break;
 163                                     case 'O':
 164                                     case 'o':
 165                                      ibase = 8;
 166                                      break;
 167                                     case 'B':
 168                                     case 'b':
 169                                      ibase = 2;
 170                                      break;
 171                                     default:
 172                                      ibase = 10;
 173                                    }
 174                                    yylval.integer = bfd_scan_vma (yytext, 0,
 175                                                                   ibase);
 176                                    yylval.bigint.str = NULL;
 177                                    return INT;
 178                                  }
 179 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 180                                   char *s = yytext;
 181                                   int ibase = 0;
 182
 183                                   if (*s == '$')
 184                                     {
 185                                       ++s;
 186                                       ibase = 16;
 187                                     }
 188                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 189                                   yylval.bigint.str = NULL;
 190                                   if (yytext[yyleng - 1] == 'M'
 191                                       || yytext[yyleng - 1] == 'm')
 192                                     {
 193                                       yylval.integer *= 1024 * 1024;
 194                                     }
 195                                   else if (yytext[yyleng - 1] == 'K'
 196                                       || yytext[yyleng - 1]=='k')
 197                                     {
 198                                       yylval.integer *= 1024;
 199                                     }
 200                                   else if (yytext[0] == '0'
 201                                            && (yytext[1] == 'x'
 202                                                || yytext[1] == 'X'))
 203                                     {
 204                                       yylval.bigint.str = xstrdup (yytext + 2);
 205                                     }
 206                                   return INT;
 207                                 }
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 242 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 243 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 244 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 245 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 246 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 247 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 248 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 249 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 250 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 251 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 252 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 253 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 254 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 256 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 257 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 258 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 259 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 260 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 261 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 262 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 263 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 264 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 265 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 266 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 267 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 268 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 270 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 271 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 272 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 273 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 274 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 275 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 276 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 277 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 278 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 279 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 280 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 281 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 282 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 283 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 284 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 285 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 286 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 287 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 288 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 289 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 290 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 291 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 292 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 293 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 294 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 295 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 296 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 297 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 298 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 299 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 300 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 301 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 302 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 303 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 304 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 305 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 306 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 307 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 308 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 309 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 310 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 311 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 312 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 313 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 314 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 315 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 316 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 317 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 318 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 319 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 320 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 321 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 322 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 323 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 324 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 325 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 326 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 327 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 328 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 329 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 330 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 331 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 332 <MRI>"#".*\n?                   { ++ lineno; }
 333 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 334 <MRI>"*".*                      { /* Mri comment line */ }
 335 <MRI>";".*                      { /* Mri comment line */ }
 336 <MRI>"END"                      { RTOKEN(ENDWORD); }
 337 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 338 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 339 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 340 <MRI>"BASE"                     { RTOKEN(BASE); }
 341 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 342 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 343 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 344 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 345 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 346 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 347 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 348 <MRI>"CASE"                     { RTOKEN(CASE); }
 349 <MRI>"START"                    { RTOKEN(START); }
 350 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 351 <MRI>"SECT"                     { RTOKEN(SECT); }
 352 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 353 <MRI>"end"                      { RTOKEN(ENDWORD); }
 354 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 355 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 356 <MRI>"chip"                     { RTOKEN(CHIP); }
 357 <MRI>"base"                     { RTOKEN(BASE); }
 358 <MRI>"alias"                    { RTOKEN(ALIAS); }
 359 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 360 <MRI>"load"                     { RTOKEN(LOAD); }
 361 <MRI>"public"                   { RTOKEN(PUBLIC); }
 362 <MRI>"order"                    { RTOKEN(ORDER); }
 363 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 364 <MRI>"format"                   { RTOKEN(FORMAT); }
 365 <MRI>"case"                     { RTOKEN(CASE); }
 366 <MRI>"extern"                   { RTOKEN(EXTERN); }
 367 <MRI>"start"                    { RTOKEN(START); }
 368 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 369 <MRI>"sect"                     { RTOKEN(SECT); }
 370 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 371
 372 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 373 /* Filename without commas, needed to parse mri stuff */
 374                                  yylval.name = xstrdup (yytext);
 375                                   return NAME;
 376                                 }
 377
 378
 379 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 380                                  yylval.name = xstrdup (yytext);
 381                                   return NAME;
 382                                 }
 383 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 384 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 385                                  yylval.name = xstrdup (yytext);
 386                                   return NAME;
 387                                 }
 388 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 389                                   yylval.name = xstrdup (yytext + 2);
 390                                   return LNAME;
 391                                 }
 392 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 393                                  yylval.name = xstrdup (yytext);
 394                                   return NAME;
 395                                 }
 396 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 397                                   yylval.name = xstrdup (yytext + 2);
 398                                   return LNAME;
 399                                 }
 400 <SCRIPT>{WILDCHAR}* {
 401                 /* Annoyingly, this pattern can match comments, and we have
 402                    longest match issues to consider.  So if the first two
 403                    characters are a comment opening, put the input back and
 404                    try again.  */
 405                 if (yytext[0] == '/' && yytext[1] == '*')
 406                   {
 407                     yyless (2);
 408                     comment ();
 409                   }
 410                 else
 411                   {
 412                     yylval.name = xstrdup (yytext);
 413                     return NAME;
 414                   }
 415         }
 416
 417 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 418                                         /* No matter the state, quotes
 419                                            give what's inside */
 420                                         yylval.name = xstrdup (yytext + 1);
 421                                         yylval.name[yyleng - 2] = 0;
 422                                         return NAME;
 423                                 }
 424 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 425 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 426
 427 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 428
 429 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 430
 431 <VERS_NODE>local                { RTOKEN(LOCAL); }
 432
 433 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 434
 435 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 436                                   return VERS_IDENTIFIER; }
 437
 438 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 439                                   return VERS_TAG; }
 440
 441 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 442
 443 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 444                                   vers_node_nesting = 0;
 445                                   return *yytext;
 446                                 }
 447 <VERS_SCRIPT>"}"                { return *yytext; }
 448 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 449 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 450                                     BEGIN(VERS_SCRIPT);
 451                                   return *yytext;
 452                                 }
 453
 454 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 455
 456 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 457
 458 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 459
 460 <<EOF>> {
 461   include_stack_ptr--;
 462   if (include_stack_ptr == 0)
 463     yyterminate ();
 464   else
 465     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 466
 467   lineno = lineno_stack[include_stack_ptr];
 468   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 469
 470   return END;
 471 }
 472
 473 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 474 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 475
 476 %%
 477 \f
 478
 479 /* Switch flex to reading script file NAME, open on FILE,
 480    saving the current input info on the include stack.  */
 481
 482 void
 483 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 484 {
 485   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 486     {
 487       einfo ("%F:includes nested too deeply\n");
 488     }
 489   file_name_stack[include_stack_ptr] = name;
 490   lineno_stack[include_stack_ptr] = lineno;
 491   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 492   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 493
 494   include_stack_ptr++;
 495   lineno = 1;
 496   input_flags.sysrooted = sysrooted;
 497   yyin = file;
 498   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 499 }
 500
 501 /* Return a newly created flex input buffer containing STRING,
 502    which is SIZE bytes long.  */
 503
 504 static YY_BUFFER_STATE
 505 yy_create_string_buffer (const char *string, size_t size)
 506 {
 507   YY_BUFFER_STATE b;
 508
 509   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 510   b = malloc (sizeof (struct yy_buffer_state));
 511   b->yy_input_file = 0;
 512   b->yy_buf_size = size;
 513
 514   /* yy_ch_buf has to be 2 characters longer than the size given because
 515      we need to put in 2 end-of-buffer characters.  */
 516   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 517
 518   b->yy_ch_buf[0] = '\n';
 519   strcpy (b->yy_ch_buf+1, string);
 520   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 521   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 522   b->yy_n_chars = size+1;
 523   b->yy_buf_pos = &b->yy_ch_buf[1];
 524
 525   b->yy_is_our_buffer = 1;
 526   b->yy_is_interactive = 0;
 527   b->yy_at_bol = 1;
 528   b->yy_fill_buffer = 0;
 529
 530   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 531      a flex internal interface in the first place!  */
 532 #ifdef YY_BUFFER_NEW
 533   b->yy_buffer_status = YY_BUFFER_NEW;
 534 #else
 535   b->yy_eof_status = EOF_NOT_SEEN;
 536 #endif
 537
 538   return b;
 539 }
 540
 541 /* Switch flex to reading from STRING, saving the current input info
 542    on the include stack.  */
 543
 544 void
 545 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 546 {
 547   YY_BUFFER_STATE tmp;
 548
 549   yy_init = 0;
 550   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 551     {
 552       einfo("%F: macros nested too deeply\n");
 553     }
 554   file_name_stack[include_stack_ptr] = fake_filename;
 555   lineno_stack[include_stack_ptr] = lineno;
 556   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 557   include_stack_ptr++;
 558   lineno = count;
 559   tmp = yy_create_string_buffer (string, strlen (string));
 560   yy_switch_to_buffer (tmp);
 561 }
 562 \f
 563 /* Functions to switch to a different flex start condition,
 564    saving the current start condition on `state_stack'.  */
 565
 566 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 567 static int *state_stack_p = state_stack;
 568
 569 void
 570 ldlex_script (void)
 571 {
 572   *(state_stack_p)++ = yy_start;
 573   BEGIN (SCRIPT);
 574 }
 575
 576 void
 577 ldlex_inputlist (void)
 578 {
 579   *(state_stack_p)++ = yy_start;
 580   BEGIN (INPUTLIST);
 581 }
 582
 583 void
 584 ldlex_mri_script (void)
 585 {
 586   *(state_stack_p)++ = yy_start;
 587   BEGIN (MRI);
 588 }
 589
 590 void
 591 ldlex_version_script (void)
 592 {
 593   *(state_stack_p)++ = yy_start;
 594   BEGIN (VERS_START);
 595 }
 596
 597 void
 598 ldlex_version_file (void)
 599 {
 600   *(state_stack_p)++ = yy_start;
 601   BEGIN (VERS_SCRIPT);
 602 }
 603
 604 void
 605 ldlex_defsym (void)
 606 {
 607   *(state_stack_p)++ = yy_start;
 608   BEGIN (DEFSYMEXP);
 609 }
 610
 611 void
 612 ldlex_expression (void)
 613 {
 614   *(state_stack_p)++ = yy_start;
 615   BEGIN (EXPRESSION);
 616 }
 617
 618 void
 619 ldlex_both (void)
 620 {
 621   *(state_stack_p)++ = yy_start;
 622   BEGIN (BOTH);
 623 }
 624
 625 void
 626 ldlex_popstate (void)
 627 {
 628   yy_start = *(--state_stack_p);
 629 }
 630
 631 /* Return the current file name, or the previous file if no file is
 632    current.  */
 633
 634 const char*
 635 ldlex_filename (void)
 636 {
 637   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 638 }
 639 \f
 640
 641 /* Place up to MAX_SIZE characters in BUF and return
 642    either the number of characters read, or 0 to indicate EOF.  */
 643
 644 static int
 645 yy_input (char *buf, int max_size)
 646 {
 647   int result = 0;
 648   if (YY_CURRENT_BUFFER->yy_input_file)
 649     {
 650       if (yyin)
 651         {
 652           result = fread (buf, 1, max_size, yyin);
 653           if (result < max_size && ferror (yyin))
 654             einfo ("%F%P: read in flex scanner failed\n");
 655         }
 656     }
 657   return result;
 658 }
 659
 660 /* Eat the rest of a C-style comment.  */
 661
 662 static void
 663 comment (void)
 664 {
 665   int c;
 666
 667   while (1)
 668   {
 669     c = input();
 670     while (c != '*' && c != EOF)
 671     {
 672       if (c == '\n')
 673         lineno++;
 674       c = input();
 675     }
 676
 677     if (c == '*')
 678     {
 679       c = input();
 680       while (c == '*')
 681        c = input();
 682       if (c == '/')
 683        break;                   /* found the end */
 684     }
 685
 686     if (c == '\n')
 687       lineno++;
 688
 689     if (c == EOF)
 690     {
 691       einfo( "%F%P: EOF in comment\n");
 692       break;
 693     }
 694   }
 695 }
 696
 697 /* Warn the user about a garbage character WHAT in the input
 698    in context WHERE.  */
 699
 700 static void
 701 lex_warn_invalid (char *where, char *what)
 702 {
 703   char buf[5];
 704
 705   /* If we have found an input file whose format we do not recognize,
 706      and we are therefore treating it as a linker script, and we find
 707      an invalid character, then most likely this is a real object file
 708      of some different format.  Treat it as such.  */
 709   if (ldfile_assumed_script)
 710     {
 711       bfd_set_error (bfd_error_file_not_recognized);
 712       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 713     }
 714
 715   if (! ISPRINT (*what))
 716     {
 717       sprintf (buf, "\\%03o", *(unsigned char *) what);
 718       what = buf;
 719     }
 720
 721   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 722 }