sys/boot/i386/pxeldr/pxeldr.s

   1 #
   2 # Copyright (c) 2000 John Baldwin
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms are freely
   6 # permitted provided that the above copyright notice and this
   7 # paragraph and the following disclaimer are duplicated in all
   8 # such forms.
   9 #
  10 # This software is provided "AS IS" and without any express or
  11 # implied warranties, including, without limitation, the implied
  12 # warranties of merchantability and fitness for a particular
  13 # purpose.
  14 #
  15
  16 # $FreeBSD: src/sys/boot/i386/pxeldr/pxeldr.s,v 1.1.2.5 2001/08/10 22:06:18 mp Exp $
  17 # $DragonFly: src/sys/boot/i386/pxeldr/Attic/pxeldr.s,v 1.2 2003/06/17 04:28:18 dillon Exp $
  18
  19 #
  20 # This simple program is a preloader for the normal boot3 loader.  It is simply
  21 # prepended to the beginning of a fully built and btxld'd loader.  It then
  22 # copies the loader to the address boot2 normally loads it, emulates the
  23 # boot[12] environment (protected mode, a bootinfo struct, etc.), and then jumps
  24 # to the start of btxldr to start the boot process.  This method allows a stock
  25 # /boot/loader to be booted over the network via PXE w/o having to write a
  26 # separate PXE-aware client just to load the loader.
  27 #
  28
  29 #
  30 # Memory locations.
  31 #
  32                 .set MEM_PAGE_SIZE,0x1000       # memory page size, 4k
  33                 .set MEM_ARG,0x900              # Arguments at start
  34                 .set MEM_ARG_BTX,0xa100         # Where we move them to so the
  35                                                 #  BTX client can see them
  36                 .set MEM_ARG_SIZE,0x18          # Size of the arguments
  37                 .set MEM_BTX_ADDRESS,0x9000     # where BTX lives
  38                 .set MEM_BTX_ENTRY,0x9010       # where BTX starts to execute
  39                 .set MEM_BTX_OFFSET,MEM_PAGE_SIZE # offset of BTX in the loader
  40                 .set MEM_BTX_CLIENT,0xa000      # where BTX clients live
  41                 .set MEM_BIOS_KEYBOARD,0x496    # BDA byte with keyboard bit
  42 #
  43 # a.out header fields
  44 #
  45                 .set AOUT_TEXT,0x04             # text segment size
  46                 .set AOUT_DATA,0x08             # data segment size
  47                 .set AOUT_BSS,0x0c              # zero'd BSS size
  48                 .set AOUT_SYMBOLS,0x10          # symbol table
  49                 .set AOUT_ENTRY,0x14            # entry point
  50                 .set AOUT_HEADER,MEM_PAGE_SIZE  # size of the a.out header
  51 #
  52 # Flags for kargs->bootflags
  53 #
  54                 .set KARGS_FLAGS_PXE,0x2        # flag to indicate booting from
  55                                                 #  PXE loader
  56 #
  57 # Boot howto bits
  58 #
  59                 .set RB_SERIAL,0x1000           # serial console
  60 #
  61 # Segment selectors.
  62 #
  63                 .set SEL_SDATA,0x8              # Supervisor data
  64                 .set SEL_RDATA,0x10             # Real mode data
  65                 .set SEL_SCODE,0x18             # PM-32 code
  66                 .set SEL_SCODE16,0x20           # PM-16 code
  67 #
  68 # BTX constants
  69 #
  70                 .set INT_SYS,0x30               # BTX syscall interrupt
  71 #
  72 # Bit in MEM_BIOS_KEYBOARD that is set if an enhanced keyboard is present
  73 #
  74                 .set KEYBOARD_BIT,0x10
  75 #
  76 # We expect to be loaded by the BIOS at 0x7c00 (standard boot loader entry
  77 # point)
  78 #
  79                 .code16
  80                 .globl start
  81                 .org 0x0, 0x0
  82 #
  83 # BTX program loader for PXE network booting
  84 #
  85 start:          cld                             # string ops inc
  86                 xorw %ax, %ax                   # zero %ax
  87                 movw %ax, %ss                   # setup the
  88                 movw $start, %sp                #  stack
  89                 movw %es, %cx                   # save PXENV+ segment
  90                 movw %ax, %ds                   # setup the
  91                 movw %ax, %es                   #  data segments
  92                 andl $0xffff, %ecx              # clear upper words
  93                 andl $0xffff, %ebx              #  of %ebx and %ecx
  94                 shll $4, %ecx                   # calculate the offset of
  95                 addl %ebx, %ecx                 #  the PXENV+ struct and
  96                 pushl %ecx                      #  save it on the stack
  97                 movw $welcome_msg, %si          # %ds:(%si) -> welcome message
  98                 callw putstr                    # display the welcome message
  99 #
 100 # Setup the arguments that the loader is expecting from boot[12]
 101 #
 102                 movw $bootinfo_msg, %si         # %ds:(%si) -> boot args message
 103                 callw putstr                    # display the message
 104                 movw $MEM_ARG, %bx              # %ds:(%bx) -> boot args
 105                 movw %bx, %di                   # %es:(%di) -> boot args
 106                 xorl %eax, %eax                 # zero %eax
 107                 movw $(MEM_ARG_SIZE/4), %cx     # Size of arguments in 32-bit
 108                                                 #  dwords
 109                 rep                             # Clear the arguments
 110                 stosl                           #  to zero
 111                 orb $KARGS_FLAGS_PXE, 0x8(%bx)  # kargs->bootflags |=
 112                                                 #  KARGS_FLAGS_PXE
 113                 popl 0xc(%bx)                   # kargs->pxeinfo = *PXENV+
 114 ifdef(`PROBE_KEYBOARD',`
 115 #
 116 # Look at the BIOS data area to see if we have an enhanced keyboard.  If not,
 117 # set the RBX_SERIAL bit in the howto byte.
 118                 testb $KEYBOARD_BIT, MEM_BIOS_KEYBOARD # keyboard present?
 119                 jnz keyb                        # yes, so skip
 120                 orl $RB_SERIAL, (%bx)           # enable serial console
 121 keyb:
 122 ')
 123 #
 124 # Turn on the A20 address line
 125 #
 126                 callw seta20                    # Turn A20 on
 127 #
 128 # Relocate the loader and BTX using a very lazy protected mode
 129 #
 130                 movw $relocate_msg, %si         # Display the
 131                 callw putstr                    #  relocation message
 132                 movl end+AOUT_ENTRY, %edi       # %edi is the destination
 133                 movl $(end+AOUT_HEADER), %esi   # %esi is
 134                                                 #  the start of the text
 135                                                 #  segment
 136                 movl end+AOUT_TEXT, %ecx        # %ecx = length of the text
 137                                                 #  segment
 138                 lgdt gdtdesc                    # setup our own gdt
 139                 cli                             # turn off interrupts
 140                 movl %cr0, %eax                 # Turn on
 141                 orb $0x1, %al                   #  protected
 142                 movl %eax, %cr0                 #  mode
 143                 ljmp $SEL_SCODE,$pm_start       # long jump to clear the
 144                                                 #  instruction pre-fetch queue
 145                 .code32
 146 pm_start:       movw $SEL_SDATA, %ax            # Initialize
 147                 movw %ax, %ds                   #  %ds and
 148                 movw %ax, %es                   #  %es to a flat selector
 149                 rep                             # Relocate the
 150                 movsb                           #  text segment
 151                 addl $(MEM_PAGE_SIZE - 1), %edi # pad %edi out to a new page
 152                 andl $~(MEM_PAGE_SIZE - 1), %edi #  for the data segment
 153                 movl end+AOUT_DATA, %ecx        # size of the data segment
 154                 rep                             # Relocate the
 155                 movsb                           #  data segment
 156                 movl end+AOUT_BSS, %ecx         # size of the bss
 157                 xorl %eax, %eax                 # zero %eax
 158                 addb $3, %cl                    # round %ecx up to
 159                 shrl $2, %ecx                   #  a multiple of 4
 160                 rep                             # zero the
 161                 stosl                           #  bss
 162                 movl end+AOUT_ENTRY, %esi       # %esi -> relocated loader
 163                 addl $MEM_BTX_OFFSET, %esi      # %esi -> BTX in the loader
 164                 movl $MEM_BTX_ADDRESS, %edi     # %edi -> where BTX needs to go
 165                 movzwl 0xa(%esi), %ecx          # %ecx -> length of BTX
 166                 rep                             # Relocate
 167                 movsb                           #  BTX
 168                 ljmp $SEL_SCODE16,$pm_16        # Jump to 16-bit PM
 169                 .code16
 170 pm_16:          movw $SEL_RDATA, %ax            # Initialize
 171                 movw %ax, %ds                   #  %ds and
 172                 movw %ax, %es                   #  %es to a real mode selector
 173                 movl %cr0, %eax                 # Turn off
 174                 andb $~0x1, %al                 #  protected
 175                 movl %eax, %cr0                 #  mode
 176                 ljmp $0,$pm_end                 # Long jump to clear the
 177                                                 #  instruction pre-fetch queue
 178 pm_end:         sti                             # Turn interrupts back on now
 179 #
 180 # Copy the BTX client to MEM_BTX_CLIENT
 181 #
 182                 xorw %ax, %ax                   # zero %ax and set
 183                 movw %ax, %ds                   #  %ds and %es
 184                 movw %ax, %es                   #  to segment 0
 185                 movw $MEM_BTX_CLIENT, %di       # Prepare to relocate
 186                 movw $btx_client, %si           #  the simple btx client
 187                 movw $(btx_client_end-btx_client), %cx # length of btx client
 188                 rep                             # Relocate the
 189                 movsb                           #  simple BTX client
 190 #
 191 # Copy the boot[12] args to where the BTX client can see them
 192 #
 193                 movw $MEM_ARG, %si              # where the args are at now
 194                 movw $MEM_ARG_BTX, %di          # where the args are moving to
 195                 movw $(MEM_ARG_SIZE/4), %cx     # size of the arguments in longs
 196                 rep                             # Relocate
 197                 movsl                           #  the words
 198 #
 199 # Save the entry point so the client can get to it later on
 200 #
 201                 movl end+AOUT_ENTRY, %eax       # load the entry point
 202                 stosl                           # add it to the end of the
 203                                                 #  arguments
 204 #
 205 # Now we just start up BTX and let it do the rest
 206 #
 207                 movw $jump_message, %si         # Display the
 208                 callw putstr                    #  jump message
 209                 ljmp $0,$MEM_BTX_ENTRY          # Jump to the BTX entry point
 210
 211 #
 212 # Display a null-terminated string
 213 #
 214 putstr:         lodsb                           # load %al from %ds:(%si)
 215                 testb %al,%al                   # stop at null
 216                 jnz putc                        # if the char != null, output it
 217                 retw                            # return when null is hit
 218 putc:           movw $0x7,%bx                   # attribute for output
 219                 movb $0xe,%ah                   # BIOS: put_char
 220                 int $0x10                       # call BIOS, print char in %al
 221                 jmp putstr                      # keep looping
 222
 223 #
 224 # Enable A20
 225 #
 226 seta20:         cli                             # Disable interrupts
 227 seta20.1:       inb $0x64,%al                   # Get status
 228                 testb $0x2,%al                  # Busy?
 229                 jnz seta20.1                    # Yes
 230                 movb $0xd1,%al                  # Command: Write
 231                 outb %al,$0x64                  #  output port
 232 seta20.2:       inb $0x64,%al                   # Get status
 233                 testb $0x2,%al                  # Busy?
 234                 jnz seta20.2                    # Yes
 235                 movb $0xdf,%al                  # Enable
 236                 outb %al,$0x60                  #  A20
 237                 sti                             # Enable interrupts
 238                 retw                            # To caller
 239
 240 #
 241 # BTX client to start btxldr
 242 #
 243                 .code32
 244 btx_client:     movl $(MEM_ARG_BTX-MEM_BTX_CLIENT+MEM_ARG_SIZE-4), %esi
 245                                                 # %ds:(%esi) -> end
 246                                                 #  of boot[12] args
 247                 movl $(MEM_ARG_SIZE/4), %ecx    # Number of words to push
 248                 std                             # Go backwards
 249 push_arg:       lodsl                           # Read argument
 250                 pushl %eax                      # Push it onto the stack
 251                 loop push_arg                   # Push all of the arguments
 252                 cld                             # In case anyone depends on this
 253                 pushl MEM_ARG_BTX-MEM_BTX_CLIENT+MEM_ARG_SIZE # Entry point of
 254                                                 #  the loader
 255                 pushl %eax                      # Emulate a near call
 256                 movl $0x1, %eax                 # 'exec' system call
 257                 int $INT_SYS                    # BTX system call
 258 btx_client_end:
 259                 .code16
 260
 261                 .p2align 4
 262 #
 263 # Global descriptor table.
 264 #
 265 gdt:            .word 0x0,0x0,0x0,0x0           # Null entry
 266                 .word 0xffff,0x0,0x9200,0xcf    # SEL_SDATA
 267                 .word 0xffff,0x0,0x9200,0x0     # SEL_RDATA
 268                 .word 0xffff,0x0,0x9a00,0xcf    # SEL_SCODE (32-bit)
 269                 .word 0xffff,0x0,0x9a00,0x8f    # SEL_SCODE16 (16-bit)
 270 gdt.1:
 271 #
 272 # Pseudo-descriptors.
 273 #
 274 gdtdesc:        .word gdt.1-gdt-1               # Limit
 275                 .long gdt                       # Base
 276
 277 welcome_msg:    .asciz  "PXE Loader 1.00\r\n\n"
 278 bootinfo_msg:   .asciz  "Building the boot loader arguments\r\n"
 279 relocate_msg:   .asciz  "Relocating the loader and the BTX\r\n"
 280 jump_message:   .asciz  "Starting the BTX loader\r\n"
 281
 282                 .p2align 4
 283 end: