lib/libc/i386/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD: src/lib/libc/i386/gen/setjmp.S,v 1.17.2.2 2001/07/06 12:41:44 deischen Exp $
  37  * $DragonFly: src/lib/libc/i386/gen/setjmp.S,v 1.3 2003/12/06 03:11:35 drhodus Exp $
  38  */
  39
  40 /*
  41  * C library -- _setjmp, _longjmp
  42  *
  43  *      longjmp(a,v)
  44  * will generate a "return(v)" from the last call to
  45  *      setjmp(a)
  46  * by restoring registers from the environment 'a'.
  47  * The previous signal state is restored.
  48  */
  49
  50 #include "DEFS.h"
  51 #include "SYS.h"
  52
  53 ENTRY(setjmp)
  54         movl    4(%esp),%ecx
  55         PIC_PROLOGUE
  56         leal    28(%ecx), %eax
  57         pushl   %eax                    /* (sigset_t*)oset */
  58         pushl   $0                      /* (sigset_t*)set  */
  59         pushl   $1                      /* SIG_BLOCK       */
  60         call    PIC_PLT(CNAME(sigprocmask))
  61         addl    $12,%esp
  62         PIC_EPILOGUE
  63         movl    4(%esp),%ecx
  64         movl    0(%esp),%edx
  65         movl    %edx, 0(%ecx)
  66         movl    %ebx, 4(%ecx)
  67         movl    %esp, 8(%ecx)
  68         movl    %ebp,12(%ecx)
  69         movl    %esi,16(%ecx)
  70         movl    %edi,20(%ecx)
  71         fnstcw  24(%ecx)
  72         xorl    %eax,%eax
  73         ret
  74
  75 #ifndef _THREAD_SAFE
  76 .weak CNAME(longjmp);
  77 .set CNAME(longjmp),CNAME(__longjmp);
  78 #endif
  79 ENTRY(__longjmp)
  80         movl    4(%esp),%edx
  81         PIC_PROLOGUE
  82         pushl   $0                      /* (sigset_t*)oset */
  83         leal    28(%edx), %eax
  84         pushl   %eax                    /* (sigset_t*)set  */
  85         pushl   $3                      /* SIG_SETMASK     */
  86         call    PIC_PLT(CNAME(sigprocmask))
  87         addl    $12,%esp
  88         PIC_EPILOGUE
  89         movl    4(%esp),%edx
  90         movl    8(%esp),%eax
  91         movl    0(%edx),%ecx
  92         movl    4(%edx),%ebx
  93         movl    8(%edx),%esp
  94         movl    12(%edx),%ebp
  95         movl    16(%edx),%esi
  96         movl    20(%edx),%edi
  97         fninit
  98         fldcw   24(%edx)
  99         testl   %eax,%eax
 100         jnz     1f
 101         incl    %eax
 102 1:      movl    %ecx,0(%esp)
 103         ret