sys/i386/isa/icu_vector.s

   1 /*
   2  *      from: vector.s, 386BSD 0.1 unknown origin
   3  * $FreeBSD: src/sys/i386/isa/icu_vector.s,v 1.14.2.2 2000/07/18 21:12:42 dfr Exp $
   4  * $DragonFly: src/sys/i386/isa/Attic/icu_vector.s,v 1.14 2003/08/25 19:50:32 dillon Exp $
   5  */
   6
   7 /*
   8  * modified for PC98 by Kakefuda
   9  */
  10
  11 #ifdef PC98
  12 #define ICU_IMR_OFFSET          2       /* IO_ICU{1,2} + 2 */
  13 #else
  14 #define ICU_IMR_OFFSET          1       /* IO_ICU{1,2} + 1 */
  15 #endif
  16
  17 #define ICU_EOI                 0x20    /* XXX - define elsewhere */
  18
  19 #define IRQ_LBIT(irq_num)       (1 << (irq_num))
  20 #define IRQ_BIT(irq_num)        (1 << ((irq_num) % 8))
  21 #define IRQ_BYTE(irq_num)       ((irq_num) >> 3)
  22
  23 #ifdef AUTO_EOI_1
  24 #define ENABLE_ICU1             /* use auto-EOI to reduce i/o */
  25 #define OUTB_ICU1
  26 #else
  27 #define ENABLE_ICU1                                                     \
  28         movb    $ICU_EOI,%al ;  /* as soon as possible send EOI ... */  \
  29         OUTB_ICU1 ;             /* ... to clear in service bit */       \
  30
  31 #define OUTB_ICU1                                                       \
  32         outb    %al,$IO_ICU1 ;                                          \
  33
  34 #endif
  35
  36 #ifdef AUTO_EOI_2
  37 /*
  38  * The data sheet says no auto-EOI on slave, but it sometimes works.
  39  */
  40 #define ENABLE_ICU1_AND_2       ENABLE_ICU1
  41 #else
  42 #define ENABLE_ICU1_AND_2                                               \
  43         movb    $ICU_EOI,%al ;  /* as above */                          \
  44         outb    %al,$IO_ICU2 ;  /* but do second icu first ... */       \
  45         OUTB_ICU1 ;     /* ... then first icu (if !AUTO_EOI_1) */       \
  46
  47 #endif
  48
  49 /*
  50  * Macro helpers
  51  */
  52 #define PUSH_FRAME                                                      \
  53         pushl   $0 ;            /* dummy error code */                  \
  54         pushl   $0 ;            /* dummy trap type */                   \
  55         pushal ;                /* 8 registers */                       \
  56         pushl   %ds ;                                                   \
  57         pushl   %es ;                                                   \
  58         pushl   %fs ;                                                   \
  59         mov     $KDSEL,%ax ;                                            \
  60         mov     %ax,%ds ;                                               \
  61         mov     %ax,%es ;                                               \
  62         mov     $KPSEL,%ax ;                                            \
  63         mov     %ax,%fs ;                                               \
  64
  65 #define PUSH_DUMMY                                                      \
  66         pushfl ;                /* phys int frame / flags */            \
  67         pushl %cs ;             /* phys int frame / cs */               \
  68         pushl   12(%esp) ;      /* original caller eip */               \
  69         pushl   $0 ;            /* dummy error code */                  \
  70         pushl   $0 ;            /* dummy trap type */                   \
  71         subl    $12*4,%esp ;    /* pushal + 3 seg regs (dummy) + CPL */ \
  72
  73 /*
  74  * Warning: POP_FRAME can only be used if there is no chance of a
  75  * segment register being changed (e.g. by procfs), which is why syscalls
  76  * have to use doreti.
  77  */
  78 #define POP_FRAME                                                       \
  79         popl    %fs ;                                                   \
  80         popl    %es ;                                                   \
  81         popl    %ds ;                                                   \
  82         popal ;                                                         \
  83         addl    $2*4,%esp ;     /* dummy trap & error codes */          \
  84
  85 #define POP_DUMMY                                                       \
  86         addl    $17*4,%esp ;                                            \
  87
  88 #define MASK_IRQ(icu, irq_num)                                          \
  89         movb    imen + IRQ_BYTE(irq_num),%al ;                          \
  90         orb     $IRQ_BIT(irq_num),%al ;                                 \
  91         movb    %al,imen + IRQ_BYTE(irq_num) ;                          \
  92         outb    %al,$icu+ICU_IMR_OFFSET ;                               \
  93
  94 #define UNMASK_IRQ(icu, irq_num)                                        \
  95         movb    imen + IRQ_BYTE(irq_num),%al ;                          \
  96         andb    $~IRQ_BIT(irq_num),%al ;                                \
  97         movb    %al,imen + IRQ_BYTE(irq_num) ;                          \
  98         outb    %al,$icu+ICU_IMR_OFFSET ;                               \
  99
 100 /*
 101  * Fast interrupt call handlers run in the following sequence:
 102  *
 103  *      - Push the trap frame required by doreti.
 104  *      - Mask the interrupt and reenable its source.
 105  *      - If we cannot take the interrupt set its fpending bit and
 106  *        doreti.
 107  *      - If we can take the interrupt clear its fpending bit,
 108  *        call the handler, then unmask the interrupt and doreti.
 109  *
 110  *      YYY can cache gd base pointer instead of using hidden %fs
 111  *      prefixes.
 112  */
 113
 114 #define FAST_INTR(irq_num, vec_name, icu, enable_icus)                  \
 115         .text ;                                                         \
 116         SUPERALIGN_TEXT ;                                               \
 117 IDTVEC(vec_name) ;                                                      \
 118         PUSH_FRAME ;                                                    \
 119         FAKE_MCOUNT(13*4(%esp)) ;                                       \
 120         MASK_IRQ(icu, irq_num) ;                                        \
 121         enable_icus ;                                                   \
 122         movl    PCPU(curthread),%ebx ;                                  \
 123         movl    TD_CPL(%ebx),%eax ;     /* save the cpl for doreti */   \
 124         pushl   %eax ;                                                  \
 125         cmpl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 126         jge     1f ;                                                    \
 127         testl   $IRQ_LBIT(irq_num), %eax ;                              \
 128         jz      2f ;                                                    \
 129 1: ;                                                                    \
 130         /* set pending bit and return, leave interrupt masked */        \
 131         orl     $IRQ_LBIT(irq_num),PCPU(fpending) ;                     \
 132         orl     $RQF_INTPEND, PCPU(reqflags) ;                          \
 133         jmp     5f ;                                                    \
 134 2: ;                                                                    \
 135         /* clear pending bit, run handler */                            \
 136         incl    PCPU(intr_nesting_level) ;                              \
 137         addl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 138         andl    $~IRQ_LBIT(irq_num),PCPU(fpending) ;                    \
 139         pushl   intr_unit + (irq_num) * 4 ;                             \
 140         call    *intr_handler + (irq_num) * 4 ;                         \
 141         addl    $4,%esp ;                                               \
 142         subl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 143         decl    PCPU(intr_nesting_level) ;                              \
 144         incl    PCPU(cnt)+V_INTR ; /* book-keeping YYY make per-cpu */  \
 145         movl    intr_countp + (irq_num) * 4,%eax ;                      \
 146         incl    (%eax) ;                                                \
 147         UNMASK_IRQ(icu, irq_num) ;                                      \
 148 5: ;                                                                    \
 149         MEXITCOUNT ;                                                    \
 150         jmp     doreti ;                                                \
 151
 152 /*
 153  * Restart fast interrupt held up by critical section or cpl.
 154  *
 155  *      - Push a dummy trap frame as required by doreti.
 156  *      - The interrupt source is already masked.
 157  *      - Clear the fpending bit
 158  *      - Run the handler
 159  *      - Unmask the interrupt
 160  *      - Pop the dummy frame and do a normal return
 161  *
 162  *      YYY can cache gd base pointer instead of using hidden %fs
 163  *      prefixes.
 164  */
 165 #define FAST_UNPEND(irq_num, vec_name, icu)                             \
 166         .text ;                                                         \
 167         SUPERALIGN_TEXT ;                                               \
 168 IDTVEC(vec_name) ;                                                      \
 169         pushl   %ebp ;                                                  \
 170         movl    %esp,%ebp ;                                             \
 171         PUSH_DUMMY ;                                                    \
 172         pushl   intr_unit + (irq_num) * 4 ;                             \
 173         call    *intr_handler + (irq_num) * 4 ;                         \
 174         addl    $4, %esp ;                                              \
 175         incl    PCPU(cnt)+V_INTR ;                                      \
 176         movl    intr_countp + (irq_num) * 4, %eax ;                     \
 177         incl    (%eax) ;                                                \
 178         UNMASK_IRQ(icu, irq_num) ;                                      \
 179         POP_DUMMY ;                                                     \
 180         popl %ebp ;                                                     \
 181         ret ;                                                           \
 182
 183 /*
 184  * Slow interrupt call handlers run in the following sequence:
 185  *
 186  *      - Push the trap frame required by doreti.
 187  *      - Mask the interrupt and reenable its source.
 188  *      - If we cannot take the interrupt set its ipending bit and
 189  *        doreti.  In addition to checking for a critical section
 190  *        and cpl mask we also check to see if the thread is still
 191  *        running.
 192  *      - If we can take the interrupt clear its ipending bit
 193  *        and schedule its thread.  Leave interrupts masked and doreti.
 194  *
 195  *      sched_ithd() is called with interrupts enabled and outside of a
 196  *      critical section (so it can preempt us).
 197  *
 198  *      YYY sched_ithd may preempt us synchronously (fix interrupt stacking)
 199  *
 200  *      Note that intr_nesting_level is not bumped during sched_ithd because
 201  *      blocking allocations are allowed in the preemption case.
 202  *
 203  *      YYY can cache gd base pointer instead of using hidden %fs
 204  *      prefixes.
 205  */
 206
 207 #define INTR(irq_num, vec_name, icu, enable_icus, reg, maybe_extra_ipending) \
 208         .text ;                                                         \
 209         SUPERALIGN_TEXT ;                                               \
 210 IDTVEC(vec_name) ;                                                      \
 211         PUSH_FRAME ;                                                    \
 212         FAKE_MCOUNT(13*4(%esp)) ;                                       \
 213         maybe_extra_ipending ;                                          \
 214         MASK_IRQ(icu, irq_num) ;                                        \
 215         enable_icus ;                                                   \
 216         movl    PCPU(curthread),%ebx ;                                  \
 217         movl    TD_CPL(%ebx), %eax ;                                    \
 218         pushl   %eax ;          /* push CPL for doreti */               \
 219         cmpl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 220         jge     1f ;                                                    \
 221         testl   $IRQ_LBIT(irq_num), %eax ;                              \
 222         jz      2f ;                                                    \
 223 1: ;                                                                    \
 224         /* set the pending bit and return, leave interrupt masked */    \
 225         orl     $IRQ_LBIT(irq_num), PCPU(ipending) ;                    \
 226         orl     $RQF_INTPEND, PCPU(reqflags) ;                          \
 227         jmp     5f ;                                                    \
 228 2: ;                                                                    \
 229         /* set running bit, clear pending bit, run handler */           \
 230         andl    $~IRQ_LBIT(irq_num), PCPU(ipending) ;                   \
 231         sti ;                                                           \
 232         pushl   $irq_num ;                                              \
 233         call    sched_ithd ;                                            \
 234         addl    $4,%esp ;                                               \
 235         incl    PCPU(cnt)+V_INTR ; /* book-keeping YYY make per-cpu */  \
 236         movl    intr_countp + (irq_num) * 4,%eax ;                      \
 237         incl    (%eax) ;                                                \
 238 5: ;                                                                    \
 239         MEXITCOUNT ;                                                    \
 240         jmp     doreti ;                                                \
 241
 242 /*
 243  * Unmask a slow interrupt.  This function is used by interrupt threads
 244  * after they have descheduled themselves to reenable interrupts and
 245  * possibly cause a reschedule to occur.
 246  */
 247
 248 #define INTR_UNMASK(irq_num, vec_name, icu)                             \
 249         .text ;                                                         \
 250         SUPERALIGN_TEXT ;                                               \
 251 IDTVEC(vec_name) ;                                                      \
 252         pushl %ebp ;     /* frame for ddb backtrace */                  \
 253         movl    %esp, %ebp ;                                            \
 254         UNMASK_IRQ(icu, irq_num) ;                                      \
 255         popl %ebp ;                                                     \
 256         ret ;                                                           \
 257
 258 MCOUNT_LABEL(bintr)
 259         FAST_INTR(0,fastintr0, IO_ICU1, ENABLE_ICU1)
 260         FAST_INTR(1,fastintr1, IO_ICU1, ENABLE_ICU1)
 261         FAST_INTR(2,fastintr2, IO_ICU1, ENABLE_ICU1)
 262         FAST_INTR(3,fastintr3, IO_ICU1, ENABLE_ICU1)
 263         FAST_INTR(4,fastintr4, IO_ICU1, ENABLE_ICU1)
 264         FAST_INTR(5,fastintr5, IO_ICU1, ENABLE_ICU1)
 265         FAST_INTR(6,fastintr6, IO_ICU1, ENABLE_ICU1)
 266         FAST_INTR(7,fastintr7, IO_ICU1, ENABLE_ICU1)
 267         FAST_INTR(8,fastintr8, IO_ICU2, ENABLE_ICU1_AND_2)
 268         FAST_INTR(9,fastintr9, IO_ICU2, ENABLE_ICU1_AND_2)
 269         FAST_INTR(10,fastintr10, IO_ICU2, ENABLE_ICU1_AND_2)
 270         FAST_INTR(11,fastintr11, IO_ICU2, ENABLE_ICU1_AND_2)
 271         FAST_INTR(12,fastintr12, IO_ICU2, ENABLE_ICU1_AND_2)
 272         FAST_INTR(13,fastintr13, IO_ICU2, ENABLE_ICU1_AND_2)
 273         FAST_INTR(14,fastintr14, IO_ICU2, ENABLE_ICU1_AND_2)
 274         FAST_INTR(15,fastintr15, IO_ICU2, ENABLE_ICU1_AND_2)
 275
 276 #define CLKINTR_PENDING movl $1,CNAME(clkintr_pending)
 277         INTR(0,intr0, IO_ICU1, ENABLE_ICU1, al, CLKINTR_PENDING)
 278         INTR(1,intr1, IO_ICU1, ENABLE_ICU1, al,)
 279         INTR(2,intr2, IO_ICU1, ENABLE_ICU1, al,)
 280         INTR(3,intr3, IO_ICU1, ENABLE_ICU1, al,)
 281         INTR(4,intr4, IO_ICU1, ENABLE_ICU1, al,)
 282         INTR(5,intr5, IO_ICU1, ENABLE_ICU1, al,)
 283         INTR(6,intr6, IO_ICU1, ENABLE_ICU1, al,)
 284         INTR(7,intr7, IO_ICU1, ENABLE_ICU1, al,)
 285         INTR(8,intr8, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 286         INTR(9,intr9, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 287         INTR(10,intr10, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 288         INTR(11,intr11, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 289         INTR(12,intr12, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 290         INTR(13,intr13, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 291         INTR(14,intr14, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 292         INTR(15,intr15, IO_ICU2, ENABLE_ICU1_AND_2, ah,)
 293
 294         FAST_UNPEND(0,fastunpend0, IO_ICU1)
 295         FAST_UNPEND(1,fastunpend1, IO_ICU1)
 296         FAST_UNPEND(2,fastunpend2, IO_ICU1)
 297         FAST_UNPEND(3,fastunpend3, IO_ICU1)
 298         FAST_UNPEND(4,fastunpend4, IO_ICU1)
 299         FAST_UNPEND(5,fastunpend5, IO_ICU1)
 300         FAST_UNPEND(6,fastunpend6, IO_ICU1)
 301         FAST_UNPEND(7,fastunpend7, IO_ICU1)
 302         FAST_UNPEND(8,fastunpend8, IO_ICU2)
 303         FAST_UNPEND(9,fastunpend9, IO_ICU2)
 304         FAST_UNPEND(10,fastunpend10, IO_ICU2)
 305         FAST_UNPEND(11,fastunpend11, IO_ICU2)
 306         FAST_UNPEND(12,fastunpend12, IO_ICU2)
 307         FAST_UNPEND(13,fastunpend13, IO_ICU2)
 308         FAST_UNPEND(14,fastunpend14, IO_ICU2)
 309         FAST_UNPEND(15,fastunpend15, IO_ICU2)
 310 MCOUNT_LABEL(eintr)
 311
 312         .data
 313
 314         .text