contrib/libgmp/mpn/alpha/rshift.s

   1 /* $Id$
   2  # Alpha 21064 __mpn_rshift --
   3
   4  # Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   5
   6  # This file is part of the GNU MP Library.
   7
   8  # The GNU MP Library is free software; you can redistribute it and/or modify
   9  # it under the terms of the GNU Library General Public License as published by
  10  # the Free Software Foundation; either version 2 of the License, or (at your
  11  # option) any later version.
  12
  13  # The GNU MP Library is distributed in the hope that it will be useful, but
  14  # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15  # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16  # License for more details.
  17
  18  # You should have received a copy of the GNU Library General Public License
  19  # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20  # the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21  # MA 02111-1307, USA.
  22
  23
  24  # INPUT PARAMETERS
  25  # res_ptr      r16
  26  # s1_ptr       r17
  27  # size         r18
  28  # cnt          r19
  29
  30  # This code runs at 4.8 cycles/limb on the 21064.  With infinite unrolling,
  31  # it would take 4 cycles/limb.  It should be possible to get down to 3
  32  # cycles/limb since both ldq and stq can be paired with the other used
  33  # instructions.  But there are many restrictions in the 21064 pipeline that
  34  # makes it hard, if not impossible, to get down to 3 cycles/limb:
  35
  36  # 1. ldq has a 3 cycle delay, srl and sll have a 2 cycle delay.
  37  # 2. Only aligned instruction pairs can be paired.
  38  # 3. The store buffer or silo might not be able to deal with the bandwidth.
  39 */
  40
  41         .set    noreorder
  42         .set    noat
  43 .text
  44         .align  3
  45         .globl  __mpn_rshift
  46         .ent    __mpn_rshift
  47 __mpn_rshift:
  48         .frame  $30,0,$26,0
  49
  50         ldq     $4,0($17)       # load first limb
  51         addq    $17,8,$17
  52         subq    $31,$19,$7
  53         subq    $18,1,$18
  54         and     $18,4-1,$20     # number of limbs in first loop
  55         sll     $4,$7,$0        # compute function result
  56
  57         beq     $20,.L0
  58         subq    $18,$20,$18
  59
  60         .align  3
  61 .Loop0:
  62         ldq     $3,0($17)
  63         addq    $16,8,$16
  64         addq    $17,8,$17
  65         subq    $20,1,$20
  66         srl     $4,$19,$5
  67         sll     $3,$7,$6
  68         bis     $3,$3,$4
  69         bis     $5,$6,$8
  70         stq     $8,-8($16)
  71         bne     $20,.Loop0
  72
  73 .L0:    beq     $18,.Lend
  74
  75         .align  3
  76 .Loop:  ldq     $3,0($17)
  77         addq    $16,32,$16
  78         subq    $18,4,$18
  79         srl     $4,$19,$5
  80         sll     $3,$7,$6
  81
  82         ldq     $4,8($17)
  83         srl     $3,$19,$1
  84         bis     $5,$6,$8
  85         stq     $8,-32($16)
  86         sll     $4,$7,$2
  87
  88         ldq     $3,16($17)
  89         srl     $4,$19,$5
  90         bis     $1,$2,$8
  91         stq     $8,-24($16)
  92         sll     $3,$7,$6
  93
  94         ldq     $4,24($17)
  95         srl     $3,$19,$1
  96         bis     $5,$6,$8
  97         stq     $8,-16($16)
  98         sll     $4,$7,$2
  99
 100         addq    $17,32,$17
 101         bis     $1,$2,$8
 102         stq     $8,-8($16)
 103
 104         bgt     $18,.Loop
 105
 106 .Lend:  srl     $4,$19,$8
 107         stq     $8,0($16)
 108         ret     $31,($26),1
 109         .end    __mpn_rshift