usr.bin/mkcsmapper/lex.l

   1 /*      $NetBSD: lex.l,v 1.4 2006/02/09 22:03:15 dogcow Exp $   */
   2
   3 %{
   4 /*-
   5  * Copyright (c)2003 Citrus Project,
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #pragma GCC diagnostic ignored "-Wsign-compare"
  31 #include <machine/endian.h>
  32 #include <assert.h>
  33 #include <errno.h>
  34 #include <limits.h>
  35 #include <stdio.h>
  36 #include <stdlib.h>
  37 #include <string.h>
  38
  39 #include "ldef.h"
  40 #include "yacc.h"
  41
  42 int aline_number = 1;
  43 %}
  44
  45 %option noinput
  46 %option nounput
  47
  48 %x      COMMENT
  49
  50 %%
  51
  52 [ \t]+  { }
  53 #.*[\n]|"//".*[\n]|[\n] { aline_number++; return (R_LN); }
  54
  55 "/*"            { BEGIN COMMENT; }
  56 <COMMENT>"*/"   { BEGIN 0; }
  57 <COMMENT>[\n]   { aline_number++; }
  58 <COMMENT>.      { }
  59 <COMMENT><<EOF>>        {
  60                 yyerror("unexpected file end (unterminate comment)\n");
  61                 exit(1);
  62         }
  63
  64 "="|"/"|"-"     { return (int)yytext[0]; }
  65
  66 ([1-9][0-9]*)|(0[0-9]*)|(0[xX][0-9A-Fa-f]+)     {
  67                 yylval.i_value = strtoul(yytext, NULL, 0);
  68                 return L_IMM;
  69         }
  70
  71 "TYPE"          { return (R_TYPE); }
  72 "NAME"          { return (R_NAME); }
  73 "SRC_ZONE"      { return (R_SRC_ZONE); }
  74 "DST_INVALID"   { return (R_DST_INVALID); }
  75 "DST_ILSEQ"     { return (R_DST_ILSEQ); }
  76 "DST_UNIT_BITS" { return (R_DST_UNIT_BITS); }
  77 "BEGIN_MAP"     { return (R_BEGIN_MAP); }
  78 "END_MAP"       { return (R_END_MAP); }
  79 "INVALID"       { return (R_INVALID); }
  80 "ILSEQ"         { return (R_ILSEQ); }
  81 "OOB_MODE"      { return (R_OOB_MODE); }
  82 "ROWCOL"        { return (R_ROWCOL); }
  83
  84 \"([^\"\n]*(\\\")?)*\"|\'([^\'\n]*(\\\')?)*\'   {
  85                 size_t len;
  86                 len = strlen(yytext);
  87                 yylval.s_value = malloc(len-1);
  88                 strlcpy(yylval.s_value, yytext+1, len-1);
  89                 return L_STRING;
  90         }
  91 [^ =/\-0-9\t\n][^ \t\n]*        {
  92                 yylval.s_value = strdup(yytext);
  93                 return L_STRING;
  94         }
  95
  96 %%
  97
  98 #ifndef yywrap
  99 int
 100 yywrap(void)
 101 {
 102         return (1);
 103 }
 104 #endif