lib/libcr/i386/string/swab.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/swab.S,v 1.5 1999/08/27 23:59:35 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/swab.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  32  *
  33  * $FreeBSD: src/lib/libc/i386/string/swab.S,v 1.5 1999/08/27 23:59:35 peter Exp $
  34  */
  35
  36 #include "DEFS.h"
  37
  38 /*
  39  * void
  40  * swab (const void *src, void *dst, size_t len)
  41  *      copy len bytes from src to dst, swapping adjacent bytes
  42  *
  43  * On the i486, this code is negligibly faster than the code generated
  44  * by gcc at about half the size.  If my i386 databook is correct, it
  45  * should be considerably faster than the gcc code on a i386.
  46  *
  47  * Written by:
  48  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  49  */
  50
  51 ENTRY(swab)
  52         pushl   %esi
  53         pushl   %edi
  54         movl    12(%esp),%esi
  55         movl    16(%esp),%edi
  56         movl    20(%esp),%ecx
  57
  58         cld                             # set direction forward
  59
  60         shrl    $1,%ecx
  61         testl   $7,%ecx                 # copy first group of 1 to 7 words
  62         jz      L2                      # while swaping alternate bytes.
  63         .align  2,0x90
  64 L1:     lodsw
  65         rorw    $8,%ax
  66         stosw
  67         decl    %ecx
  68         testl   $7,%ecx
  69         jnz     L1
  70
  71 L2:     shrl    $3,%ecx                 # copy remainder 8 words at a time
  72         jz      L4                      # while swapping alternate bytes.
  73         .align  2,0x90
  74 L3:     lodsw
  75         rorw    $8,%ax
  76         stosw
  77         lodsw
  78         rorw    $8,%ax
  79         stosw
  80         lodsw
  81         rorw    $8,%ax
  82         stosw
  83         lodsw
  84         rorw    $8,%ax
  85         stosw
  86         lodsw
  87         rorw    $8,%ax
  88         stosw
  89         lodsw
  90         rorw    $8,%ax
  91         stosw
  92         lodsw
  93         rorw    $8,%ax
  94         stosw
  95         lodsw
  96         rorw    $8,%ax
  97         stosw
  98         decl    %ecx
  99         jnz     L3
 100
 101 L4:     popl    %edi
 102         popl    %esi
 103         ret