lib/libc/i386/string/bcopy.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from locore.s.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by the University of
  18  *      California, Berkeley and its contributors.
  19  * 4. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 /* $FreeBSD: src/lib/libc/i386/string/bcopy.S,v 1.6.6.2 2002/11/07 19:35:25 sobomax Exp $ */
  37
  38 #include <machine/asm.h>
  39
  40         RCSID("$NetBSD: bcopy.S,v 1.6 1996/11/12 00:50:06 jtc Exp $")
  41
  42         /*
  43          * (ov)bcopy (src,dst,cnt)
  44          *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
  45          */
  46
  47 #ifdef MEMCOPY
  48 ENTRY(memcpy)
  49 #else
  50 #ifdef MEMMOVE
  51 ENTRY(memmove)
  52 #else
  53 ENTRY(bcopy)
  54 #endif
  55 #endif
  56         pushl   %esi
  57         pushl   %edi
  58 #if defined(MEMCOPY) || defined(MEMMOVE)
  59         movl    12(%esp),%edi
  60         movl    16(%esp),%esi
  61         movl    %edi,%eax
  62 #else
  63         movl    12(%esp),%esi
  64         movl    16(%esp),%edi
  65 #endif
  66         movl    20(%esp),%ecx
  67         movl    %edi,%edx
  68         subl    %esi,%edx
  69         cmpl    %ecx,%edx       /* overlapping? */
  70         jb      1f
  71         cld                     /* nope, copy forwards. */
  72         movl    %ecx,%edx
  73         shrl    $2,%ecx         /* copy by words */
  74         rep
  75         movsl
  76         movl    %edx,%ecx
  77         andl    $3,%ecx         /* any bytes left? */
  78         rep
  79         movsb
  80         popl    %edi
  81         popl    %esi
  82         ret
  83 1:
  84         addl    %ecx,%edi       /* copy backwards. */
  85         addl    %ecx,%esi
  86         std
  87         movl    %ecx,%edx
  88         andl    $3,%ecx         /* any fractional bytes? */
  89         decl    %edi
  90         decl    %esi
  91         rep
  92         movsb
  93         movl    %edx,%ecx       /* copy remainder by words */
  94         shrl    $2,%ecx
  95         subl    $3,%esi
  96         subl    $3,%edi
  97         rep
  98         movsl
  99         popl    %edi
 100         popl    %esi
 101         cld
 102         ret