m4: define yylex based on __DragonFly_version
[dragonfly.git] / usr.bin / m4 / tokenizer.l
1 %option nounput noinput
2 %{
3 /* $OpenBSD: tokenizer.l,v 1.7 2010/03/22 20:40:44 espie Exp $ */
4 /*
5  * Copyright (c) 2004 Marc Espie <espie@cvs.openbsd.org>
6  *
7  * Permission to use, copy, modify, and distribute this software for any
8  * purpose with or without fee is hereby granted, provided that the above
9  * copyright notice and this permission notice appear in all copies.
10  *
11  * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12  * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13  * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14  * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15  * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16  * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17  * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18  *
19  * $FreeBSD: src/usr.bin/m4/tokenizer.l,v 1.3 2012/11/17 01:54:24 svnexp Exp $
20  */
21 #pragma GCC diagnostic ignored "-Wsign-compare"
22 #include "parser.h"
23 #include <assert.h>
24 #include <stdlib.h>
25 #include <errno.h>
26 #include <stdint.h>
27 #include <limits.h>
28 #include <sys/param.h>
29
30 extern int mimic_gnu;
31 extern int32_t yylval;
32
33 int32_t number(void);
34 int32_t parse_radix(void);
35 #if __DragonFly_version < 300303
36 extern int yylex(void);
37 #endif
38 %}
39
40 delim   [ \t\n]
41 ws      {delim}+
42 hex     0[xX][0-9a-fA-F]+
43 oct     0[0-7]*
44 dec     [1-9][0-9]*
45 radix   0[rR][0-9]+:[0-9a-zA-Z]+
46
47 %%
48 {ws}                    {/* just skip it */}
49 {hex}|{oct}|{dec}       { yylval = number(); return(NUMBER); }
50 {radix}                 { if (mimic_gnu) {
51                                 yylval = parse_radix(); return(NUMBER);
52                           } else {
53                                 return(ERROR);
54                           }
55                         }
56 "<="                    { return(LE); }
57 ">="                    { return(GE); }
58 "<<"                    { return(LSHIFT); }
59 ">>"                    { return(RSHIFT); }
60 "=="                    { return(EQ); }
61 "!="                    { return(NE); }
62 "&&"                    { return(LAND); }
63 "||"                    { return(LOR); }
64 "**"                    { if (mimic_gnu) { return (EXPONENT); } }
65 .                       { return yytext[0]; }
66 %%
67
68 int32_t
69 number(void)
70 {
71         long l;
72
73         errno = 0;
74         l = strtol(yytext, NULL, 0);
75         if (((l == LONG_MAX || l == LONG_MIN) && errno == ERANGE) ||
76             l > INT32_MAX || l < INT32_MIN) {
77                 fprintf(stderr, "m4: numeric overflow in expr: %s\n", yytext);
78         }
79         return l;
80 }
81
82 int32_t
83 parse_radix(void)
84 {
85         long base;
86         char *next;
87         long l;
88         int d;
89
90         l = 0;
91         base = strtol(yytext + 2, &next, 0);
92         if (base > 36 || next == NULL) {
93                 fprintf(stderr, "m4: error in number %s\n", yytext);
94         } else {
95                 next++;
96                 while (*next != 0) {
97                         if (*next >= '0' && *next <= '9')
98                                 d = *next - '0';
99                         else if (*next >= 'a' && *next <= 'z')
100                                 d = *next - 'a' + 10;
101                         else {
102                                 assert(*next >= 'A' && *next <= 'Z');
103                                 d = *next - 'A' + 10;
104                         }
105                         if (d >= base) {
106                                 fprintf(stderr,
107                                     "m4: error in number %s\n", yytext);
108                                 return 0;
109                         }
110                         l = base * l + d;
111                         next++;
112                 }
113         }
114         return l;
115 }