lib/libcr/i386/string/bzero.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software withough specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/bzero.S,v 1.5 1999/08/27 23:59:30 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/bzero.S,v 1.3 2004/04/25 12:40:49 joerg Exp $
  32  */
  33
  34 #include "DEFS.h"
  35
  36 /*
  37  * bzero (void *b, size_t len)
  38  *      write len zero bytes to the string b.
  39  *
  40  * Written by:
  41  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  42  */
  43
  44 ENTRY(bzero)
  45         pushl   %edi
  46         pushl   %ebx
  47         movl    12(%esp),%edi
  48         movl    16(%esp),%ecx
  49
  50         cld                             /* set fill direction forward */
  51         xorl    %eax,%eax               /* set fill data to 0 */
  52
  53         /*
  54          * if the string is too short, it's really not worth the overhead
  55          * of aligning to word boundries, etc.  So we jump to a plain
  56          * unaligned set.
  57          */
  58         cmpl    $0x0f,%ecx
  59         jle     L1
  60
  61         movl    %edi,%edx               /* compute misalignment */
  62         negl    %edx
  63         andl    $3,%edx
  64         movl    %ecx,%ebx
  65         subl    %edx,%ebx
  66
  67         movl    %edx,%ecx               /* zero until word aligned */
  68         rep
  69         stosb
  70
  71         movl    %ebx,%ecx               /* zero by words */
  72         shrl    $2,%ecx
  73         rep
  74         stosl
  75
  76         movl    %ebx,%ecx
  77         andl    $3,%ecx                 /* zero remainder by bytes */
  78 L1:     rep
  79         stosb
  80
  81         popl    %ebx
  82         popl    %edi
  83         ret