sys/platform/pc64/amd64/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  * Copyright (c) 2008 Jordan Gordeev.
   4  *
   5  * This code is derived from software contributed to The DragonFly Project
   6  * by Matthew Dillon <dillon@backplane.com>
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  *
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in
  16  *    the documentation and/or other materials provided with the
  17  *    distribution.
  18  * 3. Neither the name of The DragonFly Project nor the names of its
  19  *    contributors may be used to endorse or promote products derived
  20  *    from this software without specific, prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * Copyright (c) 1990 The Regents of the University of California.
  36  * All rights reserved.
  37  *
  38  * This code is derived from software contributed to Berkeley by
  39  * William Jolitz.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by the University of
  52  *      California, Berkeley and its contributors.
  53  * 4. Neither the name of the University nor the names of its contributors
  54  *    may be used to endorse or promote products derived from this software
  55  *    without specific prior written permission.
  56  *
  57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  67  * SUCH DAMAGE.
  68  *
  69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  70  * $DragonFly: src/sys/platform/pc64/amd64/swtch.s,v 1.3 2008/08/29 17:07:10 dillon Exp $
  71  */
  72
  73 //#include "use_npx.h"
  74
  75 #include <sys/rtprio.h>
  76
  77 #include <machine/asmacros.h>
  78 #include <machine/segments.h>
  79
  80 #include <machine/pmap.h>
  81 #if JG
  82 #include <machine_base/apic/apicreg.h>
  83 #endif
  84 #include <machine/lock.h>
  85
  86 #define CHECKNZ(expr, scratch_reg) \
  87         movq expr, scratch_reg; testq scratch_reg, scratch_reg; jnz 7f; int $3; 7:
  88
  89 #include "assym.s"
  90
  91 #if defined(SMP)
  92 #define MPLOCKED        lock ;
  93 #else
  94 #define MPLOCKED
  95 #endif
  96
  97         .data
  98
  99         .globl  panic
 100
 101 #if defined(SWTCH_OPTIM_STATS)
 102         .globl  swtch_optim_stats, tlb_flush_count
 103 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
 104 tlb_flush_count:        .long   0
 105 #endif
 106
 107         .text
 108
 109
 110 /*
 111  * cpu_heavy_switch(struct thread *next_thread)
 112  *
 113  *      Switch from the current thread to a new thread.  This entry
 114  *      is normally called via the thread->td_switch function, and will
 115  *      only be called when the current thread is a heavy weight process.
 116  *
 117  *      Some instructions have been reordered to reduce pipeline stalls.
 118  *
 119  *      YYY disable interrupts once giant is removed.
 120  */
 121 ENTRY(cpu_heavy_switch)
 122         /*
 123          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
 124          */
 125         movq    PCPU(curthread),%rcx
 126         /* On top of the stack is the return adress. */
 127         movq    (%rsp),%rax                     /* (reorder optimization) */
 128         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
 129         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
 130         movq    %rbx,PCB_RBX(%rdx)
 131         movq    %rsp,PCB_RSP(%rdx)
 132         movq    %rbp,PCB_RBP(%rdx)
 133         movq    %r12,PCB_R12(%rdx)
 134         movq    %r13,PCB_R13(%rdx)
 135         movq    %r14,PCB_R14(%rdx)
 136         movq    %r15,PCB_R15(%rdx)
 137
 138         movq    %rcx,%rbx                       /* RBX = curthread */
 139         movq    TD_LWP(%rcx),%rcx
 140         movl    PCPU(cpuid), %eax
 141         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 142         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 143
 144         /*
 145          * Push the LWKT switch restore function, which resumes a heavy
 146          * weight process.  Note that the LWKT switcher is based on
 147          * TD_SP, while the heavy weight process switcher is based on
 148          * PCB_RSP.  TD_SP is usually two ints pushed relative to
 149          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
 150          */
 151         pushfq
 152         movq    $cpu_heavy_restore, %rax
 153         pushq   %rax
 154         movq    %rsp,TD_SP(%rbx)
 155
 156         /*
 157          * Save debug regs if necessary
 158          */
 159         movq    PCB_FLAGS(%rdx),%rax
 160         andq    $PCB_DBREGS,%rax
 161         jz      1f                              /* no, skip over */
 162         movq    %dr7,%rax                       /* yes, do the save */
 163         movq    %rax,PCB_DR7(%rdx)
 164         /* JG correct value? */
 165         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 166         movq    %rax,%dr7
 167         movq    %dr6,%rax
 168         movq    %rax,PCB_DR6(%rdx)
 169         movq    %dr3,%rax
 170         movq    %rax,PCB_DR3(%rdx)
 171         movq    %dr2,%rax
 172         movq    %rax,PCB_DR2(%rdx)
 173         movq    %dr1,%rax
 174         movq    %rax,PCB_DR1(%rdx)
 175         movq    %dr0,%rax
 176         movq    %rax,PCB_DR0(%rdx)
 177 1:
 178
 179 #if JG
 180 #if NNPX > 0
 181         /*
 182          * Save the FP state if we have used the FP.  Note that calling
 183          * npxsave will NULL out PCPU(npxthread).
 184          */
 185         cmpl    %ebx,PCPU(npxthread)
 186         jne     1f
 187         pushl   TD_SAVEFPU(%ebx)
 188         call    npxsave                 /* do it in a big C function */
 189         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 190 1:
 191 #endif
 192 #endif  /* NNPX > 0 */
 193
 194         /*
 195          * Switch to the next thread, which was passed as an argument
 196          * to cpu_heavy_switch().  The argument is in %rdi.
 197          * Set the current thread, load the stack pointer,
 198          * and 'ret' into the switch-restore function.
 199          *
 200          * The switch restore function expects the new thread to be in %rax
 201          * and the old one to be in %rbx.
 202          *
 203          * There is a one-instruction window where curthread is the new
 204          * thread but %rsp still points to the old thread's stack, but
 205          * we are protected by a critical section so it is ok.
 206          */
 207         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
 208         movq    %rax,PCPU(curthread)
 209         movq    TD_SP(%rax),%rsp
 210         CHECKNZ((%rsp), %r9)
 211         ret
 212
 213 /*
 214  *  cpu_exit_switch(struct thread *next)
 215  *
 216  *      The switch function is changed to this when a thread is going away
 217  *      for good.  We have to ensure that the MMU state is not cached, and
 218  *      we don't bother saving the existing thread state before switching.
 219  *
 220  *      At this point we are in a critical section and this cpu owns the
 221  *      thread's token, which serves as an interlock until the switchout is
 222  *      complete.
 223  */
 224 ENTRY(cpu_exit_switch)
 225         /*
 226          * Get us out of the vmspace
 227          */
 228 #if JG
 229         movq    %cr3,%rax
 230         cmpq    %rcx,%rax
 231         je      1f
 232         /* JG no increment of statistics counters? see cpu_heavy_restore */
 233         movq    %rcx,%cr3
 234 1:
 235 #else
 236         movq    IdlePTD, %rcx
 237         orq     $(PG_RW|PG_V), %rcx
 238         movq    link_pdpe,%r12
 239         movq    %rcx, (%r12)
 240         movq    %cr3, %rcx
 241         movq    %rcx, %cr3
 242 #endif
 243         movq    PCPU(curthread),%rbx
 244
 245         /*
 246          * If this is a process/lwp, deactivate the pmap after we've
 247          * switched it out.
 248          */
 249         movq    TD_LWP(%rbx),%rcx
 250         testq   %rcx,%rcx
 251         jz      2f
 252         movl    PCPU(cpuid), %eax
 253         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 254         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 255 2:
 256         /*
 257          * Switch to the next thread.  RET into the restore function, which
 258          * expects the new thread in RAX and the old in RBX.
 259          *
 260          * There is a one-instruction window where curthread is the new
 261          * thread but %rsp still points to the old thread's stack, but
 262          * we are protected by a critical section so it is ok.
 263          */
 264         movq    %rdi,%rax
 265         movq    %rax,PCPU(curthread)
 266         movq    TD_SP(%rax),%rsp
 267         CHECKNZ((%rsp), %r9)
 268         ret
 269
 270 /*
 271  * cpu_heavy_restore()  (current thread in %rax on entry)
 272  *
 273  *      Restore the thread after an LWKT switch.  This entry is normally
 274  *      called via the LWKT switch restore function, which was pulled
 275  *      off the thread stack and jumped to.
 276  *
 277  *      This entry is only called if the thread was previously saved
 278  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 279  *      or when a new process is initially scheduled.  The first thing we
 280  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 281  *      new thread.
 282  *
 283  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
 284  *      a preemption switch may interrupt the process and then return via
 285  *      cpu_heavy_restore.
 286  *
 287  *      YYY theoretically we do not have to restore everything here, a lot
 288  *      of this junk can wait until we return to usermode.  But for now
 289  *      we restore everything.
 290  *
 291  *      YYY the PCB crap is really crap, it makes startup a bitch because
 292  *      we can't switch away.
 293  *
 294  *      YYY note: spl check is done in mi_switch when it splx()'s.
 295  */
 296
 297 ENTRY(cpu_heavy_restore)
 298         popfq
 299         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
 300         movq    TD_LWP(%rax),%rcx
 301
 302 #if defined(SWTCH_OPTIM_STATS)
 303         incl    _swtch_optim_stats
 304 #endif
 305         /*
 306          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 307          * safely test/reload %cr3 until after we have set the bit in the
 308          * pmap (remember, we do not hold the MP lock in the switch code).
 309          */
 310         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 311         movl    PCPU(cpuid), %esi
 312         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%rcx)
 313
 314         /*
 315          * Restore the MMU address space.  If it is the same as the last
 316          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 317          * YYY which naturally also means that the PM_ACTIVE bit had better
 318          * already have been set before we set it above, check? YYY
 319          */
 320 #if JG
 321         movq    %cr3,%rsi
 322         movq    PCB_CR3(%rdx),%rcx
 323         cmpq    %rsi,%rcx
 324         je      4f
 325 #if defined(SWTCH_OPTIM_STATS)
 326         decl    _swtch_optim_stats
 327         incl    _tlb_flush_count
 328 #endif
 329         movq    %rcx,%cr3
 330 4:
 331 #else
 332         movq    PCB_CR3(%rdx),%rcx
 333         orq     $(PG_RW|PG_U|PG_V), %rcx
 334         /*XXX*/
 335         movq    link_pdpe,%r12
 336         movq    %rcx, (%r12)
 337         movq    %cr3, %rcx
 338         movq    %rcx, %cr3
 339 #endif
 340         /*
 341          * Clear TDF_RUNNING flag in old thread only after cleaning up
 342          * %cr3.  The target thread is already protected by being TDF_RUNQ
 343          * so setting TDF_RUNNING isn't as big a deal.
 344          */
 345         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 346         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 347
 348         /*
 349          * Deal with the PCB extension, restore the private tss
 350          */
 351         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
 352         /* JG cheaper than "movq $1,%rbx", right? */
 353         /* JG what's that magic value $1? */
 354         movl    $1,%ebx                 /* maybe mark use of a private tss */
 355         testq   %rdi,%rdi
 356 #if JG
 357         jnz     2f
 358 #endif
 359
 360         /* JG
 361          * Going back to the common_tss.  We may need to update TSS_ESP0
 362          * which sets the top of the supervisor stack when entering from
 363          * usermode.  The PCB is at the top of the stack but we need another
 364          * 16 bytes to take vm86 into account.
 365          */
 366         leaq    -16(%rdx),%rbx
 367         movq    %rbx, PCPU(common_tss) + TSS_RSP0
 368         movq    %rbx, PCPU(rsp0)
 369
 370 #if JG
 371         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 372         je      3f                      /* already using the common TSS */
 373
 374         /* JG? */
 375         subl    %ebx,%ebx               /* unmark use of private tss */
 376
 377         /*
 378          * Get the address of the common TSS descriptor for the ltr.
 379          * There is no way to get the address of a segment-accessed variable
 380          * so we store a self-referential pointer at the base of the per-cpu
 381          * data area and add the appropriate offset.
 382          */
 383         /* JG movl? */
 384         movq    $gd_common_tssd, %rdi
 385         /* JG name for "%gs:0"? */
 386         addq    %gs:0, %rdi
 387
 388         /*
 389          * Move the correct TSS descriptor into the GDT slot, then reload
 390          * ltr.
 391          */
 392 2:
 393         /* JG */
 394         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 395         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
 396         movq    0(%rdi), %rax
 397         movq    %rax, 0(%rbx)
 398         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 399         ltr     %si
 400 #endif
 401
 402 3:
 403         /*
 404          * Restore the user %gs and %fs
 405          */
 406         movq    PCB_FSBASE(%rdx),%r9
 407         cmpq    PCPU(user_fs),%r9
 408         je      4f
 409         movq    %rdx,%r10
 410         movq    %r9,PCPU(user_fs)
 411         movl    $MSR_FSBASE,%ecx
 412         movl    PCB_FSBASE(%r10),%eax
 413         movl    PCB_FSBASE+4(%r10),%edx
 414         wrmsr
 415         movq    %r10,%rdx
 416 4:
 417         movq    PCB_GSBASE(%rdx),%r9
 418         cmpq    PCPU(user_gs),%r9
 419         je      5f
 420         movq    %rdx,%r10
 421         movq    %r9,PCPU(user_gs)
 422         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
 423         movl    PCB_GSBASE(%r10),%eax
 424         movl    PCB_GSBASE+4(%r10),%edx
 425         wrmsr
 426         movq    %r10,%rdx
 427 5:
 428
 429         /*
 430          * Restore general registers.
 431          */
 432         movq    PCB_RBX(%rdx), %rbx
 433         movq    PCB_RSP(%rdx), %rsp
 434         movq    PCB_RBP(%rdx), %rbp
 435         movq    PCB_R12(%rdx), %r12
 436         movq    PCB_R13(%rdx), %r13
 437         movq    PCB_R14(%rdx), %r14
 438         movq    PCB_R15(%rdx), %r15
 439         movq    PCB_RIP(%rdx), %rax
 440         movq    %rax, (%rsp)
 441
 442 #if JG
 443         /*
 444          * Restore the user LDT if we have one
 445          */
 446         cmpl    $0, PCB_USERLDT(%edx)
 447         jnz     1f
 448         movl    _default_ldt,%eax
 449         cmpl    PCPU(currentldt),%eax
 450         je      2f
 451         lldt    _default_ldt
 452         movl    %eax,PCPU(currentldt)
 453         jmp     2f
 454 1:      pushl   %edx
 455         call    set_user_ldt
 456         popl    %edx
 457 2:
 458 #endif
 459 #if JG
 460         /*
 461          * Restore the user TLS if we have one
 462          */
 463         pushl   %edx
 464         call    set_user_TLS
 465         popl    %edx
 466 #endif
 467
 468         /*
 469          * Restore the DEBUG register state if necessary.
 470          */
 471         movq    PCB_FLAGS(%rdx),%rax
 472         andq    $PCB_DBREGS,%rax
 473         jz      1f                              /* no, skip over */
 474         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
 475         movq    %rax,%dr6
 476         movq    PCB_DR3(%rdx),%rax
 477         movq    %rax,%dr3
 478         movq    PCB_DR2(%rdx),%rax
 479         movq    %rax,%dr2
 480         movq    PCB_DR1(%rdx),%rax
 481         movq    %rax,%dr1
 482         movq    PCB_DR0(%rdx),%rax
 483         movq    %rax,%dr0
 484         movq    %dr7,%rax                /* load dr7 so as not to disturb */
 485         /* JG correct value? */
 486         andq    $0x0000fc00,%rax         /*   reserved bits               */
 487         /* JG we've got more registers on amd64 */
 488         pushq   %rbx
 489         movq    PCB_DR7(%rdx),%rbx
 490         /* JG correct value? */
 491         andq    $~0x0000fc00,%rbx
 492         orq     %rbx,%rax
 493         popq    %rbx
 494         movq    %rax,%dr7
 495 1:
 496
 497         CHECKNZ((%rsp), %r9)
 498         ret
 499
 500 /*
 501  * savectx(struct pcb *pcb)
 502  *
 503  * Update pcb, saving current processor state.
 504  */
 505 ENTRY(savectx)
 506         /* fetch PCB */
 507         /* JG use %rdi instead of %rcx everywhere? */
 508         movq    %rdi,%rcx
 509
 510         /* caller's return address - child won't execute this routine */
 511         movq    (%rsp),%rax
 512         movq    %rax,PCB_RIP(%rcx)
 513
 514         movq    %cr3,%rax
 515 #ifndef JG
 516         movq    (%rax), %rax
 517         movq    $0x000ffffffffff000, %rcx
 518         andq    %rcx, %rax
 519         movq    (%rax), %rax
 520         andq    %rcx, %rax
 521 #endif
 522         movq    %rax,PCB_CR3(%rcx)
 523
 524         movq    %rbx,PCB_RBX(%rcx)
 525         movq    %rsp,PCB_RSP(%rcx)
 526         movq    %rbp,PCB_RBP(%rcx)
 527         movq    %r12,PCB_R12(%rcx)
 528         movq    %r13,PCB_R13(%rcx)
 529         movq    %r14,PCB_R14(%rcx)
 530         movq    %r15,PCB_R15(%rcx)
 531
 532 #if JG
 533 #if NNPX > 0
 534         /*
 535          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 536          * state had better already be in the pcb.  This is true for forks
 537          * but not for dumps (the old book-keeping with FP flags in the pcb
 538          * always lost for dumps because the dump pcb has 0 flags).
 539          *
 540          * If npxthread != NULL, then we have to save the npx h/w state to
 541          * npxthread's pcb and copy it to the requested pcb, or save to the
 542          * requested pcb and reload.  Copying is easier because we would
 543          * have to handle h/w bugs for reloading.  We used to lose the
 544          * parent's npx state for forks by forgetting to reload.
 545          */
 546         movl    PCPU(npxthread),%eax
 547         testl   %eax,%eax
 548         je      1f
 549
 550         pushl   %ecx                    /* target pcb */
 551         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 552         pushl   %eax
 553
 554         pushl   %eax
 555         call    npxsave
 556         addl    $4,%esp
 557
 558         popl    %eax
 559         popl    %ecx
 560
 561         pushl   $PCB_SAVEFPU_SIZE
 562         leal    PCB_SAVEFPU(%ecx),%ecx
 563         pushl   %ecx
 564         pushl   %eax
 565         call    bcopy
 566         addl    $12,%esp
 567 #endif  /* NNPX > 0 */
 568
 569 1:
 570 #endif
 571         CHECKNZ((%rsp), %r9)
 572         ret
 573
 574 /*
 575  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
 576  *
 577  *      Don't bother setting up any regs other than %rbp so backtraces
 578  *      don't die.  This restore function is used to bootstrap into the
 579  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 580  *      switching.
 581  *
 582  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 583  *
 584  *      If we are an AP we have to call ap_init() before jumping to
 585  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 586  *      setting up various ncpu-dependant globaldata fields.  This may
 587  *      happen on UP as well as SMP if we happen to be simulating multiple
 588  *      cpus.
 589  */
 590 ENTRY(cpu_idle_restore)
 591         /* cli */
 592         movq    IdlePTD,%rcx
 593         /* JG xor? */
 594         movl    $0,%ebp
 595         /* JG push RBP? */
 596         pushq   $0
 597         orq     $(PG_RW|PG_V), %rcx
 598         movq    link_pdpe,%r12
 599         movq    %rcx, (%r12)
 600         movq    %cr3, %rcx
 601         movq    %rcx,%cr3
 602         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 603         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 604 #ifdef SMP
 605         cmpl    $0,PCPU(cpuid)
 606         je      1f
 607         call    ap_init
 608 1:
 609 #endif
 610         /*
 611          * ap_init can decide to enable interrupts early, but otherwise, or if
 612          * we are UP, do it here.
 613          */
 614         sti
 615         jmp     cpu_idle
 616
 617 /*
 618  * cpu_kthread_restore() (current thread is %rax on entry) (one-time execution)
 619  *
 620  *      Don't bother setting up any regs other then %rbp so backtraces
 621  *      don't die.  This restore function is used to bootstrap into an
 622  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 623  *      after this.
 624  *
 625  *      Since all of our context is on the stack we are reentrant and
 626  *      we can release our critical section and enable interrupts early.
 627  */
 628 ENTRY(cpu_kthread_restore)
 629         sti
 630         movq    IdlePTD,%rcx
 631         movq    TD_PCB(%rax),%rdx
 632         /* JG "movq $0, %rbp"? "xorq %rbp, %rbp"? */
 633         movl    $0,%ebp
 634         orq     $(PG_RW|PG_V), %rcx
 635         movq    link_pdpe,%r12
 636         movq    %rcx, (%r12)
 637         movq    %cr3, %rcx
 638         movq    %rcx,%cr3
 639         /* rax and rbx come from the switchout code */
 640         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 641         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 642         subl    $TDPRI_CRIT,TD_PRI(%rax)
 643         movq    PCB_R12(%rdx),%rdi      /* argument to RBX function */
 644         movq    PCB_RBX(%rdx),%rax      /* thread function */
 645         /* note: top of stack return address inherited by function */
 646         CHECKNZ(%rax, %r9)
 647         jmp     *%rax
 648
 649 /*
 650  * cpu_lwkt_switch(struct thread *)
 651  *
 652  *      Standard LWKT switching function.  Only non-scratch registers are
 653  *      saved and we don't bother with the MMU state or anything else.
 654  *
 655  *      This function is always called while in a critical section.
 656  *
 657  *      There is a one-instruction window where curthread is the new
 658  *      thread but %rsp still points to the old thread's stack, but
 659  *      we are protected by a critical section so it is ok.
 660  *
 661  *      YYY BGL, SPL
 662  */
 663 ENTRY(cpu_lwkt_switch)
 664         pushq   %rbp    /* JG note: GDB hacked to locate ebp relative to td_sp */
 665         /* JG we've got more registers on AMD64 */
 666         pushq   %rbx
 667         movq    PCPU(curthread),%rbx
 668         pushq   %r12
 669         pushq   %r13
 670         pushq   %r14
 671         pushq   %r15
 672         pushfq
 673
 674 #if JG
 675 #if NNPX > 0
 676         /*
 677          * Save the FP state if we have used the FP.  Note that calling
 678          * npxsave will NULL out PCPU(npxthread).
 679          *
 680          * We have to deal with the FP state for LWKT threads in case they
 681          * happen to get preempted or block while doing an optimized
 682          * bzero/bcopy/memcpy.
 683          */
 684         cmpl    %ebx,PCPU(npxthread)
 685         jne     1f
 686         pushl   TD_SAVEFPU(%ebx)
 687         call    npxsave                 /* do it in a big C function */
 688         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 689 1:
 690 #endif  /* NNPX > 0 */
 691 #endif
 692
 693         movq    %rdi,%rax               /* switch to this thread */
 694         pushq   $cpu_lwkt_restore
 695         movq    %rsp,TD_SP(%rbx)
 696         movq    %rax,PCPU(curthread)
 697         movq    TD_SP(%rax),%rsp
 698
 699         /*
 700          * %rax contains new thread, %rbx contains old thread.
 701          */
 702         CHECKNZ((%rsp), %r9)
 703         ret
 704
 705 /*
 706  * cpu_lwkt_restore()   (current thread in %rax on entry)
 707  *
 708  *      Standard LWKT restore function.  This function is always called
 709  *      while in a critical section.
 710  *
 711  *      Warning: due to preemption the restore function can be used to
 712  *      'return' to the original thread.  Interrupt disablement must be
 713  *      protected through the switch so we cannot run splz here.
 714  *
 715  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
 716  *      so we need a way to detect when the PTD we are using is being
 717  *      deleted due to a process exiting.
 718  */
 719 ENTRY(cpu_lwkt_restore)
 720 #if JG
 721         movq    common_lvl4_phys,%rcx   /* YYY borrow but beware desched/cpuchg/exit */
 722 #endif
 723         movq    IdlePTD, %rcx
 724         orq     $(PG_RW|PG_V), %rcx
 725         movq    link_pdpe,%r12
 726         movq    %rcx, (%r12)
 727         movq    %cr3, %rcx
 728         movq    %rcx, %cr3
 729 #if JG
 730         movq    %cr3,%rdx
 731         cmpq    %rcx,%rdx
 732         je      1f
 733         movq    %rcx,%cr3
 734 1:
 735 #endif
 736         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 737         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 738         popfq
 739         popq    %r15
 740         popq    %r14
 741         popq    %r13
 742         popq    %r12
 743         popq    %rbx
 744         popq    %rbp
 745         ret