lib/libcr/i386/string/bcopy.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from locore.s.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by the University of
  18  *      California, Berkeley and its contributors.
  19  * 4. Neither the name of the University nor the names of its contributors
  20  *    may be used to endorse or promote products derived from this software
  21  *    without specific prior written permission.
  22  *
  23  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  24  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  25  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  26  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  27  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  28  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  29  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  30  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  31  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  32  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  */
  35
  36 /* $FreeBSD: src/lib/libc/i386/string/bcopy.S,v 1.6.6.2 2002/11/07 19:35:25 sobomax Exp $ */
  37 /* $DragonFly: src/lib/libcr/i386/string/Attic/bcopy.S,v 1.2 2003/06/17 04:26:43 dillon Exp $ */
  38
  39 #include <machine/asm.h>
  40
  41         RCSID("$NetBSD: bcopy.S,v 1.6 1996/11/12 00:50:06 jtc Exp $")
  42
  43         /*
  44          * (ov)bcopy (src,dst,cnt)
  45          *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
  46          */
  47
  48 #ifdef MEMCOPY
  49 ENTRY(memcpy)
  50 #else
  51 #ifdef MEMMOVE
  52 ENTRY(memmove)
  53 #else
  54 ENTRY(bcopy)
  55 #endif
  56 #endif
  57         pushl   %esi
  58         pushl   %edi
  59 #if defined(MEMCOPY) || defined(MEMMOVE)
  60         movl    12(%esp),%edi
  61         movl    16(%esp),%esi
  62         movl    %edi,%eax
  63 #else
  64         movl    12(%esp),%esi
  65         movl    16(%esp),%edi
  66 #endif
  67         movl    20(%esp),%ecx
  68         movl    %edi,%edx
  69         subl    %esi,%edx
  70         cmpl    %ecx,%edx       /* overlapping? */
  71         jb      1f
  72         cld                     /* nope, copy forwards. */
  73         movl    %ecx,%edx
  74         shrl    $2,%ecx         /* copy by words */
  75         rep
  76         movsl
  77         movl    %edx,%ecx
  78         andl    $3,%ecx         /* any bytes left? */
  79         rep
  80         movsb
  81         popl    %edi
  82         popl    %esi
  83         ret
  84 1:
  85         addl    %ecx,%edi       /* copy backwards. */
  86         addl    %ecx,%esi
  87         std
  88         movl    %ecx,%edx
  89         andl    $3,%ecx         /* any fractional bytes? */
  90         decl    %edi
  91         decl    %esi
  92         rep
  93         movsb
  94         movl    %edx,%ecx       /* copy remainder by words */
  95         shrl    $2,%ecx
  96         subl    $3,%esi
  97         subl    $3,%edi
  98         rep
  99         movsl
 100         popl    %edi
 101         popl    %esi
 102         cld
 103         ret