lib/libcr/i386/string/strcat.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software withough specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/strcat.S,v 1.5 1999/08/27 23:59:33 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/strcat.S,v 1.4 2004/04/25 12:40:49 joerg Exp $
  32  */
  33
  34 #include "DEFS.h"
  35
  36 /*
  37  * strcat(s, append)
  38  *      append a copy of the null-terminated string "append" to the end
  39  *      of the null-terminated string s, then add a terminating `\0'.
  40  *
  41  * Written by:
  42  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  43  */
  44
  45 /*
  46  * I've unrolled the loop eight times: large enough to make a
  47  * significant difference, and small enough not to totally trash the
  48  * cache.
  49  */
  50
  51 ENTRY(strcat)
  52         pushl   %edi                    /* save edi */
  53         movl    8(%esp),%edi            /* dst address */
  54         movl    12(%esp),%edx           /* src address */
  55         pushl   %edi                    /* push destination address */
  56
  57         cld                             /* set search forward */
  58         xorl    %eax,%eax               /* set search for null terminator */
  59         movl    $-1,%ecx                /* set search for lots of characters */
  60         repne                           /* search! */
  61         scasb
  62
  63         leal    -1(%edi),%ecx           /* correct dst address */
  64
  65         .align 2,0x90
  66 L1:     movb    (%edx),%al              /* unroll loop, but not too much */
  67         movb    %al,(%ecx)
  68         testb   %al,%al
  69         je      L2
  70         movb    1(%edx),%al
  71         movb    %al,1(%ecx)
  72         testb   %al,%al
  73         je      L2
  74         movb    2(%edx),%al
  75         movb    %al,2(%ecx)
  76         testb   %al,%al
  77         je      L2
  78         movb    3(%edx),%al
  79         movb    %al,3(%ecx)
  80         testb   %al,%al
  81         je      L2
  82         movb    4(%edx),%al
  83         movb    %al,4(%ecx)
  84         testb   %al,%al
  85         je      L2
  86         movb    5(%edx),%al
  87         movb    %al,5(%ecx)
  88         testb   %al,%al
  89         je      L2
  90         movb    6(%edx),%al
  91         movb    %al,6(%ecx)
  92         testb   %al,%al
  93         je      L2
  94         movb    7(%edx),%al
  95         movb    %al,7(%ecx)
  96         addl    $8,%edx
  97         addl    $8,%ecx
  98         testb   %al,%al
  99         jne     L1
 100 L2:     popl    %eax                    /* pop destination address */
 101         popl    %edi                    /* restore edi */
 102         ret