sys/boot/ia64/skiload/ldscript.ia64

   1 /*
   2  * $FreeBSD: src/sys/boot/ia64/skiload/ldscript.ia64,v 1.2 2003/07/17 01:49:59 marcel Exp $
   3  * $DragonFly: src/sys/boot/ia64/skiload/ldscript.ia64,v 1.1 2003/11/10 06:08:37 dillon Exp $
   4  */
   5 OUTPUT_FORMAT("elf64-ia64-little", "elf64-ia64-little", "elf64-ia64-little")
   6 OUTPUT_ARCH(ia64)
   7 ENTRY(_start)
   8 SECTIONS
   9 {
  10   /* Read-only sections, merged into text segment: */
  11   . = 0x100000;
  12   .text         : {
  13     *(.text .stub .text.* .gnu.linkonce.t.*)
  14     /* .gnu.warning sections are handled specially by elf32.em. */
  15     *(.gnu.warning)
  16     *(.plt)
  17   } =0x00300000010070000002000001000400
  18   .data         : {
  19     *(.rodata .rodata.* .gnu.linkonce.r.*)
  20     *(.rodata1)
  21     *(.sdata2 .sdata2.* .gnu.linkonce.s2.*)
  22     *(.sbss2 .sbss2.* .gnu.linkonce.sb2.*)
  23     *(.opd)
  24     *(.IA_64.unwind_info* .gnu.linkonce.ia64unwi.*)
  25     *(.IA_64.unwind* .gnu.linkonce.ia64unw.*)
  26     __start_set_Xcommand_set = .;
  27     *(set_Xcommand_set)
  28     __stop_set_Xcommand_set = .;
  29     *(.data .data.* .gnu.linkonce.d.*)
  30     *(.data1)
  31     *(.plabel)
  32     *(.dynbss)
  33     *(.bss .bss.* .gnu.linkonce.b.*)
  34     *(COMMON)
  35   }
  36   __gp = .;
  37   .sdata        : {
  38     *(.got.plt .got)
  39     *(.IA_64.pltoff)
  40     *(.sdata .sdata.* .gnu.linkonce.s.*)
  41     *(dynsbss)
  42     *(.sbss .sbss.* .gnu.linkonce.sb.*)
  43     *(.scommon)
  44   }
  45   .dynamic      : { *(.dynamic) }
  46   .rela         : {
  47     *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*)
  48     *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*)
  49     *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*)
  50     *(.rela.got)
  51     *(.rela.sdata .rela.sdata.* .rela.gnu.linkonce.s.*)
  52     *(.rela.sbss .rela.sbss.* .rela.gnu.linkonce.sb.*)
  53     *(.rela.sdata2 .rela.sdata2.* .rela.gnu.linkonce.s2.*)
  54     *(.rela.sbss2 .rela.sbss2.* .rela.gnu.linkonce.sb2.*)
  55     *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)
  56     *(.rela.plt)
  57     *(.rela.IA_64.pltoff)
  58     *(.relaset_*)
  59     *(.rela.dyn .rela.dyn.*)
  60   }
  61   .hash         : { *(.hash) }
  62   .dynsym       : { *(.dynsym) }
  63   .dynstr       : { *(.dynstr) }
  64 }