lib/libcr/i386/string/swab.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/swab.S,v 1.5 1999/08/27 23:59:35 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/swab.S,v 1.3 2004/04/25 12:40:49 joerg Exp $
  32  */
  33
  34 #include "DEFS.h"
  35
  36 /*
  37  * void
  38  * swab (const void *src, void *dst, size_t len)
  39  *      copy len bytes from src to dst, swapping adjacent bytes
  40  *
  41  * On the i486, this code is negligibly faster than the code generated
  42  * by gcc at about half the size.  If my i386 databook is correct, it
  43  * should be considerably faster than the gcc code on a i386.
  44  *
  45  * Written by:
  46  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  47  */
  48
  49 ENTRY(swab)
  50         pushl   %esi
  51         pushl   %edi
  52         movl    12(%esp),%esi
  53         movl    16(%esp),%edi
  54         movl    20(%esp),%ecx
  55
  56         cld                             # set direction forward
  57
  58         shrl    $1,%ecx
  59         testl   $7,%ecx                 # copy first group of 1 to 7 words
  60         jz      L2                      # while swaping alternate bytes.
  61         .align  2,0x90
  62 L1:     lodsw
  63         rorw    $8,%ax
  64         stosw
  65         decl    %ecx
  66         testl   $7,%ecx
  67         jnz     L1
  68
  69 L2:     shrl    $3,%ecx                 # copy remainder 8 words at a time
  70         jz      L4                      # while swapping alternate bytes.
  71         .align  2,0x90
  72 L3:     lodsw
  73         rorw    $8,%ax
  74         stosw
  75         lodsw
  76         rorw    $8,%ax
  77         stosw
  78         lodsw
  79         rorw    $8,%ax
  80         stosw
  81         lodsw
  82         rorw    $8,%ax
  83         stosw
  84         lodsw
  85         rorw    $8,%ax
  86         stosw
  87         lodsw
  88         rorw    $8,%ax
  89         stosw
  90         lodsw
  91         rorw    $8,%ax
  92         stosw
  93         lodsw
  94         rorw    $8,%ax
  95         stosw
  96         decl    %ecx
  97         jnz     L3
  98
  99 L4:     popl    %edi
 100         popl    %esi
 101         ret