lib/libc/i386/string/strcmp.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software withough specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/strcmp.S,v 1.5 1999/08/27 23:59:33 peter Exp $
  31  * $DragonFly: src/lib/libc/i386/string/strcmp.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  32  *
  33  * $FreeBSD: src/lib/libc/i386/string/strcmp.S,v 1.5 1999/08/27 23:59:33 peter Exp $
  34  */
  35
  36 #include "DEFS.h"
  37
  38 /*
  39  * strcmp(s1, s2)
  40  *      return an integer greater than, equal to, or less than 0,
  41  *      according as string s1 is greater than, equal to, or less
  42  *      than the string s2.
  43  *
  44  * %eax - pointer to s1
  45  * %edx - pointer to s2
  46  *
  47  * Written by:
  48  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  49  */
  50
  51 /*
  52  * I've unrolled the loop eight times: large enough to make a
  53  * significant difference, and small enough not to totally trash the
  54  * cashe.
  55  */
  56
  57 ENTRY(strcmp)
  58         movl    0x04(%esp),%eax
  59         movl    0x08(%esp),%edx
  60         jmp     L2                      /* Jump into the loop! */
  61
  62         .align  2,0x90
  63 L1:     incl    %eax
  64         incl    %edx
  65 L2:     movb    (%eax),%cl
  66         testb   %cl,%cl
  67         je      L3
  68         cmpb    %cl,(%edx)
  69         jne     L3
  70         incl    %eax
  71         incl    %edx
  72         movb    (%eax),%cl
  73         testb   %cl,%cl
  74         je      L3
  75         cmpb    %cl,(%edx)
  76         jne     L3
  77         incl    %eax
  78         incl    %edx
  79         movb    (%eax),%cl
  80         testb   %cl,%cl
  81         je      L3
  82         cmpb    %cl,(%edx)
  83         jne     L3
  84         incl    %eax
  85         incl    %edx
  86         movb    (%eax),%cl
  87         testb   %cl,%cl
  88         je      L3
  89         cmpb    %cl,(%edx)
  90         jne     L3
  91         incl    %eax
  92         incl    %edx
  93         movb    (%eax),%cl
  94         testb   %cl,%cl
  95         je      L3
  96         cmpb    %cl,(%edx)
  97         jne     L3
  98         incl    %eax
  99         incl    %edx
 100         movb    (%eax),%cl
 101         testb   %cl,%cl
 102         je      L3
 103         cmpb    %cl,(%edx)
 104         jne     L3
 105         incl    %eax
 106         incl    %edx
 107         movb    (%eax),%cl
 108         testb   %cl,%cl
 109         je      L3
 110         cmpb    %cl,(%edx)
 111         jne     L3
 112         incl    %eax
 113         incl    %edx
 114         movb    (%eax),%cl
 115         testb   %cl,%cl
 116         je      L3
 117         cmpb    %cl,(%edx)
 118         je      L1
 119         .align 2, 0x90
 120 L3:     movzbl  (%eax),%eax             /* unsigned comparison */
 121         movzbl  (%edx),%edx
 122         subl    %edx,%eax
 123         ret