lib/libc/net/nsparser.y

   1 %{
   2 /*      $NetBSD: nsparser.y,v 1.3 1999/01/25 00:16:18 lukem Exp $       */
   3
   4 /*-
   5  * Copyright (c) 1997, 1998, 1999 The NetBSD Foundation, Inc.
   6  * All rights reserved.
   7  *
   8  * This code is derived from software contributed to The NetBSD Foundation
   9  * by Luke Mewburn.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. All advertising materials mentioning features or use of this software
  20  *    must display the following acknowledgement:
  21  *        This product includes software developed by the NetBSD
  22  *        Foundation, Inc. and its contributors.
  23  * 4. Neither the name of The NetBSD Foundation nor the names of its
  24  *    contributors may be used to endorse or promote products derived
  25  *    from this software without specific prior written permission.
  26  *
  27  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  28  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  29  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  30  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  31  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  32  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  33  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  34  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  35  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  36  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  37  * POSSIBILITY OF SUCH DAMAGE.
  38  *
  39  * $FreeBSD: src/lib/libc/net/nsparser.y,v 1.6 2007/05/17 03:33:23 jon Exp $
  40  */
  41
  42 #include "namespace.h"
  43 #define _NS_PRIVATE
  44 #include <nsswitch.h>
  45 #include <stdio.h>
  46 #include <string.h>
  47 #include <syslog.h>
  48 #include "un-namespace.h"
  49
  50 static  void    _nsaddsrctomap(const char *);
  51
  52 static  ns_dbt          curdbt;
  53 static  ns_src          cursrc;
  54 %}
  55
  56 %union {
  57         char *str;
  58         int   mapval;
  59 }
  60
  61 %token  NL
  62 %token  SUCCESS UNAVAIL NOTFOUND TRYAGAIN
  63 %token  RETURN CONTINUE
  64 %token  ERRORTOKEN
  65 %token  <str> STRING
  66
  67 %type   <mapval> Status Action
  68
  69 %%
  70
  71 File
  72         :       /* empty */
  73         | Lines
  74         ;
  75
  76 Lines
  77         : Entry
  78         | Lines Entry
  79         ;
  80
  81 Entry
  82         : NL
  83         | Database ':' NL
  84                 {
  85                         free((char*)curdbt.name);
  86                 }
  87         | Database ':' Srclist NL
  88                 {
  89                         _nsdbtput(&curdbt);
  90                 }
  91         | error NL
  92                 {
  93                         yyerrok;
  94                 }
  95         ;
  96
  97 Database
  98         : STRING
  99                 {
 100                         curdbt.name = yylval.str;
 101                         curdbt.srclist = NULL;
 102                         curdbt.srclistsize = 0;
 103                 }
 104         ;
 105
 106 Srclist
 107         : Item
 108         | Srclist Item
 109         ;
 110
 111 Item
 112         : STRING
 113                 {
 114                         cursrc.flags = NS_TERMINATE;
 115                         _nsaddsrctomap($1);
 116                 }
 117         | STRING '[' { cursrc.flags = NS_SUCCESS; } Criteria ']'
 118                 {
 119                         _nsaddsrctomap($1);
 120                 }
 121         ;
 122
 123 Criteria
 124         : Criterion
 125         | Criteria Criterion
 126         ;
 127
 128 Criterion
 129         : Status '=' Action
 130                 {
 131                         if ($3)      /* if action == RETURN set RETURN bit */
 132                                 cursrc.flags |= $1;
 133                         else         /* else unset it */
 134                                 cursrc.flags &= ~$1;
 135                 }
 136         ;
 137
 138 Status
 139         : SUCCESS       { $$ = NS_SUCCESS; }
 140         | UNAVAIL       { $$ = NS_UNAVAIL; }
 141         | NOTFOUND      { $$ = NS_NOTFOUND; }
 142         | TRYAGAIN      { $$ = NS_TRYAGAIN; }
 143         ;
 144
 145 Action
 146         : RETURN        { $$ = NS_ACTION_RETURN; }
 147         | CONTINUE      { $$ = NS_ACTION_CONTINUE; }
 148         ;
 149
 150 %%
 151
 152 static void
 153 _nsaddsrctomap(const char *elem)
 154 {
 155         int             i, lineno;
 156         extern int      _nsyylineno;
 157         extern char *   _nsyytext;
 158
 159         lineno = _nsyylineno - (*_nsyytext == '\n' ? 1 : 0);
 160         if (curdbt.srclistsize > 0) {
 161                 if (((strcasecmp(elem, NSSRC_COMPAT) == 0) &&
 162                     (strcasecmp(curdbt.srclist[0].name, NSSRC_CACHE) != 0)) ||
 163                     (strcasecmp(curdbt.srclist[0].name, NSSRC_COMPAT) == 0)) {
 164                         syslog(LOG_ERR,
 165             "NSSWITCH(nsparser): %s line %d: 'compat' used with sources, other than 'cache'",
 166                             _PATH_NS_CONF, lineno);
 167                         free((void*)elem);
 168                         return;
 169                 }
 170         }
 171         for (i = 0; i < curdbt.srclistsize; i++) {
 172                 if (strcasecmp(curdbt.srclist[i].name, elem) == 0) {
 173                         syslog(LOG_ERR,
 174                        "NSSWITCH(nsparser): %s line %d: duplicate source '%s'",
 175                             _PATH_NS_CONF, lineno, elem);
 176                         free((void*)elem);
 177                         return;
 178                 }
 179         }
 180         cursrc.name = elem;
 181         _nsdbtaddsrc(&curdbt, &cursrc);
 182 }