lib/libcr/i386/string/memset.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/memset.S,v 1.5 1999/08/27 23:59:32 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/memset.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  32  *
  33  * $FreeBSD: src/lib/libc/i386/string/memset.S,v 1.5 1999/08/27 23:59:32 peter Exp $
  34  */
  35
  36 #include "DEFS.h"
  37
  38 /*
  39  * memset(void *b, int c, size_t len)
  40  *      write len bytes of value c (converted to an unsigned char) to
  41  *      the string b.
  42  *
  43  * Written by:
  44  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  45  */
  46
  47 ENTRY(memset)
  48         pushl   %edi
  49         pushl   %ebx
  50         movl    12(%esp),%edi
  51         movzbl  16(%esp),%eax           /* unsigned char, zero extend */
  52         movl    20(%esp),%ecx
  53         pushl   %edi                    /* push address of buffer */
  54
  55         cld                             /* set fill direction forward */
  56
  57         /*
  58          * if the string is too short, it's really not worth the overhead
  59          * of aligning to word boundries, etc.  So we jump to a plain
  60          * unaligned set.
  61          */
  62         cmpl    $0x0f,%ecx
  63         jle     L1
  64
  65         movb    %al,%ah                 /* copy char to all bytes in word */
  66         movl    %eax,%edx
  67         sall    $16,%eax
  68         orl     %edx,%eax
  69
  70         movl    %edi,%edx               /* compute misalignment */
  71         negl    %edx
  72         andl    $3,%edx
  73         movl    %ecx,%ebx
  74         subl    %edx,%ebx
  75
  76         movl    %edx,%ecx               /* set until word aligned */
  77         rep
  78         stosb
  79
  80         movl    %ebx,%ecx
  81         shrl    $2,%ecx                 /* set by words */
  82         rep
  83         stosl
  84
  85         movl    %ebx,%ecx               /* set remainder by bytes */
  86         andl    $3,%ecx
  87 L1:     rep
  88         stosb
  89
  90         popl    %eax                    /* pop address of buffer */
  91         popl    %ebx
  92         popl    %edi
  93         ret