contrib/perl5/lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove a series of directories
   6
   7 =head1 SYNOPSIS
   8
   9 C<use File::Path>
  10
  11 C<mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);>
  12
  13 C<rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);>
  14
  15 =head1 DESCRIPTION
  16
  17 The C<mkpath> function provides a convenient way to create directories, even
  18 if your C<mkdir> kernel call won't create more than one level of directory at
  19 a time.  C<mkpath> takes three arguments:
  20
  21 =over 4
  22
  23 =item *
  24
  25 the name of the path to create, or a reference
  26 to a list of paths to create,
  27
  28 =item *
  29
  30 a boolean value, which if TRUE will cause C<mkpath>
  31 to print the name of each directory as it is created
  32 (defaults to FALSE), and
  33
  34 =item *
  35
  36 the numeric mode to use when creating the directories
  37 (defaults to 0777)
  38
  39 =back
  40
  41 It returns a list of all directories (including intermediates, determined
  42 using the Unix '/' separator) created.
  43
  44 Similarly, the C<rmtree> function provides a convenient way to delete a
  45 subtree from the directory structure, much like the Unix command C<rm -r>.
  46 C<rmtree> takes three arguments:
  47
  48 =over 4
  49
  50 =item *
  51
  52 the root of the subtree to delete, or a reference to
  53 a list of roots.  All of the files and directories
  54 below each root, as well as the roots themselves,
  55 will be deleted.
  56
  57 =item *
  58
  59 a boolean value, which if TRUE will cause C<rmtree> to
  60 print a message each time it examines a file, giving the
  61 name of the file, and indicating whether it's using C<rmdir>
  62 or C<unlink> to remove it, or that it's skipping it.
  63 (defaults to FALSE)
  64
  65 =item *
  66
  67 a boolean value, which if TRUE will cause C<rmtree> to
  68 skip any files to which you do not have delete access
  69 (if running under VMS) or write access (if running
  70 under another OS).  This will change in the future when
  71 a criterion for 'delete permission' under OSs other
  72 than VMS is settled.  (defaults to FALSE)
  73
  74 =back
  75
  76 It returns the number of files successfully deleted.  Symlinks are
  77 treated as ordinary files.
  78
  79 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  80 in the face of failure or interruption.  Files and directories which
  81 were not deleted may be left with permissions reset to allow world
  82 read and write access.  Note also that the occurrence of errors in
  83 rmtree can be determined I<only> by trapping diagnostic messages
  84 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  85 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  86 in situations where security is an issue.
  87
  88 =head1 AUTHORS
  89
  90 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  91 Charles Bailey <F<bailey@newman.upenn.edu>>
  92
  93 =head1 REVISION
  94
  95 Current $VERSION is 1.0401.
  96
  97 =cut
  98
  99 use Carp;
 100 use File::Basename ();
 101 use DirHandle ();
 102 use Exporter ();
 103 use strict;
 104
 105 use vars qw( $VERSION @ISA @EXPORT );
 106 $VERSION = "1.0401";
 107 @ISA = qw( Exporter );
 108 @EXPORT = qw( mkpath rmtree );
 109
 110 my $Is_VMS = $^O eq 'VMS';
 111
 112 # These OSes complain if you want to remove a file that you have no
 113 # write permission to:
 114 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32'
 115                        || $^O eq 'amigaos');
 116
 117 sub mkpath {
 118     my($paths, $verbose, $mode) = @_;
 119     # $paths   -- either a path string or ref to list of paths
 120     # $verbose -- optional print "mkdir $path" for each directory created
 121     # $mode    -- optional permissions, defaults to 0777
 122     local($")="/";
 123     $mode = 0777 unless defined($mode);
 124     $paths = [$paths] unless ref $paths;
 125     my(@created,$path);
 126     foreach $path (@$paths) {
 127         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:$/; # feature of CRT
 128         next if -d $path;
 129         # Logic wants Unix paths, so go with the flow.
 130         $path = VMS::Filespec::unixify($path) if $Is_VMS;
 131         my $parent = File::Basename::dirname($path);
 132         # Allow for creation of new logical filesystems under VMS
 133         if (not $Is_VMS or $parent !~ m:/[^/]+/000000/?:) {
 134             push(@created,mkpath($parent, $verbose, $mode)) unless (-d $parent);
 135         }
 136         print "mkdir $path\n" if $verbose;
 137         unless (mkdir($path,$mode)) {
 138           my $e = $!;
 139           # allow for another process to have created it meanwhile
 140           croak "mkdir $path: $e" unless -d $path;
 141         }
 142         push(@created, $path);
 143     }
 144     @created;
 145 }
 146
 147 sub rmtree {
 148     my($roots, $verbose, $safe) = @_;
 149     my(@files);
 150     my($count) = 0;
 151     $roots = [$roots] unless ref $roots;
 152     $verbose ||= 0;
 153     $safe ||= 0;
 154
 155     my($root);
 156     foreach $root (@{$roots}) {
 157         $root =~ s#/$##;
 158         (undef, undef, my $rp) = lstat $root or next;
 159         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 160         if ( -d _ ) {
 161             # notabene: 0777 is for making readable in the first place,
 162             # it's also intended to change it to writable in case we have
 163             # to recurse in which case we are better than rm -rf for
 164             # subtrees with strange permissions
 165             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 166               or carp "Can't make directory $root read+writeable: $!"
 167                 unless $safe;
 168
 169             my $d = DirHandle->new($root)
 170               or carp "Can't read $root: $!";
 171             @files = $d->read;
 172             $d->close;
 173
 174             # Deleting large numbers of files from VMS Files-11 filesystems
 175             # is faster if done in reverse ASCIIbetical order
 176             @files = reverse @files if $Is_VMS;
 177             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir$## if $Is_VMS;
 178             @files = map("$root/$_", grep $_!~/^\.{1,2}$/,@files);
 179             $count += rmtree(\@files,$verbose,$safe);
 180             if ($safe &&
 181                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 182                 print "skipped $root\n" if $verbose;
 183                 next;
 184             }
 185             chmod 0777, $root
 186               or carp "Can't make directory $root writeable: $!"
 187                 if $force_writeable;
 188             print "rmdir $root\n" if $verbose;
 189             if (rmdir $root) {
 190                 ++$count;
 191             }
 192             else {
 193                 carp "Can't remove directory $root: $!";
 194                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 195                     or carp("and can't restore permissions to "
 196                             . sprintf("0%o",$rp) . "\n");
 197             }
 198         }
 199         else {
 200             if ($safe &&
 201                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 202                 print "skipped $root\n" if $verbose;
 203                 next;
 204             }
 205             chmod 0666, $root
 206               or carp "Can't make file $root writeable: $!"
 207                 if $force_writeable;
 208             print "unlink $root\n" if $verbose;
 209             # delete all versions under VMS
 210             for (;;) {
 211                 unless (unlink $root) {
 212                     carp "Can't unlink file $root: $!";
 213                     if ($force_writeable) {
 214                         chmod $rp, $root
 215                             or carp("and can't restore permissions to "
 216                                     . sprintf("0%o",$rp) . "\n");
 217                     }
 218                     last;
 219                 }
 220                 ++$count;
 221                 last unless $Is_VMS && lstat $root;
 222             }
 223         }
 224     }
 225
 226     $count;
 227 }
 228
 229 1;