libexec/rtld-elf/i386/rtld_start.S

   1 /*-
   2  * Copyright 1996-1998 John D. Polstra.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  15  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  16  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  17  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  18  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  19  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  20  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  21  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  22  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  23  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24  *
  25  * $FreeBSD: src/libexec/rtld-elf/i386/rtld_start.S,v 1.3 1999/08/28 00:10:15 peter Exp $
  26  * $DragonFly: src/libexec/rtld-elf/i386/rtld_start.S,v 1.3 2004/01/20 18:46:21 dillon Exp $
  27  */
  28
  29         .text
  30         .align  4
  31         .globl  resident_start
  32         .globl  .rtld_start
  33         .type   .rtld_start,@function
  34 resident_start:
  35 .rtld_start:
  36         xorl    %ebp,%ebp               # Clear frame pointer for good form
  37         movl    %esp,%eax               # Save initial stack pointer
  38         subl    $8,%esp                 # A place to store exit procedure addr
  39         movl    %esp,%ebx               # save address of exit proc
  40         movl    %esp,%ecx               # construct address of obj_main
  41         addl    $4,%ecx
  42         pushl   %ecx                    # Pass address of obj_main
  43         pushl   %ebx                    # Pass address of exit proc
  44         pushl   %eax                    # Pass initial stack pointer to rtld
  45         call    _rtld@PLT               # Call rtld(sp); returns entry point
  46         addl    $12,%esp                # Remove arguments from stack
  47         popl    %edx                    # Get exit procedure address
  48         addl    $4,%esp                 # Ignore obj_main
  49 /*
  50  * At this point, %eax contains the entry point of the main program, and
  51  * %edx contains a pointer to a termination function that should be
  52  * registered with atexit().  (crt1.o registers it.)
  53  */
  54 .globl .rtld_goto_main
  55 .rtld_goto_main:        # This symbol exists just to make debugging easier.
  56         jmp     *%eax                   # Enter main program
  57
  58
  59 /*
  60  * Binder entry point.  Control is transferred to here by code in the PLT.
  61  * On entry, there are two arguments on the stack.  In ascending address
  62  * order, they are (1) "obj", a pointer to the calling object's Obj_Entry,
  63  * and (2) "reloff", the byte offset of the appropriate relocation entry
  64  * in the PLT relocation table.
  65  *
  66  * We are careful to preserve all registers, even the the caller-save
  67  * registers.  That is because this code may be invoked by low-level
  68  * assembly-language code that is not ABI-compliant.
  69  */
  70         .align  4
  71         .globl  _rtld_bind_start
  72         .type   _rtld_bind_start,@function
  73 _rtld_bind_start:
  74         pushf                           # Save eflags
  75         pushl   %eax                    # Save %eax
  76         pushl   %edx                    # Save %edx
  77         pushl   %ecx                    # Save %ecx
  78         pushl   20(%esp)                # Copy reloff argument
  79         pushl   20(%esp)                # Copy obj argument
  80
  81         call    _rtld_bind@PLT          # Transfer control to the binder
  82         /* Now %eax contains the entry point of the function being called. */
  83
  84         addl    $8,%esp                 # Discard binder arguments
  85         movl    %eax,20(%esp)           # Store target over obj argument
  86         popl    %ecx                    # Restore %ecx
  87         popl    %edx                    # Restore %edx
  88         popl    %eax                    # Restore %eax
  89         popf                            # Restore eflags
  90         leal    4(%esp),%esp            # Discard reloff, do not change eflags
  91         ret                             # "Return" to target address