lib/msun/i387/e_exp.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  */
  30
  31 /*
  32  * Written by:
  33  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 #include "abi.h"
  39
  40 #if 0
  41 RCSID("$NetBSD: e_exp.S,v 1.11 2001/06/19 17:49:36 fvdl Exp $")
  42 RCSID("$FreeBSD: src/lib/msun/i387/e_exp.S,v 1.8.2.1 2000/07/10 09:16:28 obrien Exp $")
  43 #endif
  44 RCSID("$DragonFly: src/lib/msun/i387/Attic/e_exp.S,v 1.3 2004/12/29 11:40:17 asmodai Exp $")
  45
  46 /* e^x = 2^(x * log2(e)) */
  47 ENTRY(__ieee754_exp)
  48 #ifndef __i386__
  49         /*
  50          * XXX: This code is broken and needs to be merged with the i386 case.
  51          */
  52         fstcw   -12(%rsp)
  53         movw    -12(%rsp),%dx
  54         orw     $0x0180,%dx
  55         movw    %dx,-16(%rsp)
  56         fldcw   -16(%rsp)
  57         movsd   %xmm0,-8(%rsp)
  58         fldl    -8(%rsp)
  59
  60         fldl2e
  61         fmulp                           /* x * log2(e) */
  62         fld     %st(0)
  63         frndint                         /* int(x * log2(e)) */
  64         fxch    %st(1)
  65         fsub    %st(1),%st              /* fract(x * log2(e)) */
  66         f2xm1                           /* 2^(fract(x * log2(e))) - 1 */
  67         fld1
  68         faddp                           /* 2^(fract(x * log2(e))) */
  69         fscale                          /* e^x */
  70         fstp    %st(1)
  71
  72         fstpl   -8(%rsp)
  73         movsd   -8(%rsp),%xmm0
  74         fldcw   -12(%rsp)
  75         ret
  76 #else
  77         /*
  78          * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
  79          * Avoid this.  Also avoid it if x is NaN for convenience.
  80          */
  81         movl    8(%esp),%eax
  82         andl    $0x7fffffff,%eax
  83         cmpl    $0x7ff00000,%eax
  84         jae     x_Inf_or_NaN
  85
  86         fldl    4(%esp)
  87
  88         /*
  89          * Ensure that the rounding mode is to nearest (to give the smallest
  90          * possible fraction) and that the precision is as high as possible.
  91          * We may as well mask interrupts if we switch the mode.
  92          */
  93         fstcw   4(%esp)
  94         movl    4(%esp),%eax
  95         andl    $0x0300,%eax
  96         cmpl    $0x0300,%eax            /* RC == 0 && PC == 3? */
  97         je      1f                      /* jump if mode is good */
  98         movl    $0x137f,8(%esp)
  99         fldcw   8(%esp)
 100 1:
 101         fldl2e
 102         fmulp                           /* x * log2(e) */
 103         fst     %st(1)
 104         frndint                         /* int(x * log2(e)) */
 105         fst     %st(2)
 106         fsubrp                          /* fract(x * log2(e)) */
 107         f2xm1                           /* 2^(fract(x * log2(e))) - 1 */
 108         fld1
 109         faddp                           /* 2^(fract(x * log2(e))) */
 110         fscale                          /* e^x */
 111         fstp    %st(1)
 112         je      1f
 113         fldcw   4(%esp)
 114 1:
 115         ret
 116
 117 x_Inf_or_NaN:
 118         /*
 119          * Return 0 if x is -Inf.  Otherwise just return x, although the
 120          * C version would return (x + x) (Real Indefinite) if x is a NaN.
 121          */
 122         cmpl    $0xfff00000,8(%esp)
 123         jne     x_not_minus_Inf
 124         cmpl    $0,4(%esp)
 125         jne     x_not_minus_Inf
 126         fldz
 127         ret
 128
 129 x_not_minus_Inf:
 130         fldl    4(%esp)
 131         ret
 132 #endif