sys/i386/i386/swtch.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  * LWKT threads Copyright (c) 2003 Matthew Dillon
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * William Jolitz.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by the University of
  20  *      California, Berkeley and its contributors.
  21  * 4. Neither the name of the University nor the names of its contributors
  22  *    may be used to endorse or promote products derived from this software
  23  *    without specific prior written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35  * SUCH DAMAGE.
  36  *
  37  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  38  * $DragonFly: src/sys/i386/i386/Attic/swtch.s,v 1.28 2003/09/25 23:49:03 dillon Exp $
  39  */
  40
  41 #include "use_npx.h"
  42 #include "opt_user_ldt.h"
  43
  44 #include <sys/rtprio.h>
  45
  46 #include <machine/asmacros.h>
  47 #include <machine/ipl.h>
  48
  49 #ifdef SMP
  50 #include <machine/pmap.h>
  51 #include <machine/smptests.h>           /** GRAB_LOPRIO */
  52 #include <machine/apic.h>
  53 #include <machine/lock.h>
  54 #endif /* SMP */
  55
  56 #include "assym.s"
  57
  58 #if defined(SMP)
  59 #define MPLOCKED        lock ;
  60 #else
  61 #define MPLOCKED
  62 #endif
  63
  64         .data
  65
  66         .globl  panic
  67
  68 #if defined(SWTCH_OPTIM_STATS)
  69         .globl  swtch_optim_stats, tlb_flush_count
  70 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
  71 tlb_flush_count:        .long   0
  72 #endif
  73
  74         .text
  75
  76
  77 /*
  78  * cpu_heavy_switch(next_thread)
  79  *
  80  *      Switch from the current thread to a new thread.  This entry
  81  *      is normally called via the thread->td_switch function, and will
  82  *      only be called when the current thread is a heavy weight process.
  83  *
  84  *      Some instructions have been reordered to reduce pipeline stalls.
  85  *
  86  *      YYY disable interrupts once giant is removed.
  87  */
  88 ENTRY(cpu_heavy_switch)
  89         /*
  90          * Save general regs
  91          */
  92         movl    PCPU(curthread),%ecx
  93         movl    (%esp),%eax                     /* (reorder optimization) */
  94         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
  95         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
  96         movl    %ebx,PCB_EBX(%edx)
  97         movl    %esp,PCB_ESP(%edx)
  98         movl    %ebp,PCB_EBP(%edx)
  99         movl    %esi,PCB_ESI(%edx)
 100         movl    %edi,PCB_EDI(%edx)
 101         movl    %gs,PCB_GS(%edx)
 102
 103         movl    %ecx,%ebx                       /* EBX = curthread */
 104         movl    TD_PROC(%ecx),%ecx
 105         movl    PCPU(cpuid), %eax
 106         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 107         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
 108
 109         /*
 110          * Push the LWKT switch restore function, which resumes a heavy
 111          * weight process.  Note that the LWKT switcher is based on
 112          * TD_SP, while the heavy weight process switcher is based on
 113          * PCB_ESP.  TD_SP is usually two ints pushed relative to
 114          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
 115          */
 116         pushfl
 117         pushl   $cpu_heavy_restore
 118         movl    %esp,TD_SP(%ebx)
 119
 120         /*
 121          * Save debug regs if necessary
 122          */
 123         movb    PCB_FLAGS(%edx),%al
 124         andb    $PCB_DBREGS,%al
 125         jz      1f                              /* no, skip over */
 126         movl    %dr7,%eax                       /* yes, do the save */
 127         movl    %eax,PCB_DR7(%edx)
 128         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 129         movl    %eax,%dr7
 130         movl    %dr6,%eax
 131         movl    %eax,PCB_DR6(%edx)
 132         movl    %dr3,%eax
 133         movl    %eax,PCB_DR3(%edx)
 134         movl    %dr2,%eax
 135         movl    %eax,PCB_DR2(%edx)
 136         movl    %dr1,%eax
 137         movl    %eax,PCB_DR1(%edx)
 138         movl    %dr0,%eax
 139         movl    %eax,PCB_DR0(%edx)
 140 1:
 141
 142         /*
 143          * Save the FP state if we have used the FP.  Note that calling
 144          * npxsave will NULL out PCPU(npxthread).
 145          */
 146 #if NNPX > 0
 147         cmpl    %ebx,PCPU(npxthread)
 148         jne     1f
 149         addl    $PCB_SAVEFPU,%edx
 150         pushl   %edx
 151         call    npxsave                 /* do it in a big C function */
 152         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 153 1:
 154 #endif  /* NNPX > 0 */
 155
 156         /*
 157          * Switch to the next thread, which was passed as an argument
 158          * to cpu_heavy_switch().  Due to the eflags and switch-restore
 159          * function we pushed, the argument is at 12(%esp).  Set the current
 160          * thread, load the stack pointer, and 'ret' into the switch-restore
 161          * function.
 162          *
 163          * The switch restore function expects the new thread to be in %eax
 164          * and the old one to be in %ebx.
 165          *
 166          * There is a one-instruction window where curthread is the new
 167          * thread but %esp still points to the old thread's stack, but
 168          * we are protected by a critical section so it is ok.
 169          */
 170         movl    12(%esp),%eax           /* EAX = newtd, EBX = oldtd */
 171         movl    %eax,PCPU(curthread)
 172         movl    TD_SP(%eax),%esp
 173         ret
 174
 175 /*
 176  *  cpu_exit_switch()
 177  *
 178  *      The switch function is changed to this when a thread is going away
 179  *      for good.  We have to ensure that the MMU state is not cached, and
 180  *      we don't bother saving the existing thread state before switching.
 181  *
 182  *      At this point we are in a critical section and this cpu owns the
 183  *      thread's token, which serves as an interlock until the switchout is
 184  *      complete.
 185  */
 186 ENTRY(cpu_exit_switch)
 187         /*
 188          * Get us out of the vmspace
 189          */
 190         movl    IdlePTD,%ecx
 191         movl    %cr3,%eax
 192         cmpl    %ecx,%eax
 193         je      1f
 194         movl    %ecx,%cr3
 195 1:
 196         movl    PCPU(curthread),%ebx
 197         /*
 198          * Switch to the next thread.  RET into the restore function, which
 199          * expects the new thread in EAX and the old in EBX.
 200          *
 201          * There is a one-instruction window where curthread is the new
 202          * thread but %esp still points to the old thread's stack, but
 203          * we are protected by a critical section so it is ok.
 204          */
 205         movl    4(%esp),%eax
 206         movl    %eax,PCPU(curthread)
 207         movl    TD_SP(%eax),%esp
 208         ret
 209
 210 /*
 211  * cpu_heavy_restore()  (current thread in %eax on entry)
 212  *
 213  *      Restore the thread after an LWKT switch.  This entry is normally
 214  *      called via the LWKT switch restore function, which was pulled
 215  *      off the thread stack and jumped to.
 216  *
 217  *      This entry is only called if the thread was previously saved
 218  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 219  *      or when a new process is initially scheduled.  The first thing we
 220  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 221  *      new thread.
 222  *
 223  *      YYY theoretically we do not have to restore everything here, a lot
 224  *      of this junk can wait until we return to usermode.  But for now
 225  *      we restore everything.
 226  *
 227  *      YYY the PCB crap is really crap, it makes startup a bitch because
 228  *      we can't switch away.
 229  *
 230  *      YYY note: spl check is done in mi_switch when it splx()'s.
 231  */
 232
 233 ENTRY(cpu_heavy_restore)
 234         popfl
 235         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
 236         movl    TD_PROC(%eax),%ecx
 237 #ifdef  DIAGNOSTIC
 238         /*
 239          * A heavy weight process will normally be in an SRUN state
 240          * but can also be preempted while it is entering a SZOMB
 241          * (zombie) state.
 242          */
 243         cmpb    $SRUN,P_STAT(%ecx)
 244         je      1f
 245         cmpb    $SZOMB,P_STAT(%ecx)
 246         jne     badsw2
 247 1:
 248 #endif
 249
 250 #if defined(SWTCH_OPTIM_STATS)
 251         incl    _swtch_optim_stats
 252 #endif
 253         /*
 254          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 255          * safely test/reload %cr3 until after we have set the bit in the
 256          * pmap (remember, we do not hold the MP lock in the switch code).
 257          */
 258         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 259         movl    PCPU(cpuid), %esi
 260         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%ecx)
 261
 262         /*
 263          * Restore the MMU address space.  If it is the same as the last
 264          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 265          * YYY which naturally also means that the PM_ACTIVE bit had better
 266          * already have been set before we set it above, check? YYY
 267          */
 268         movl    %cr3,%esi
 269         movl    PCB_CR3(%edx),%ecx
 270         cmpl    %esi,%ecx
 271         je      4f
 272 #if defined(SWTCH_OPTIM_STATS)
 273         decl    _swtch_optim_stats
 274         incl    _tlb_flush_count
 275 #endif
 276         movl    %ecx,%cr3
 277 4:
 278         /*
 279          * Clear TDF_RUNNING flag in old thread only after cleaning up
 280          * %cr3.  The target thread is already protected by being TDF_RUNQ
 281          * so setting TDF_RUNNING isn't as big a deal.
 282          */
 283         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 284         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 285
 286         /*
 287          * Deal with the PCB extension, restore the private tss
 288          */
 289         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
 290         movl    $1,%ebx                 /* maybe mark use of a private tss */
 291         testl   %edi,%edi
 292         jnz     2f
 293
 294         /*
 295          * Going back to the common_tss.  We may need to update TSS_ESP0
 296          * which sets the top of the supervisor stack when entering from
 297          * usermode.  The PCB is at the top of the stack but we need another
 298          * 16 bytes to take vm86 into account.
 299          */
 300         leal    -16(%edx),%ebx
 301         movl    %ebx, PCPU(common_tss) + TSS_ESP0
 302
 303         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 304         je      3f                      /* already using the common TSS */
 305
 306         subl    %ebx,%ebx               /* unmark use of private tss */
 307
 308         /*
 309          * Get the address of the common TSS descriptor for the ltr.
 310          * There is no way to get the address of a segment-accessed variable
 311          * so we store a self-referential pointer at the base of the per-cpu
 312          * data area and add the appropriate offset.
 313          */
 314         movl    $gd_common_tssd, %edi
 315         addl    %fs:0, %edi
 316
 317         /*
 318          * Move the correct TSS descriptor into the GDT slot, then reload
 319          * ltr.
 320          */
 321 2:
 322         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 323         movl    PCPU(tss_gdt), %ebx             /* entry in GDT */
 324         movl    0(%edi), %eax
 325         movl    %eax, 0(%ebx)
 326         movl    4(%edi), %eax
 327         movl    %eax, 4(%ebx)
 328         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 329         ltr     %si
 330
 331 3:
 332         /*
 333          * Restore general registers.
 334          */
 335         movl    PCB_EBX(%edx),%ebx
 336         movl    PCB_ESP(%edx),%esp
 337         movl    PCB_EBP(%edx),%ebp
 338         movl    PCB_ESI(%edx),%esi
 339         movl    PCB_EDI(%edx),%edi
 340         movl    PCB_EIP(%edx),%eax
 341         movl    %eax,(%esp)
 342
 343         /*
 344          * Restore the user LDT if we have one
 345          */
 346 #ifdef  USER_LDT
 347         cmpl    $0, PCB_USERLDT(%edx)
 348         jnz     1f
 349         movl    _default_ldt,%eax
 350         cmpl    PCPU(currentldt),%eax
 351         je      2f
 352         lldt    _default_ldt
 353         movl    %eax,PCPU(currentldt)
 354         jmp     2f
 355 1:      pushl   %edx
 356         call    set_user_ldt
 357         popl    %edx
 358 2:
 359 #endif
 360         /*
 361          * Restore the %gs segment register, which must be done after
 362          * loading the user LDT.  Since user processes can modify the
 363          * register via procfs, this may result in a fault which is
 364          * detected by checking the fault address against cpu_switch_load_gs
 365          * in i386/i386/trap.c
 366          */
 367         .globl  cpu_switch_load_gs
 368 cpu_switch_load_gs:
 369         movl    PCB_GS(%edx),%gs
 370
 371         /*
 372          * Restore the DEBUG register state if necessary.
 373          */
 374         movb    PCB_FLAGS(%edx),%al
 375         andb    $PCB_DBREGS,%al
 376         jz      1f                              /* no, skip over */
 377         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
 378         movl    %eax,%dr6
 379         movl    PCB_DR3(%edx),%eax
 380         movl    %eax,%dr3
 381         movl    PCB_DR2(%edx),%eax
 382         movl    %eax,%dr2
 383         movl    PCB_DR1(%edx),%eax
 384         movl    %eax,%dr1
 385         movl    PCB_DR0(%edx),%eax
 386         movl    %eax,%dr0
 387         movl    %dr7,%eax                /* load dr7 so as not to disturb */
 388         andl    $0x0000fc00,%eax         /*   reserved bits               */
 389         pushl   %ebx
 390         movl    PCB_DR7(%edx),%ebx
 391         andl    $~0x0000fc00,%ebx
 392         orl     %ebx,%eax
 393         popl    %ebx
 394         movl    %eax,%dr7
 395 1:
 396
 397         ret
 398
 399 badsw2:
 400         pushl   $sw0_2
 401         call    panic
 402
 403 sw0_2:  .asciz  "cpu_switch: not SRUN"
 404
 405 /*
 406  * savectx(pcb)
 407  * Update pcb, saving current processor state.
 408  */
 409 ENTRY(savectx)
 410         /* fetch PCB */
 411         movl    4(%esp),%ecx
 412
 413         /* caller's return address - child won't execute this routine */
 414         movl    (%esp),%eax
 415         movl    %eax,PCB_EIP(%ecx)
 416
 417         movl    %cr3,%eax
 418         movl    %eax,PCB_CR3(%ecx)
 419
 420         movl    %ebx,PCB_EBX(%ecx)
 421         movl    %esp,PCB_ESP(%ecx)
 422         movl    %ebp,PCB_EBP(%ecx)
 423         movl    %esi,PCB_ESI(%ecx)
 424         movl    %edi,PCB_EDI(%ecx)
 425         movl    %gs,PCB_GS(%ecx)
 426
 427 #if NNPX > 0
 428         /*
 429          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 430          * state had better already be in the pcb.  This is true for forks
 431          * but not for dumps (the old book-keeping with FP flags in the pcb
 432          * always lost for dumps because the dump pcb has 0 flags).
 433          *
 434          * If npxthread != NULL, then we have to save the npx h/w state to
 435          * npxthread's pcb and copy it to the requested pcb, or save to the
 436          * requested pcb and reload.  Copying is easier because we would
 437          * have to handle h/w bugs for reloading.  We used to lose the
 438          * parent's npx state for forks by forgetting to reload.
 439          */
 440         movl    PCPU(npxthread),%eax
 441         testl   %eax,%eax
 442         je      1f
 443
 444         pushl   %ecx
 445         movl    TD_PCB(%eax),%eax
 446         leal    PCB_SAVEFPU(%eax),%eax
 447         pushl   %eax
 448         pushl   %eax
 449         call    npxsave
 450         addl    $4,%esp
 451         popl    %eax
 452         popl    %ecx
 453
 454         pushl   $PCB_SAVEFPU_SIZE
 455         leal    PCB_SAVEFPU(%ecx),%ecx
 456         pushl   %ecx
 457         pushl   %eax
 458         call    bcopy
 459         addl    $12,%esp
 460 #endif  /* NNPX > 0 */
 461
 462 1:
 463         ret
 464
 465 /*
 466  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
 467  *
 468  *      Don't bother setting up any regs other then %ebp so backtraces
 469  *      don't die.  This restore function is used to bootstrap into the
 470  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 471  *      switching.
 472  *
 473  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 474  *
 475  *      If we are an AP we have to call ap_init() before jumping to
 476  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 477  *      setting up various ncpu-dependant globaldata fields.  This may
 478  *      happen on UP as well as SMP if we happen to be simulating multiple
 479  *      cpus.
 480  */
 481 ENTRY(cpu_idle_restore)
 482         /* cli */
 483         movl    IdlePTD,%ecx
 484         movl    $0,%ebp
 485         pushl   $0
 486         movl    %ecx,%cr3
 487         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 488         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 489 #ifdef SMP
 490         cmpl    $0,PCPU(cpuid)
 491         je      1f
 492         call    ap_init
 493 1:
 494 #endif
 495         sti
 496         jmp     cpu_idle
 497
 498 /*
 499  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
 500  *
 501  *      Don't bother setting up any regs other then %ebp so backtraces
 502  *      don't die.  This restore function is used to bootstrap into an
 503  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 504  *      after this.
 505  *
 506  *      Since all of our context is on the stack we are reentrant and
 507  *      we can release our critical section and enable interrupts early.
 508  */
 509 ENTRY(cpu_kthread_restore)
 510         sti
 511         movl    IdlePTD,%ecx
 512         movl    TD_PCB(%eax),%edx
 513         movl    $0,%ebp
 514         movl    %ecx,%cr3
 515         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 516         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 517         subl    $TDPRI_CRIT,TD_PRI(%eax)
 518         popl    %eax            /* kthread exit function */
 519         pushl   PCB_EBX(%edx)   /* argument to ESI function */
 520         pushl   %eax            /* set exit func as return address */
 521         movl    PCB_ESI(%edx),%eax
 522         jmp     *%eax
 523
 524 /*
 525  * cpu_lwkt_switch()
 526  *
 527  *      Standard LWKT switching function.  Only non-scratch registers are
 528  *      saved and we don't bother with the MMU state or anything else.
 529  *
 530  *      This function is always called while in a critical section.
 531  *
 532  *      There is a one-instruction window where curthread is the new
 533  *      thread but %esp still points to the old thread's stack, but
 534  *      we are protected by a critical section so it is ok.
 535  *
 536  *      YYY BGL, SPL
 537  */
 538 ENTRY(cpu_lwkt_switch)
 539         movl    4(%esp),%eax
 540         pushl   %ebp
 541         pushl   %ebx
 542         pushl   %esi
 543         pushl   %edi
 544         pushfl
 545         movl    PCPU(curthread),%ebx
 546         pushl   $cpu_lwkt_restore
 547         movl    %esp,TD_SP(%ebx)
 548         movl    %eax,PCPU(curthread)
 549         movl    TD_SP(%eax),%esp
 550
 551         /*
 552          * eax contains new thread, ebx contains old thread.
 553          */
 554         ret
 555
 556 /*
 557  * cpu_lwkt_restore()   (current thread in %eax on entry)
 558  *
 559  *      Standard LWKT restore function.  This function is always called
 560  *      while in a critical section.
 561  *
 562  *      Warning: due to preemption the restore function can be used to
 563  *      'return' to the original thread.  Interrupt disablement must be
 564  *      protected through the switch so we cannot run splz here.
 565  *
 566  *      YYY we theoretically do not need to load IdlePTD into cr3, but if
 567  *      so we need a way to detect when the PTD we are using is being
 568  *      deleted due to a process exiting.
 569  */
 570 ENTRY(cpu_lwkt_restore)
 571         movl    IdlePTD,%ecx    /* YYY borrow but beware desched/cpuchg/exit */
 572         movl    %cr3,%edx
 573         cmpl    %ecx,%edx
 574         je      1f
 575         movl    %ecx,%cr3
 576 1:
 577         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 578         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 579         popfl
 580         popl    %edi
 581         popl    %esi
 582         popl    %ebx
 583         popl    %ebp
 584         ret
 585