lib/libc/i386/string/strcmp.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software withough specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/strcmp.S,v 1.5 1999/08/27 23:59:33 peter Exp $
  31  * $DragonFly: src/lib/libc/i386/string/strcmp.S,v 1.3 2003/12/06 03:11:36 drhodus Exp $
  32  */
  33
  34 #include "DEFS.h"
  35
  36 /*
  37  * strcmp(s1, s2)
  38  *      return an integer greater than, equal to, or less than 0,
  39  *      according as string s1 is greater than, equal to, or less
  40  *      than the string s2.
  41  *
  42  * %eax - pointer to s1
  43  * %edx - pointer to s2
  44  *
  45  * Written by:
  46  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  47  */
  48
  49 /*
  50  * I've unrolled the loop eight times: large enough to make a
  51  * significant difference, and small enough not to totally trash the
  52  * cache.
  53  */
  54
  55 ENTRY(strcmp)
  56         movl    0x04(%esp),%eax
  57         movl    0x08(%esp),%edx
  58         jmp     L2                      /* Jump into the loop! */
  59
  60         .align  2,0x90
  61 L1:     incl    %eax
  62         incl    %edx
  63 L2:     movb    (%eax),%cl
  64         testb   %cl,%cl
  65         je      L3
  66         cmpb    %cl,(%edx)
  67         jne     L3
  68         incl    %eax
  69         incl    %edx
  70         movb    (%eax),%cl
  71         testb   %cl,%cl
  72         je      L3
  73         cmpb    %cl,(%edx)
  74         jne     L3
  75         incl    %eax
  76         incl    %edx
  77         movb    (%eax),%cl
  78         testb   %cl,%cl
  79         je      L3
  80         cmpb    %cl,(%edx)
  81         jne     L3
  82         incl    %eax
  83         incl    %edx
  84         movb    (%eax),%cl
  85         testb   %cl,%cl
  86         je      L3
  87         cmpb    %cl,(%edx)
  88         jne     L3
  89         incl    %eax
  90         incl    %edx
  91         movb    (%eax),%cl
  92         testb   %cl,%cl
  93         je      L3
  94         cmpb    %cl,(%edx)
  95         jne     L3
  96         incl    %eax
  97         incl    %edx
  98         movb    (%eax),%cl
  99         testb   %cl,%cl
 100         je      L3
 101         cmpb    %cl,(%edx)
 102         jne     L3
 103         incl    %eax
 104         incl    %edx
 105         movb    (%eax),%cl
 106         testb   %cl,%cl
 107         je      L3
 108         cmpb    %cl,(%edx)
 109         jne     L3
 110         incl    %eax
 111         incl    %edx
 112         movb    (%eax),%cl
 113         testb   %cl,%cl
 114         je      L3
 115         cmpb    %cl,(%edx)
 116         je      L1
 117         .align 2, 0x90
 118 L3:     movzbl  (%eax),%eax             /* unsigned comparison */
 119         movzbl  (%edx),%edx
 120         subl    %edx,%eax
 121         ret