sys/boot/pc32/libi386/amd64_tramp.S

   1 /*-
   2  * Copyright (c) 2003  Peter Wemm <peter@FreeBSD.org>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD: src/sys/boot/i386/libi386/amd64_tramp.S,v 1.2 2003/05/17 00:30:51 peter Exp $
  27  * $DragonFly: src/sys/boot/pc32/libi386/amd64_tramp.S,v 1.3 2004/07/19 23:30:37 dillon Exp $
  28  */
  29
  30 #include "../bootasm.h"
  31
  32 /*
  33  * Quick and dirty trampoline to get into 64 bit (long) mode and running
  34  * with paging enabled so that we enter the kernel at its linked address.
  35  */
  36 #define MSR_EFER        0xc0000080
  37 #define EFER_LME        0x00000100
  38 #define CR4_PAE         0x00000020
  39 #define CR4_PSE         0x00000010
  40 #define CR0_PG          0x80000000
  41
  42 /* GRRR. Deal with BTX that links us for a non-zero location */
  43 #define VTOP(x) ((x) + MEM_BTX_USR)
  44
  45         .data
  46
  47         .p2align 12,0x40
  48
  49         .globl  PT4
  50 PT4:
  51         .space  0x1000
  52         .globl  PT3
  53 PT3:
  54         .space  0x1000
  55         .globl  PT2
  56 PT2:
  57         .space  0x1000
  58
  59 gdtdesc:
  60         .word   gdtend - gdt
  61         .long   VTOP(gdt)               # low
  62         .long   0                       # high
  63
  64 gdt:
  65         .long   0                       # null descriptor
  66         .long   0
  67         .long   0x00000000              # %cs
  68         .long   0x00209800
  69         .long   0x00000000              # %ds
  70         .long   0x00008000
  71 gdtend:
  72
  73         .text
  74         .code32
  75
  76         .globl  amd64_tramp
  77 amd64_tramp:
  78         /* Be sure that interrupts are disabled */
  79         cli
  80
  81         /* Turn on EFER.LME */
  82         movl    $MSR_EFER, %ecx
  83         rdmsr
  84         orl     $EFER_LME, %eax
  85         wrmsr
  86
  87         /* Turn on PAE */
  88         movl    %cr4, %eax
  89         orl     $(CR4_PAE | CR4_PSE), %eax
  90         movl    %eax, %cr4
  91
  92         /* Set %cr3 for PT4 */
  93         movl    $VTOP(PT4), %eax
  94         movl    %eax, %cr3
  95
  96         /* Turn on paging (implicitly sets EFER.LMA) */
  97         movl    %cr0, %eax
  98         orl     $CR0_PG, %eax
  99         movl    %eax, %cr0
 100
 101         /* Now we're in compatibility mode. set %cs for long mode */
 102         movl    $VTOP(gdtdesc), %eax
 103         movl    VTOP(entry_hi), %esi
 104         movl    VTOP(entry_lo), %edi
 105         lgdt    (%eax)
 106         ljmp    $0x8, $VTOP(longmode)
 107
 108         .code64
 109 longmode:
 110         /* We're still running V=P, jump to entry point */
 111         movl    %esi, %eax
 112         salq    $32, %rax
 113         orq     %rdi, %rax
 114         pushq   %rax
 115         ret