usr.sbin/ndiscvt/inf-token.l

   1 %{
   2 /*
   3  * Copyright (c) 2003
   4  *      Bill Paul <wpaul@windriver.com>.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. All advertising materials mentioning features or use of this software
  15  *    must display the following acknowledgement:
  16  *      This product includes software developed by Bill Paul.
  17  * 4. Neither the name of the author nor the names of any co-contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY Bill Paul AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL Bill Paul OR THE VOICES IN HIS HEAD
  25  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  26  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  27  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  28  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  29  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  30  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
  31  * THE POSSIBILITY OF SUCH DAMAGE.
  32  *
  33  * $FreeBSD: src/usr.sbin/ndiscvt/inf-token.l,v 1.3 2004/01/11 21:10:35 mdodd Exp $
  34  */
  35
  36 #pragma GCC diagnostic ignored "-Wsign-compare"
  37 #include <regex.h>
  38 #include <ctype.h>
  39 #include <err.h>
  40 #include <stdio.h>
  41 #include <stdlib.h>
  42 #include <string.h>
  43 #include "y.tab.h"
  44
  45 int lineno = 1;
  46
  47 void yyerror(const char *);
  48
  49 static void
  50 update_lineno(const char *cp)
  51 {
  52         while (*cp)
  53                 if (*cp++ == '\n')
  54                         lineno++;
  55 }
  56
  57 %}
  58
  59 %option noinput
  60 %option nounput
  61
  62 %%
  63
  64 [ \t]+                  ;
  65 \n                      { lineno++; return EOL; }
  66 \r                      ;
  67 ;.*$                    ;
  68 \/\/.*$                 ;
  69 =                       { return EQUALS; }
  70 ,                       { return COMMA; }
  71 \"(\\\"|[^"]|\"\")*\"   {
  72                         int len = strlen(yytext) - 2;
  73                         int blen = len + 1;
  74                         char *walker;
  75                         int i;
  76                         update_lineno(yytext);
  77                         yylval.str = (char *)malloc(blen);
  78                         if (yylval.str == NULL)
  79                                 goto out;
  80                         walker = yylval.str;
  81                         for (i = 1; i <= len; i++) {
  82                                 if (yytext[i] == '\"') {
  83                                         switch (yytext[i + 1]) {
  84                                         case '\"':
  85                                                 i++;
  86                                                 break;
  87                                         default:
  88                                                 break;
  89                                         }
  90                                 }
  91                                 if (yytext[i] == '\\') {
  92                                         switch (yytext[i + 1]) {
  93                                         case '\n':
  94                                                 i += 2;
  95                                                 while(isspace(yytext[i]))
  96                                                         i++;
  97                                                 break;
  98                                         case '\"':
  99                                                 i++;
 100                                                 break;
 101                                         case '(':
 102                                                 i++;
 103                                                 break;
 104                                         default:
 105                                                 break;
 106                                         }
 107                                 }
 108                                 *walker++ = yytext[i];
 109                         }
 110                         *walker++ = '\0';
 111                         out:;
 112                         return STRING;
 113                         }
 114 \[[a-zA-Z0-9%&\{\}\-\.\/_\\\*\ ]+\]     {
 115                                 int len = strlen(yytext);
 116                                 yytext[len-1] = '\0';
 117                                 yylval.str = strdup(yytext+1);
 118                                 return SECTION;
 119                         }
 120 [a-zA-Z0-9%&\{\}\-\.\/_\\\*]+           {
 121                                 yylval.str = strdup(yytext);
 122                                 return WORD;
 123                         }
 124 %%
 125
 126 void
 127 yyerror(const char *s)
 128 {
 129         errx(1, "line %d: %s%s %s.", lineno, yytext, yytext?":":"", s);
 130 }