lib/libcr/mips/string/bcopy.S

   1 /*-
   2  * Copyright (c) 1991, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Ralph Campbell.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  */
  36
  37 #include <machine/asm.h>
  38
  39 #if defined(LIBC_SCCS)
  40         .text
  41         .asciz "$OpenBSD$"
  42 #endif /* LIBC_SCCS */
  43
  44 /* bcopy(s1, s2, n) */
  45
  46
  47 LEAF(bcopy)
  48         .set    noreorder
  49         addu    t0, a0, a2              # t0 = end of s1 region
  50         sltu    t1, a1, t0
  51         sltu    t2, a0, a1
  52         and     t1, t1, t2              # t1 = true if from < to < (from+len)
  53         beq     t1, zero, forward       # non overlapping, do forward copy
  54         slt     t2, a2, 12              # check for small copy
  55
  56         ble     a2, zero, 2f
  57         addu    t1, a1, a2              # t1 = end of to region
  58 1:
  59         lb      v0, -1(t0)              # copy bytes backwards,
  60         subu    t0, t0, 1               #   doesnt happen often so do slow way
  61         subu    t1, t1, 1
  62         bne     t0, a0, 1b
  63         sb      v0, 0(t1)
  64 2:
  65         j       ra
  66         nop
  67 forward:
  68         bne     t2, zero, smallcpy      # do a small bcopy
  69         xor     v0, a0, a1              # compare low two bits of addresses
  70         and     v0, v0, 3
  71         subu    a3, zero, a1            # compute # bytes to word align address
  72         beq     v0, zero, aligned       # addresses can be word aligned
  73         and     a3, a3, 3
  74
  75         beq     a3, zero, 1f
  76         subu    a2, a2, a3              # subtract from remaining count
  77         LWHI    v0, 0(a0)               # get next 4 bytes (unaligned)
  78         LWLO    v0, 3(a0)
  79         addu    a0, a0, a3
  80         SWHI    v0, 0(a1)               # store 1, 2, or 3 bytes to align a1
  81         addu    a1, a1, a3
  82 1:
  83         and     v0, a2, 3               # compute number of words left
  84         subu    a3, a2, v0
  85         move    a2, v0
  86         addu    a3, a3, a0              # compute ending address
  87 2:
  88         LWHI    v0, 0(a0)               # copy words a0 unaligned, a1 aligned
  89         LWLO    v0, 3(a0)
  90         addu    a0, a0, 4
  91         addu    a1, a1, 4
  92         bne     a0, a3, 2b
  93         sw      v0, -4(a1)
  94         b       smallcpy
  95         nop
  96 aligned:
  97         beq     a3, zero, 1f
  98         subu    a2, a2, a3              # subtract from remaining count
  99         LWHI    v0, 0(a0)               # copy 1, 2, or 3 bytes to align
 100         addu    a0, a0, a3
 101         SWHI    v0, 0(a1)
 102         addu    a1, a1, a3
 103 1:
 104         and     v0, a2, 3               # compute number of whole words left
 105         subu    a3, a2, v0
 106         move    a2, v0
 107         addu    a3, a3, a0              # compute ending address
 108 2:
 109         lw      v0, 0(a0)               # copy words
 110         addu    a0, a0, 4
 111         addu    a1, a1, 4
 112         bne     a0, a3, 2b
 113         sw      v0, -4(a1)
 114 smallcpy:
 115         ble     a2, zero, 2f
 116         addu    a3, a2, a0              # compute ending address
 117 1:
 118         lbu     v0, 0(a0)               # copy bytes
 119         addu    a0, a0, 1
 120         addu    a1, a1, 1
 121         bne     a0, a3, 1b
 122         sb      v0, -1(a1)
 123 2:
 124         j       ra
 125         nop
 126         .set    reorder
 127 END(bcopy)