lib/libc/x86_64/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * @(#)setjmp.s 5.1 (Berkeley) 4/23/90
  33  * $FreeBSD: src/lib/libc/amd64/gen/setjmp.S,v 1.29 2008/11/02 01:10:54 peter Exp $
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 /*
  39  * C library -- _setjmp, _longjmp
  40  *
  41  *      longjmp(a,v)
  42  * will generate a "return(v)" from the last call to
  43  *      setjmp(a)
  44  * by restoring registers from the environment 'a'.
  45  * The previous signal state is restored.
  46  */
  47
  48 #include "SYS.h"
  49
  50 ENTRY(setjmp)
  51         pushq   %rdi
  52         movq    %rdi,%rcx
  53         movq    $1,%rdi                 /* SIG_BLOCK       */
  54         movq    $0,%rsi                 /* (sigset_t*)set  */
  55         leaq    72(%rcx),%rdx           /* 9,10; (sigset_t*)oset */
  56         /* stack is 16-byte aligned */
  57         call    PIC_PLT(CNAME(_sigprocmask))
  58         popq    %rdi
  59         movq    %rdi,%rcx
  60         movq    0(%rsp),%rdx            /* retval */
  61         movq    %rdx, 0(%rcx)           /* 0; retval */
  62         movq    %rbx, 8(%rcx)           /* 1; rbx */
  63         movq    %rsp,16(%rcx)           /* 2; rsp */
  64         movq    %rbp,24(%rcx)           /* 3; rbp */
  65         movq    %r12,32(%rcx)           /* 4; r12 */
  66         movq    %r13,40(%rcx)           /* 5; r13 */
  67         movq    %r14,48(%rcx)           /* 6; r14 */
  68         movq    %r15,56(%rcx)           /* 7; r15 */
  69         fnstcw  64(%rcx)                /* 8; fpu cw */
  70         stmxcsr 68(%rcx)                /*    and mxcsr */
  71         xorq    %rax,%rax
  72         ret
  73 END(setjmp)
  74
  75         .weak CNAME(longjmp)
  76         .set CNAME(longjmp),CNAME(__longjmp)
  77 ENTRY(__longjmp)
  78         pushq   %rdi
  79         pushq   %rsi
  80         movq    %rdi,%rdx
  81         movq    $3,%rdi                 /* SIG_SETMASK     */
  82         leaq    72(%rdx),%rsi           /* (sigset_t*)set  */
  83         movq    $0,%rdx                 /* (sigset_t*)oset */
  84         subq    $0x8,%rsp               /* make the stack 16-byte aligned */
  85         call    PIC_PLT(CNAME(_sigprocmask))
  86         addq    $0x8,%rsp
  87         popq    %rsi
  88         popq    %rdi                    /* jmpbuf */
  89         movq    %rdi,%rdx
  90         /* Restore the mxcsr, but leave exception flags intact. */
  91         stmxcsr -4(%rsp)
  92         movl    68(%rdx),%eax
  93         andl    $0xffffffc0,%eax
  94         movl    -4(%rsp),%edi
  95         andl    $0x3f,%edi
  96         xorl    %eax,%edi
  97         movl    %edi,-4(%rsp)
  98         ldmxcsr -4(%rsp)
  99         movq    %rsi,%rax               /* retval */
 100         movq    0(%rdx),%rcx
 101         movq    8(%rdx),%rbx
 102         movq    16(%rdx),%rsp
 103         movq    24(%rdx),%rbp
 104         movq    32(%rdx),%r12
 105         movq    40(%rdx),%r13
 106         movq    48(%rdx),%r14
 107         movq    56(%rdx),%r15
 108         fldcw   64(%rdx)
 109         testq   %rax,%rax
 110         jnz     1f
 111         incq    %rax
 112 1:      movq    %rcx,0(%rsp)
 113         ret
 114 END(__longjmp)
 115
 116         .section .note.GNU-stack,"",%progbits