sys/i386/i386/in_cksum2.s

   1 /*
   2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * $DragonFly: src/sys/i386/i386/Attic/in_cksum2.s,v 1.3 2004/07/16 05:48:29 dillon Exp $
  35  */
  36
  37 #include <machine/asmacros.h>           /* miscellaneous asm macros */
  38 #include <machine/apicreg.h>
  39 #include <machine/specialreg.h>
  40
  41 #include "assym.s"
  42
  43         .text
  44
  45         /*
  46          * asm_ones32(32bitalignedbuffer, numberof32bitwords)
  47          *
  48          * Returns the 32 bit one complement partial checksum.  This is
  49          * basically a 1's complement checksum without the inversion (~)
  50          * at the end.  A 32 bit value is returned.  If the caller is
  51          * calculating a 16 bit 1's complement checksum the caller must
  52          * collapse the 32 bit return value via:
  53          *
  54          *      result = (result >> 16) + (result & 0xFFFF)
  55          *      if (result > 0xFFFF)
  56          *          result -= 0xFFFF;   <<< same as (result + 1) & 0xFFFF
  57          *                                  within the range of result.
  58          * Note that worst case 0xFFFFFFFF + 0xFFFFFFFF = 0xFFFFFFFE + CARRY,
  59          * so no double-carry ever occurs.
  60          */
  61         .p2align 4
  62 ENTRY(asm_ones32)
  63         movl    4(%esp),%edx    /* %edx = buffer pointer */
  64         movl    8(%esp),%ecx    /* %ecx = counter */
  65         subl    %eax,%eax       /* %eax = checksum */
  66         cmpl    $5,%ecx
  67         jl      2f
  68 1:
  69         subl    $5,%ecx
  70         addl    (%edx),%eax
  71         adcl    4(%edx),%eax
  72         adcl    8(%edx),%eax
  73         adcl    12(%edx),%eax
  74         adcl    16(%edx),%eax
  75         adcl    $0,%eax
  76         addl    $20,%edx
  77         cmpl    $5,%ecx
  78         jge     1b
  79 2:
  80         testl   %ecx,%ecx
  81         je      4f
  82 3:
  83         addl    (%edx),%eax
  84         adcl    $0,%eax
  85         addl    $4,%edx
  86         decl    %ecx
  87         jnz     3b
  88 4:
  89         ret