contrib/ipfilter/FreeBSD-2.2/unminstall

   1 #!/bin/csh -f
   2 #
   3 set dir=`pwd`
   4 set karch=`uname -m`
   5 if ( -d /sys/arch/$karch ) set archdir="/sys/arch/$karch"
   6 if ( -d /sys/$karch ) set archdir="/sys/$karch"
   7 set confdir="$archdir/conf"
   8
   9 if ( $dir =~ */FreeBSD* ) cd ..
  10 echo "Unpatching ip_input.c, ip_output.c and in_proto.c"
  11 cat FreeBSD-2.2/ip_{in,out}put.c.diffs FreeBSD-2.2/in_proto.c.diffs |  \
  12 (cd /sys/netinet; patch -R)
  13
  14 set config=`(cd $confdir; /bin/ls -1t [0-9A-Z_]*) | head -1`
  15 echo -n "Kernel configuration to update [$config] "
  16 set newconfig=$<
  17 if ( "$newconfig" != "" ) then
  18         set config="$confdir/$newconfig"
  19 else
  20         set newconfig=$config
  21 endif
  22 if ( -f $confdir/$newconfig ) then
  23         mv $confdir/$newconfig $confdir/$newconfig.bak
  24 endif
  25 if ( -d $archdir/../compile/$newconfig ) then
  26         set bak=".bak"
  27         set dot=0
  28         while ( -d $archdir/../compile/${newconfig}.${bak} )
  29                 set bak=".bak.$dot"
  30                 set dot=`expr 1 + $dot`
  31         end
  32         mv $archdir/../compile/$newconfig $archdir/../compile/${newconfig}.$bak
  33 endif
  34 grep -v IPFILTER $confdir/$newconfig.bak > $confdir/$newconfig
  35 echo 'You will now need to run "config" and build a new kernel.'
  36 exit 0