lib/libc/i386/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD: src/lib/libc/i386/gen/setjmp.S,v 1.17.2.2 2001/07/06 12:41:44 deischen Exp $
  37  */
  38
  39 #if defined(LIBC_RCS) && !defined(lint)
  40         .text
  41         .asciz "$FreeBSD: src/lib/libc/i386/gen/setjmp.S,v 1.17.2.2 2001/07/06 12:41:44 deischen Exp $"
  42 #endif /* LIBC_RCS and not lint */
  43
  44 /*
  45  * C library -- _setjmp, _longjmp
  46  *
  47  *      longjmp(a,v)
  48  * will generate a "return(v)" from the last call to
  49  *      setjmp(a)
  50  * by restoring registers from the environment 'a'.
  51  * The previous signal state is restored.
  52  */
  53
  54 #include "DEFS.h"
  55 #include "SYS.h"
  56
  57 ENTRY(setjmp)
  58         movl    4(%esp),%ecx
  59         PIC_PROLOGUE
  60         leal    28(%ecx), %eax
  61         pushl   %eax                    /* (sigset_t*)oset */
  62         pushl   $0                      /* (sigset_t*)set  */
  63         pushl   $1                      /* SIG_BLOCK       */
  64         call    PIC_PLT(CNAME(sigprocmask))
  65         addl    $12,%esp
  66         PIC_EPILOGUE
  67         movl    4(%esp),%ecx
  68         movl    0(%esp),%edx
  69         movl    %edx, 0(%ecx)
  70         movl    %ebx, 4(%ecx)
  71         movl    %esp, 8(%ecx)
  72         movl    %ebp,12(%ecx)
  73         movl    %esi,16(%ecx)
  74         movl    %edi,20(%ecx)
  75         fnstcw  24(%ecx)
  76         xorl    %eax,%eax
  77         ret
  78
  79 #ifndef _THREAD_SAFE
  80 .weak CNAME(longjmp);
  81 .set CNAME(longjmp),CNAME(__longjmp);
  82 #endif
  83 ENTRY(__longjmp)
  84         movl    4(%esp),%edx
  85         PIC_PROLOGUE
  86         pushl   $0                      /* (sigset_t*)oset */
  87         leal    28(%edx), %eax
  88         pushl   %eax                    /* (sigset_t*)set  */
  89         pushl   $3                      /* SIG_SETMASK     */
  90         call    PIC_PLT(CNAME(sigprocmask))
  91         addl    $12,%esp
  92         PIC_EPILOGUE
  93         movl    4(%esp),%edx
  94         movl    8(%esp),%eax
  95         movl    0(%edx),%ecx
  96         movl    4(%edx),%ebx
  97         movl    8(%edx),%esp
  98         movl    12(%edx),%ebp
  99         movl    16(%edx),%esi
 100         movl    20(%edx),%edi
 101         fninit
 102         fldcw   24(%edx)
 103         testl   %eax,%eax
 104         jnz     1f
 105         incl    %eax
 106 1:      movl    %ecx,0(%esp)
 107         ret