contrib/libf2c/libF77/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   3 #   Contributed by Dave Love (d.love@dl.ac.uk).
   4 #
   5 #This file is part of GNU Fortran.
   6 #
   7 #GNU Fortran is free software; you can redistribute it and/or modify
   8 #it under the terms of the GNU General Public License as published by
   9 #the Free Software Foundation; either version 2, or (at your option)
  10 #any later version.
  11 #
  12 #GNU Fortran is distributed in the hope that it will be useful,
  13 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #GNU General Public License for more details.
  16 #
  17 #You should have received a copy of the GNU General Public License
  18 #along with GNU Fortran; see the file COPYING.  If not, write to
  19 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  20 #02111-1307, USA.
  21
  22 AC_PREREQ(2.12.1)
  23 AC_INIT(getarg_.c)
  24
  25 dnl Checks for programs.
  26 # For g77 we'll set CC to point at the built gcc, but this will get it into
  27 # the makefiles
  28 AC_PROG_CC
  29
  30 test "$AR" || AR=ar
  31 AC_SUBST(AR)
  32 AC_PROG_MAKE_SET
  33
  34 dnl Checks for libraries.
  35
  36 dnl Checks for header files.
  37 # Sanity check for the cross-compilation case:
  38 AC_CHECK_HEADER(stdio.h,:,
  39   [AC_MSG_ERROR([Can't find stdio.h.
  40 You must have a usable C system for the target already installed, at least
  41 including headers and, preferably, the library, before you can configure
  42 the G77 runtime system.  If necessary, install gcc now with \`LANGUAGES=c',
  43 then the target library, then build with \`LANGUAGES=f77'.])])
  44
  45 AC_HEADER_STDC
  46 dnl We could do this if we didn't know we were using gcc
  47 dnl AC_MSG_CHECKING(for prototype-savvy compiler)
  48 dnl AC_CACHE_VAL(g77_cv_sys_proto,
  49 dnl   [AC_TRY_LINK(,
  50 dnl dnl looks screwy because TRY_LINK expects a function body
  51 dnl    [return 0;} int foo (int * bar) {],
  52 dnl    g77_cv_sys_proto=yes,
  53 dnl    [g77_cv_sys_proto=no
  54 dnl     AC_DEFINE(KR_headers)])])
  55 dnl AC_MSG_RESULT($g77_cv_sys_proto)
  56
  57 AC_MSG_CHECKING(for posix)
  58 AC_CACHE_VAL(g77_cv_header_posix,
  59   AC_EGREP_CPP(yes,
  60   [#include <sys/types.h>
  61 #include <unistd.h>
  62 #ifdef _POSIX_VERSION
  63   yes
  64 #endif
  65 ],
  66   g77_cv_header_posix=yes,
  67   g77_cv_header_posix=no))
  68 AC_MSG_RESULT($g77_cv_header_posix)
  69
  70 # We can rely on the GNU library being posix-ish.  I guess checking the
  71 # header isn't actually like checking the functions, though...
  72 AC_MSG_CHECKING(for GNU library)
  73 AC_CACHE_VAL(g77_cv_lib_gnu,
  74   AC_EGREP_CPP(yes,
  75     [#include <stdio.h>
  76 #ifdef __GNU_LIBRARY__
  77   yes
  78 #endif
  79 ],
  80   g77_cv_lib_gnu=yes, g77_cv_lib_gnu=no))
  81 AC_MSG_RESULT($g77_cv_lib_gnu)
  82
  83 dnl Checks for library functions.
  84 AC_TYPE_SIGNAL
  85 # we'll get atexit by default
  86 if test $ac_cv_header_stdc != yes; then
  87 AC_CHECK_FUNC(atexit,
  88   AC_DEFINE(onexit,atexit),dnl just in case
  89   [AC_DEFINE(NO_ONEXIT)
  90   AC_CHECK_FUNC(onexit,,
  91     [AC_CHECK_FUNC(on_exit,
  92      AC_DEFINE(onexit,on_exit),)])])
  93 else true
  94 fi
  95
  96 dnl perhaps should check also for remainder
  97 dnl Unfortunately, the message implies we're just checking for -lm...
  98 AC_CHECK_LIB(m,drem,AC_DEFINE(IEEE_drem))
  99
 100 AC_DEFINE(Skip_f2c_Undefs)
 101
 102 AC_OUTPUT(Makefile)
 103
 104 dnl Local Variables:
 105 dnl comment-start: "dnl "
 106 dnl comment-end: ""
 107 dnl comment-start-skip: "\\bdnl\\b\\s *"
 108 dnl End: