lib/libc/x86_64/gen/modf.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Sean Eric Fagan.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  *      from: @(#)modf.s        5.5 (Berkeley) 3/18/91
  33  * $NetBSD: modf.S,v 1.5 1997/07/16 14:37:18 christos Exp $
  34  * $FreeBSD: src/lib/libc/amd64/gen/modf.S,v 1.4 2008/11/02 01:10:54 peter Exp $
  35  */
  36
  37 #include <machine/asm.h>
  38
  39 /*
  40  * modf(value, iptr): return fractional part of value, and stores the
  41  * integral part into iptr (a pointer to double).
  42  *
  43  * Written by Sean Eric Fagan (sef@kithrup.COM)
  44  * Sun Mar 11 20:27:30 PST 1990
  45  */
  46
  47 /* With CHOP mode on, frndint behaves as TRUNC does.  Useful. */
  48 ENTRY(modf)
  49
  50         /*
  51          * Set chop mode.
  52          */
  53         fnstcw  -12(%rsp)
  54         movw    -12(%rsp),%dx
  55         orw     $3072,%dx
  56         movw    %dx,-16(%rsp)
  57         fldcw   -16(%rsp)
  58
  59         /*
  60          * Get integral part.
  61          */
  62         movsd   %xmm0,-24(%rsp)
  63         fldl    -24(%rsp)
  64         frndint
  65         fstpl   -8(%rsp)
  66
  67         /*
  68          * Restore control word.
  69          */
  70         fldcw   -12(%rsp)
  71
  72         /*
  73          * Store integral part.
  74          */
  75         movsd   -8(%rsp),%xmm0
  76         movsd   %xmm0,(%rdi)
  77
  78         /*
  79          * Get fractional part and return it.
  80          */
  81         fldl    -24(%rsp)
  82         fsubl   -8(%rsp)
  83         fstpl   -8(%rsp)
  84         movsd   -8(%rsp),%xmm0
  85
  86         ret
  87 END(modf)