contrib/binutils-2.24/ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright 1991-2013 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "sysdep.h"
  26 #include "bfd.h"
  27 #include "safe-ctype.h"
  28 #include "bfdlink.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.
  44    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  45 unsigned int lineno = 1;
  46
  47 /* The string we are currently lexing, or NULL if we are reading a
  48    file.  */
  49 const char *lex_string = NULL;
  50
  51 /* Support for flex reading from more than one input file (stream).
  52    `include_stack' is flex's input state for each open file;
  53    `file_name_stack' is the file names.  `lineno_stack' is the current
  54    line numbers.
  55
  56    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  57    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  58
  59 #undef YY_INPUT
  60 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  61
  62 #ifndef YY_NO_UNPUT
  63 #define YY_NO_UNPUT
  64 #endif
  65
  66 #define MAX_INCLUDE_DEPTH 10
  67 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  68 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  71 static unsigned int include_stack_ptr = 0;
  72 static int vers_node_nesting = 0;
  73
  74 static int yy_input (char *, int);
  75 static void comment (void);
  76 static void lex_warn_invalid (char *where, char *what);
  77
  78 /* STATES
  79         EXPRESSION      definitely in an expression
  80         SCRIPT          definitely in a script
  81         BOTH            either EXPRESSION or SCRIPT
  82         DEFSYMEXP       in an argument to -defsym
  83         MRI             in an MRI script
  84         VERS_START      starting a Sun style mapfile
  85         VERS_SCRIPT     a Sun style mapfile
  86         VERS_NODE       a node within a Sun style mapfile
  87 */
  88 #define RTOKEN(x)  {  yylval.token = x; return x; }
  89
  90 /* Some versions of flex want this.  */
  91 #ifndef yywrap
  92 int yywrap (void) { return 1; }
  93 #endif
  94 %}
  95
  96 %a 4000
  97 %o 5000
  98
  99 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 100 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 101 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 102 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 103 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 104 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 105 WHITE           [ \t\n\r]+
 106
 107 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 108
 109 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 110 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 111
 112 %s SCRIPT
 113 %s EXPRESSION
 114 %s BOTH
 115 %s DEFSYMEXP
 116 %s MRI
 117 %s VERS_START
 118 %s VERS_SCRIPT
 119 %s VERS_NODE
 120 %%
 121
 122   if (parser_input != input_selected)
 123     {
 124       /* The first token of the input determines the initial parser state.  */
 125       input_type t = parser_input;
 126       parser_input = input_selected;
 127       switch (t)
 128         {
 129         case input_script: return INPUT_SCRIPT; break;
 130         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 131         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 132         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 133         case input_defsym: return INPUT_DEFSYM; break;
 134         default: abort ();
 135         }
 136     }
 137
 138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 139
 140
 141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 144 <DEFSYMEXP>"="                  { RTOKEN('='); }
 145
 146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 148                                 yylval.bigint.str = NULL;
 149                                 return INT;
 150                         }
 151
 152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 153                                    int ibase ;
 154                                    switch (yytext[yyleng - 1]) {
 155                                     case 'X':
 156                                     case 'x':
 157                                     case 'H':
 158                                     case 'h':
 159                                      ibase = 16;
 160                                      break;
 161                                     case 'O':
 162                                     case 'o':
 163                                      ibase = 8;
 164                                      break;
 165                                     case 'B':
 166                                     case 'b':
 167                                      ibase = 2;
 168                                      break;
 169                                     default:
 170                                      ibase = 10;
 171                                    }
 172                                    yylval.integer = bfd_scan_vma (yytext, 0,
 173                                                                   ibase);
 174                                    yylval.bigint.str = NULL;
 175                                    return INT;
 176                                  }
 177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 178                                   char *s = yytext;
 179                                   int ibase = 0;
 180
 181                                   if (*s == '$')
 182                                     {
 183                                       ++s;
 184                                       ibase = 16;
 185                                     }
 186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 187                                   yylval.bigint.str = NULL;
 188                                   if (yytext[yyleng - 1] == 'M'
 189                                       || yytext[yyleng - 1] == 'm')
 190                                     {
 191                                       yylval.integer *= 1024 * 1024;
 192                                     }
 193                                   else if (yytext[yyleng - 1] == 'K'
 194                                       || yytext[yyleng - 1]=='k')
 195                                     {
 196                                       yylval.integer *= 1024;
 197                                     }
 198                                   else if (yytext[0] == '0'
 199                                            && (yytext[1] == 'x'
 200                                                || yytext[1] == 'X'))
 201                                     {
 202                                       yylval.bigint.str = xstrdup (yytext + 2);
 203                                     }
 204                                   return INT;
 205                                 }
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 244 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 245 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 246 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 247 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 248 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 249 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 250 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 251 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 252 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 256 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 257 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 258 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 259 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 260 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 261 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 262 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 263 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 264 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 265 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 266 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 267 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 268 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 269 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 270 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 271 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 272 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 273 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 274 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 275 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 276 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 277 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 278 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 279 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 280 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 281 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 282 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 283 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 284 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 285 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 286 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 287 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 288 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 289 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 290 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 291 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 292 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 293 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 294 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 295 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 296 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 297 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 298 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 299 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 300 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 301 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 302 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 303 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 304 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 305 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 306 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 307 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 308 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 309 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 310 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 311 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 312 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 313 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 314 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 315 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 316 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 317 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 318 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 319 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 320 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 321 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 322 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 323 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 324 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 325 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 326 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 327 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 328 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 329 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 330 <MRI>"#".*\n?                   { ++ lineno; }
 331 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 332 <MRI>"*".*                      { /* Mri comment line */ }
 333 <MRI>";".*                      { /* Mri comment line */ }
 334 <MRI>"END"                      { RTOKEN(ENDWORD); }
 335 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 336 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 337 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 338 <MRI>"BASE"                     { RTOKEN(BASE); }
 339 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 340 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 341 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 342 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 343 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 344 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 345 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 346 <MRI>"CASE"                     { RTOKEN(CASE); }
 347 <MRI>"START"                    { RTOKEN(START); }
 348 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 349 <MRI>"SECT"                     { RTOKEN(SECT); }
 350 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 351 <MRI>"end"                      { RTOKEN(ENDWORD); }
 352 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 353 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 354 <MRI>"chip"                     { RTOKEN(CHIP); }
 355 <MRI>"base"                     { RTOKEN(BASE); }
 356 <MRI>"alias"                    { RTOKEN(ALIAS); }
 357 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 358 <MRI>"load"                     { RTOKEN(LOAD); }
 359 <MRI>"public"                   { RTOKEN(PUBLIC); }
 360 <MRI>"order"                    { RTOKEN(ORDER); }
 361 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 362 <MRI>"format"                   { RTOKEN(FORMAT); }
 363 <MRI>"case"                     { RTOKEN(CASE); }
 364 <MRI>"extern"                   { RTOKEN(EXTERN); }
 365 <MRI>"start"                    { RTOKEN(START); }
 366 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 367 <MRI>"sect"                     { RTOKEN(SECT); }
 368 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 369
 370 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 371 /* Filename without commas, needed to parse mri stuff */
 372                                  yylval.name = xstrdup (yytext);
 373                                   return NAME;
 374                                 }
 375
 376
 377 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
 378                                  yylval.name = xstrdup (yytext);
 379                                   return NAME;
 380                                 }
 381 <BOTH>"-l"{FILENAMECHAR}+ {
 382                                   yylval.name = xstrdup (yytext + 2);
 383                                   return LNAME;
 384                                 }
 385 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 386                                  yylval.name = xstrdup (yytext);
 387                                   return NAME;
 388                                 }
 389 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 390                                   yylval.name = xstrdup (yytext + 2);
 391                                   return LNAME;
 392                                 }
 393 <SCRIPT>{WILDCHAR}* {
 394                 /* Annoyingly, this pattern can match comments, and we have
 395                    longest match issues to consider.  So if the first two
 396                    characters are a comment opening, put the input back and
 397                    try again.  */
 398                 if (yytext[0] == '/' && yytext[1] == '*')
 399                   {
 400                     yyless (2);
 401                     comment ();
 402                   }
 403                 else
 404                   {
 405                     yylval.name = xstrdup (yytext);
 406                     return NAME;
 407                   }
 408         }
 409
 410 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 411                                         /* No matter the state, quotes
 412                                            give what's inside */
 413                                         yylval.name = xstrdup (yytext + 1);
 414                                         yylval.name[yyleng - 2] = 0;
 415                                         return NAME;
 416                                 }
 417 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 418 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 419
 420 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 421
 422 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 423
 424 <VERS_NODE>local                { RTOKEN(LOCAL); }
 425
 426 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 427
 428 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 429                                   return VERS_IDENTIFIER; }
 430
 431 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 432                                   return VERS_TAG; }
 433
 434 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 435
 436 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 437                                   vers_node_nesting = 0;
 438                                   return *yytext;
 439                                 }
 440 <VERS_SCRIPT>"}"                { return *yytext; }
 441 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 442 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 443                                     BEGIN(VERS_SCRIPT);
 444                                   return *yytext;
 445                                 }
 446
 447 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 448
 449 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 450
 451 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 452
 453 <<EOF>> {
 454   include_stack_ptr--;
 455   if (include_stack_ptr == 0)
 456     yyterminate ();
 457   else
 458     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 459
 460   lineno = lineno_stack[include_stack_ptr];
 461   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 462
 463   return END;
 464 }
 465
 466 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 467 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 468
 469 %%
 470 \f
 471
 472 /* Switch flex to reading script file NAME, open on FILE,
 473    saving the current input info on the include stack.  */
 474
 475 void
 476 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 477 {
 478   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 479     {
 480       einfo ("%F:includes nested too deeply\n");
 481     }
 482   file_name_stack[include_stack_ptr] = name;
 483   lineno_stack[include_stack_ptr] = lineno;
 484   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 485   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 486
 487   include_stack_ptr++;
 488   lineno = 1;
 489   input_flags.sysrooted = sysrooted;
 490   yyin = file;
 491   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 492 }
 493
 494 /* Return a newly created flex input buffer containing STRING,
 495    which is SIZE bytes long.  */
 496
 497 static YY_BUFFER_STATE
 498 yy_create_string_buffer (const char *string, size_t size)
 499 {
 500   YY_BUFFER_STATE b;
 501
 502   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 503   b = malloc (sizeof (struct yy_buffer_state));
 504   b->yy_input_file = 0;
 505   b->yy_buf_size = size;
 506
 507   /* yy_ch_buf has to be 2 characters longer than the size given because
 508      we need to put in 2 end-of-buffer characters.  */
 509   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 510
 511   b->yy_ch_buf[0] = '\n';
 512   strcpy (b->yy_ch_buf+1, string);
 513   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 514   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 515   b->yy_n_chars = size+1;
 516   b->yy_buf_pos = &b->yy_ch_buf[1];
 517
 518   b->yy_is_our_buffer = 1;
 519   b->yy_is_interactive = 0;
 520   b->yy_at_bol = 1;
 521   b->yy_fill_buffer = 0;
 522
 523   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 524      a flex internal interface in the first place!  */
 525 #ifdef YY_BUFFER_NEW
 526   b->yy_buffer_status = YY_BUFFER_NEW;
 527 #else
 528   b->yy_eof_status = EOF_NOT_SEEN;
 529 #endif
 530
 531   return b;
 532 }
 533
 534 /* Switch flex to reading from STRING, saving the current input info
 535    on the include stack.  */
 536
 537 void
 538 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 539 {
 540   YY_BUFFER_STATE tmp;
 541
 542   yy_init = 0;
 543   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 544     {
 545       einfo("%F: macros nested too deeply\n");
 546     }
 547   file_name_stack[include_stack_ptr] = fake_filename;
 548   lineno_stack[include_stack_ptr] = lineno;
 549   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 550   include_stack_ptr++;
 551   lineno = count;
 552   tmp = yy_create_string_buffer (string, strlen (string));
 553   yy_switch_to_buffer (tmp);
 554 }
 555 \f
 556 /* Functions to switch to a different flex start condition,
 557    saving the current start condition on `state_stack'.  */
 558
 559 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 560 static int *state_stack_p = state_stack;
 561
 562 void
 563 ldlex_script (void)
 564 {
 565   *(state_stack_p)++ = yy_start;
 566   BEGIN (SCRIPT);
 567 }
 568
 569 void
 570 ldlex_mri_script (void)
 571 {
 572   *(state_stack_p)++ = yy_start;
 573   BEGIN (MRI);
 574 }
 575
 576 void
 577 ldlex_version_script (void)
 578 {
 579   *(state_stack_p)++ = yy_start;
 580   BEGIN (VERS_START);
 581 }
 582
 583 void
 584 ldlex_version_file (void)
 585 {
 586   *(state_stack_p)++ = yy_start;
 587   BEGIN (VERS_SCRIPT);
 588 }
 589
 590 void
 591 ldlex_defsym (void)
 592 {
 593   *(state_stack_p)++ = yy_start;
 594   BEGIN (DEFSYMEXP);
 595 }
 596
 597 void
 598 ldlex_expression (void)
 599 {
 600   *(state_stack_p)++ = yy_start;
 601   BEGIN (EXPRESSION);
 602 }
 603
 604 void
 605 ldlex_both (void)
 606 {
 607   *(state_stack_p)++ = yy_start;
 608   BEGIN (BOTH);
 609 }
 610
 611 void
 612 ldlex_popstate (void)
 613 {
 614   yy_start = *(--state_stack_p);
 615 }
 616
 617 /* Return the current file name, or the previous file if no file is
 618    current.  */
 619
 620 const char*
 621 ldlex_filename (void)
 622 {
 623   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 624 }
 625 \f
 626
 627 /* Place up to MAX_SIZE characters in BUF and return
 628    either the number of characters read, or 0 to indicate EOF.  */
 629
 630 static int
 631 yy_input (char *buf, int max_size)
 632 {
 633   int result = 0;
 634   if (YY_CURRENT_BUFFER->yy_input_file)
 635     {
 636       if (yyin)
 637         {
 638           result = fread (buf, 1, max_size, yyin);
 639           if (result < max_size && ferror (yyin))
 640             einfo ("%F%P: read in flex scanner failed\n");
 641         }
 642     }
 643   return result;
 644 }
 645
 646 /* Eat the rest of a C-style comment.  */
 647
 648 static void
 649 comment (void)
 650 {
 651   int c;
 652
 653   while (1)
 654   {
 655     c = input();
 656     while (c != '*' && c != EOF)
 657     {
 658       if (c == '\n')
 659         lineno++;
 660       c = input();
 661     }
 662
 663     if (c == '*')
 664     {
 665       c = input();
 666       while (c == '*')
 667        c = input();
 668       if (c == '/')
 669        break;                   /* found the end */
 670     }
 671
 672     if (c == '\n')
 673       lineno++;
 674
 675     if (c == EOF)
 676     {
 677       einfo( "%F%P: EOF in comment\n");
 678       break;
 679     }
 680   }
 681 }
 682
 683 /* Warn the user about a garbage character WHAT in the input
 684    in context WHERE.  */
 685
 686 static void
 687 lex_warn_invalid (char *where, char *what)
 688 {
 689   char buf[5];
 690
 691   /* If we have found an input file whose format we do not recognize,
 692      and we are therefore treating it as a linker script, and we find
 693      an invalid character, then most likely this is a real object file
 694      of some different format.  Treat it as such.  */
 695   if (ldfile_assumed_script)
 696     {
 697       bfd_set_error (bfd_error_file_not_recognized);
 698       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 699     }
 700
 701   if (! ISPRINT (*what))
 702     {
 703       sprintf (buf, "\\%03o", *(unsigned char *) what);
 704       what = buf;
 705     }
 706
 707   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 708 }