contrib/binutils/bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $DragonFly: src/contrib/binutils/bfd/Attic/configure.in,v 1.2 2003/11/19 00:51:31 dillon Exp $
   3
   4 dnl
   5
   6 AC_PREREQ(2.13)
   7 AC_INIT(libbfd.c)
   8
   9 AC_CANONICAL_SYSTEM
  10 AC_ISC_POSIX
  11
  12 AM_INIT_AUTOMAKE(bfd, 2.12.1)
  13 # Uncomment the next line to remove the date from the reported bfd version
  14 is_release=y
  15
  16 changequote(,)dnl
  17 bfd_version=`echo "${VERSION}" | sed -e 's/\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\)\.*\([^\.]*\).*/\1.00\2.00\3.00\4.00\5/' -e 's/\([^\.]*\)\..*\(..\)\..*\(..\)\..*\(..\)\..*\(..\)$/\1\2\3\4\5/'`
  18 changequote([,])dnl
  19
  20 bfd_version_string="\"${VERSION}\""
  21 bfd_version_date=`sed -e 's/.*DATE //' < ${srcdir}/version.h`
  22 if test x${is_release} = x; then
  23 dnl Sad, but we can't use XSTRING here to pick up the date from version.h
  24 dnl because traditional C doesn't allow it.
  25   bfd_version_string="\"${VERSION} ${bfd_version_date}\""
  26 fi
  27 dnl Since we need to edit bfd-in3.h to get the date for bfd_version_string,
  28 dnl we may as well substitute for bfd_version_date too.  That way we don't
  29 dnl need to #include version.h
  30 AC_SUBST(bfd_version)
  31 AC_SUBST(bfd_version_date)
  32 AC_SUBST(bfd_version_string)
  33
  34 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 dnl Default to a non shared library.  This may be overridden by the
  40 dnl configure option --enable-shared.
  41 AM_DISABLE_SHARED
  42
  43 AM_PROG_LIBTOOL
  44
  45 AC_ARG_ENABLE(64-bit-bfd,
  46 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  47 [case "${enableval}" in
  48   yes)  want64=true  ;;
  49   no)   want64=false ;;
  50   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  51 esac],[want64=false])dnl
  52 AC_ARG_ENABLE(targets,
  53 [  --enable-targets        alternative target configurations],
  54 [case "${enableval}" in
  55   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  56             ;;
  57   no)       enable_targets= ;;
  58   *)        enable_targets=$enableval ;;
  59 esac])dnl
  60 AC_ARG_ENABLE(commonbfdlib,
  61 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  62 [case "${enableval}" in
  63   yes) commonbfdlib=true ;;
  64   no)  commonbfdlib=false ;;
  65   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  66 esac])dnl
  67 AC_ARG_WITH(mmap,
  68 [  --with-mmap             try using mmap for BFD input files if available],
  69 [case "${withval}" in
  70   yes)  want_mmap=true ;;
  71   no)   want_mmap=false ;;
  72   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  73 esac],[want_mmap=false])dnl
  74
  75 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  76 AC_ARG_ENABLE(build-warnings,
  77 [  --enable-build-warnings Enable build-time compiler warnings if gcc is used],
  78 [case "${enableval}" in
  79   yes)  ;;
  80   no)   build_warnings="-w";;
  81   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  82         build_warnings="${build_warnings} ${t}";;
  83   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  84         build_warnings="${t} ${build_warnings}";;
  85   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  86 esac
  87 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  88   echo "Setting warning flags = $build_warnings" 6>&1
  89 fi])dnl
  90 WARN_CFLAGS=""
  91 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
  92     WARN_CFLAGS="${build_warnings}"
  93 fi
  94 AC_SUBST(WARN_CFLAGS)
  95
  96 AM_CONFIG_HEADER(config.h:config.in)
  97
  98 if test -z "$target" ; then
  99     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 100 fi
 101
 102 AM_MAINTAINER_MODE
 103 AC_EXEEXT
 104
 105 host64=false
 106 target64=false
 107 bfd_default_target_size=32
 108
 109 # host stuff:
 110
 111 AC_PROG_CC
 112
 113 ALL_LINGUAS="fr tr ja es sv"
 114 CY_GNU_GETTEXT
 115
 116 # Permit host specific settings.
 117 . ${srcdir}/configure.host
 118
 119 AC_SUBST(HDEFINES)
 120 AC_PROG_INSTALL
 121
 122 BFD_HOST_64BIT_LONG=0
 123 BFD_HOST_64_BIT_DEFINED=0
 124 BFD_HOST_64_BIT=
 125 BFD_HOST_U_64_BIT=
 126 if test "x${HOST_64BIT_TYPE}" = "xlong"; then
 127   BFD_HOST_64BIT_LONG=1
 128 elif test "x${HOST_64BIT_TYPE}" != "x"; then
 129   BFD_HOST_64_BIT_DEFINED=1
 130   BFD_HOST_64_BIT=${HOST_64BIT_TYPE}
 131   BFD_HOST_U_64_BIT=${HOST_U_64BIT_TYPE}
 132 fi
 133 AC_SUBST(BFD_HOST_64BIT_LONG)
 134 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 135 AC_SUBST(BFD_HOST_64_BIT)
 136 AC_SUBST(BFD_HOST_U_64_BIT)
 137
 138 BFD_CC_FOR_BUILD
 139
 140 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 141 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 142 AC_HEADER_TIME
 143 AC_HEADER_DIRENT
 144 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 145
 146 BFD_BINARY_FOPEN
 147
 148 BFD_NEED_DECLARATION(strstr)
 149 BFD_NEED_DECLARATION(malloc)
 150 BFD_NEED_DECLARATION(realloc)
 151 BFD_NEED_DECLARATION(free)
 152 BFD_NEED_DECLARATION(getenv)
 153
 154 # If we are configured native, pick a core file support file.
 155 COREFILE=
 156 COREFLAG=
 157 TRAD_HEADER=
 158 if test "${target}" = "${host}"; then
 159   case "${host}" in
 160   alpha*-*-freebsd*)
 161         COREFILE=''
 162         ;;
 163   alpha*-*-linux-gnu*)
 164         COREFILE=trad-core.lo
 165         TRAD_HEADER='"hosts/alphalinux.h"'
 166         ;;
 167   alpha*-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 168   alpha*-*-*)           COREFILE=osf-core.lo ;;
 169   arm-*-dragonfly*)     COREFILE='' ;;
 170   arm-*-freebsd*)       COREFILE='' ;;
 171   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 172   arm-*-riscix)         COREFILE=trad-core.lo ;;
 173   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 174   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 175   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 176   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 177                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 178   i370-*-*)
 179         COREFILE=trad-core.lo
 180         TRAD_HEADER='"hosts/i370linux.h"'
 181         ;;
 182
 183 changequote(,)dnl
 184   i[3456]86-sequent-bsd*)
 185 changequote([,])dnl
 186         COREFILE=trad-core.lo
 187         TRAD_HEADER='"hosts/symmetry.h"'
 188         ;;
 189 changequote(,)dnl
 190   i[3456]86-sequent-sysv4*) ;;
 191   i[3456]86-sequent-sysv*)
 192 changequote([,])dnl
 193         COREFILE=trad-core.lo
 194         TRAD_HEADER='"hosts/symmetry.h"'
 195         ;;
 196 changequote(,)dnl
 197   i[3456]86-*-bsdi)
 198 changequote([,])dnl
 199         COREFILE=
 200         ;;
 201 changequote(,)dnl
 202   i[3456]86-*-bsd* | i[34567]86-*-freebsd[123] | i[34567]86-*-freebsd[123]\.* | i[34567]86-*-freebsd4\.[01234]* | i[34567]86-*-freebsd*aout*)
 203 changequote([,])dnl
 204         COREFILE=trad-core.lo
 205         TRAD_HEADER='"hosts/i386bsd.h"'
 206         ;;
 207 changequote(,)dnl
 208   i[3456]86-*-freebsd*)
 209 changequote([,])dnl
 210         COREFILE=''
 211         TRAD_HEADER='"hosts/i386bsd.h"'
 212         ;;
 213   i[3456]86-*-dragonfly*)
 214 changequote([,])dnl
 215         COREFILE=''
 216         TRAD_HEADER='"hosts/i386bsd.h"'
 217         ;;
 218 changequote(,)dnl
 219   i[3456]86-*-netbsd* | i[3456]86-*-openbsd*)
 220 changequote([,])dnl
 221         COREFILE=netbsd-core.lo
 222         ;;
 223 changequote(,)dnl
 224   i[3456]86-esix-sysv3*)
 225 changequote([,])dnl
 226         COREFILE=trad-core.lo
 227         TRAD_HEADER='"hosts/esix.h"'
 228         ;;
 229 changequote(,)dnl
 230   i[3456]86-*-sco3.2v5*)
 231 changequote([,])dnl
 232         COREFILE=sco5-core.lo
 233         ;;
 234 changequote(,)dnl
 235   i[3456]86-*-sco* | i[3456]86-*-isc*)
 236 changequote([,])dnl
 237         COREFILE=trad-core.lo
 238         TRAD_HEADER='"hosts/i386sco.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3456]86-*-mach3*)
 242 changequote([,])dnl
 243         COREFILE=trad-core.lo
 244         TRAD_HEADER='"hosts/i386mach3.h"'
 245         ;;
 246 changequote(,)dnl
 247   i[3456]86-*-linux-gnu*)
 248 changequote([,])dnl
 249         COREFILE=trad-core.lo
 250         TRAD_HEADER='"hosts/i386linux.h"'
 251         ;;
 252 changequote(,)dnl
 253   i[3456]86-*-isc*)     COREFILE=trad-core.lo ;;
 254   i[3456]86-*-aix*)     COREFILE=aix386-core.lo ;;
 255 changequote([,])dnl
 256   i860-*-mach3* | i860-*-osf1*)
 257         COREFILE=trad-core.lo
 258         TRAD_HEADER='"hosts/i860mach3.h"'
 259         ;;
 260   mips-dec-bsd*)
 261         COREFILE=trad-core.lo
 262         TRAD_HEADER='"hosts/mipsbsd.h"'
 263         ;;
 264   mips-dec-mach3*)
 265         COREFILE=trad-core.lo
 266         TRAD_HEADER='"hosts/mipsmach3.h"'
 267         ;;
 268   mips-*-netbsd* | mips*-*-openbsd*)
 269         COREFILE=netbsd-core.lo
 270         ;;
 271   mips-dec-*)
 272         COREFILE=trad-core.lo
 273         TRAD_HEADER='"hosts/decstation.h"'
 274         ;;
 275   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 276   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 277   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 278   mips-*-mach3*)
 279         COREFILE=trad-core.lo
 280         TRAD_HEADER='"hosts/mipsmach3.h"'
 281         ;;
 282   mips-*-sysv4*)        ;;
 283   mips-*-sysv* | mips-*-riscos*)
 284         COREFILE=trad-core.lo
 285         TRAD_HEADER='"hosts/riscos.h"'
 286         ;;
 287   mips-sony-bsd*)
 288         COREFILE=trad-core.lo
 289         TRAD_HEADER='"hosts/news-mips.h"'
 290         ;;
 291   m68*-bull*-sysv*)
 292         COREFILE=trad-core.lo
 293         TRAD_HEADER='"hosts/dpx2.h"'
 294         ;;
 295   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 296   m68*-hp-bsd*)
 297         COREFILE=trad-core.lo
 298         TRAD_HEADER='"hosts/hp300bsd.h"'
 299         ;;
 300   m68*-*-linux-gnu*)
 301         COREFILE=trad-core.lo
 302         TRAD_HEADER='"hosts/m68klinux.h"'
 303         ;;
 304   m68*-motorola-sysv*)
 305         COREFILE=trad-core.lo
 306         TRAD_HEADER='"hosts/delta68.h"'
 307         ;;
 308   m68*-sony-*)
 309         COREFILE=trad-core.lo
 310         TRAD_HEADER='"hosts/news.h"'
 311         ;;
 312   m68*-*-netbsd* | m68*-*-openbsd*)
 313         COREFILE=netbsd-core.lo
 314         ;;
 315   m68*-apple-aux*)
 316         COREFILE=trad-core.lo
 317         TRAD_HEADER='"hosts/m68kaux.h"'
 318         ;;
 319   m88*-*-sysv4*)        ;;
 320   m88*-motorola-sysv*)  COREFILE=ptrace-core.lo ;;
 321   m88*-*-mach3*)
 322         COREFILE=trad-core.lo
 323         TRAD_HEADER='"hosts/m88kmach3.h"'
 324         ;;
 325   ns32k-pc532-mach)
 326         COREFILE=trad-core.lo
 327         TRAD_HEADER='"hosts/pc532mach.h"'
 328         ;;
 329   ns32k-*-netbsd* | ns32k-*-openbsd*)
 330         COREFILE=netbsd-core.lo
 331         ;;
 332   rs6000-*-lynx*)       COREFILE=lynx-core.lo ;;
 333 changequote(,)dnl
 334   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 335 changequote([,])dnl
 336         COREFILE=rs6000-core.lo
 337         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 338         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 339         # have c_impl as a member of struct core_dumpx
 340         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 341         AC_TRY_COMPILE([#include <core.h>],
 342           [struct core_dumpx c; c.c_impl = 0;],
 343           [AC_DEFINE(HAVE_ST_C_IMPL, 1,
 344             [Define if struct core_dumpx has member c_impl])
 345           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 346         ;;
 347   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 348   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 349   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 350   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 351   powerpc-*-beos*)      ;;
 352   powerpc-*-dragonfly*) COREFILE='' ;;
 353   powerpc-*-freebsd*)   COREFILE='' ;;
 354   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 355   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 356   s390*-*-*)            COREFILE=trad-core.lo ;;
 357   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 358   sparc-*-netbsd* | sparc-*-openbsd*)
 359         COREFILE=netbsd-core.lo
 360         ;;
 361   tahoe-*-*)
 362         COREFILE=trad-core.lo
 363         TRAD_HEADER='"hosts/tahoe.h"'
 364         ;;
 365   vax-*-ultrix2*)
 366         COREFILE=trad-core.lo
 367         TRAD_HEADER='"hosts/vaxult2.h"'
 368         ;;
 369   vax-*-ultrix*)
 370         COREFILE=trad-core.lo
 371         TRAD_HEADER='"hosts/vaxult2.h"'
 372         ;;
 373   vax-*-*)
 374         COREFILE=trad-core.lo
 375         TRAD_HEADER='"hosts/vaxbsd.h"'
 376         ;;
 377   x86_64-*-netbsd*)     COREFILE=netbsd-core.lo ;;
 378   esac
 379
 380   case "$COREFILE" in
 381   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 382   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 383   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 384   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 385   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 386   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 387   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 388   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 389   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 390   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 391   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 392   esac
 393
 394   # ELF corefile support has several flavors, but all of
 395   # them use something called <sys/procfs.h>
 396   AC_CHECK_HEADERS(sys/procfs.h)
 397   if test "$ac_cv_header_sys_procfs_h" = yes; then
 398     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 399     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 400     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 401     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 402     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 403     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 412     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 413     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 414   fi
 415 fi
 416 AC_SUBST(COREFILE)
 417 AC_SUBST(COREFLAG)
 418 if test -n "$TRAD_HEADER"; then
 419   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 420     [Name of host specific header file to include in trad-core.c.])
 421 fi
 422
 423 # Horrible hacks to build DLLs on Windows.
 424 WIN32LDFLAGS=
 425 WIN32LIBADD=
 426 case "${host}" in
 427 *-*-cygwin*)
 428   if test "$enable_shared" = "yes"; then
 429     WIN32LDFLAGS="-no-undefined"
 430     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 431   fi
 432   ;;
 433 *-*-linux*)
 434   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 435   # libiberty.a.
 436   case "${host}" in
 437   mips*-*-linux*)
 438     # Linux/MIPS uses PIC by default.
 439     if test "$enable_shared" = "yes"; then
 440       WIN32LIBADD="-L../libiberty -liberty"
 441     fi
 442     ;;
 443   *)
 444 changequote(,)dnl
 445     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | tail -1`
 446 changequote([,])dnl
 447     if test -n "$x"; then
 448       WIN32LIBADD="-L../libiberty/pic -liberty"
 449     fi
 450   ;;
 451   esac
 452   ;;
 453 esac
 454 AC_SUBST(WIN32LDFLAGS)
 455 AC_SUBST(WIN32LIBADD)
 456
 457 # target stuff:
 458
 459 # Canonicalize the secondary target names.
 460 if test -n "$enable_targets" ; then
 461     for targ in `echo $enable_targets | sed 's/,/ /g'`
 462     do
 463         result=`$ac_config_sub $targ 2>/dev/null`
 464         if test -n "$result" ; then
 465             canon_targets="$canon_targets $result"
 466         else
 467             # Allow targets that config.sub doesn't recognize, like "all".
 468             canon_targets="$canon_targets $targ"
 469         fi
 470     done
 471 fi
 472
 473 all_targets=false
 474 defvec=
 475 selvecs=
 476 selarchs=
 477 TDEFINES=
 478 for targ in $target $canon_targets
 479 do
 480     if test "x$targ" = "xall"; then
 481         all_targets=true
 482     else
 483         . $srcdir/config.bfd
 484         if test "x$targ" = "x$target"; then
 485             defvec=$targ_defvec
 486         fi
 487         selvecs="$selvecs $targ_defvec $targ_selvecs"
 488         selarchs="$selarchs $targ_archs"
 489         TDEFINES="$TDEFINES $targ_cflags"
 490     fi
 491 done
 492 AC_SUBST(TDEFINES)
 493
 494 # This processing still needs to be done if we're to decide properly whether
 495 # 64-bit support needs to be compiled in.  Currently, it will be included if
 496 # the default or any other explicitly requested target requires it; it
 497 # will not be included on a 32-bit host if no 64-bit target is requested, and
 498 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 499 # used.
 500
 501 # uniq the default and selected vectors in all the configured targets.
 502 f=""
 503 for i in $selvecs ; do
 504     case " $f " in
 505     *" $i "*) ;;
 506     *) f="$f $i" ;;
 507     esac
 508 done
 509 selvecs="$f"
 510
 511
 512 # uniq the architectures in all the configured targets.
 513 f=""
 514 for i in $selarchs ; do
 515     case " $f " in
 516     *" $i "*) ;;
 517     *) f="$f $i" ;;
 518     esac
 519 done
 520 selarchs="$f"
 521
 522 # Target backend .o files.
 523 tb=
 524
 525 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 526
 527 for vec in $selvecs
 528 do
 529     target_size=32
 530     case "$vec" in
 531     # This list is alphabetized to make it easy to compare
 532     # with the two vector lists in targets.c.  For the same reason,
 533     # use one entry per line, even though this leads to long lines.
 534     # FIXME: We include cofflink.lo not because it's needed for
 535     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 536     # which needs it but does not list it.  Should be fixed in right place.
 537     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo"
 538                                 target_size=64 ;;
 539     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32.lo $elf cofflink.lo"
 540                                 target_size=64 ;;
 541     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf"
 542                                 target_size=64 ;;
 543     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf"
 544                                 target_size=64 ;;
 545     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 546     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 547     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 548     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 549     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 550     aout_mips_big_vec)          tb="$tb mipsbsd.lo aout32.lo" ;;
 551     aout_mips_little_vec)       tb="$tb mipsbsd.lo aout32.lo" ;;
 552     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 553     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 554     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 555     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 556     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 557     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 558     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 559     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 560     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 561     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 562     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 563     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 564     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 565     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 566     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 567     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 568     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 569     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 570     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 571     bfd_elf32_bigarm_oabi_vec)  tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 572     bfd_elf32_bigarm_vec)       tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 573     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 574     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 575     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 576     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 577     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 578     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 579     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 580     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 581     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 582     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 583     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 584     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 585     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 586     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 587     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 588     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 589     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 590     bfd_elf32_littlearm_oabi_vec) tb="$tb elfarm-oabi.lo elf32.lo $elf" ;;
 591     bfd_elf32_littlearm_vec)    tb="$tb elfarm-nabi.lo elf32.lo $elf" ;;
 592     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 593     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 594     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32.lo $elf" ;;
 595     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32.lo $elf" ;;
 596     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 597     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 598     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 599     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 600     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 601     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 602     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 603     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 604     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 605     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 606     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 607     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 608     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 609     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 610     bfd_elf32_shblin_vec)       tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 611     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 612     bfd_elf32_shlin_vec)        tb="$tb elf32-sh-lin.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 613     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 614     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh-nbsd.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 615     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elf32.lo $elf" ;;
 616     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 617     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elf32.lo $elf ecofflink.lo" ;;
 618     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 619     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 620     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 621     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 622     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 623     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 624     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 625     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 626     bfd_elf64_ia64_aix_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 627     bfd_elf64_ia64_aix_little_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 628     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 629     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 630     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 631     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 632     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elf32-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 633     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 634     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 635     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 636     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 637     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elf64.lo $elf"; target_size=64 ;;
 638     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo $elf ecofflink.lo"; target_size=64 ;;
 639     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo $elf ecofflink.lo"; target_size=64 ;;
 640     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 641     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 642     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 643     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 644     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 645     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 646     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 647     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 648     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 649     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 650     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 651     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 652     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 653     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 654     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 655     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 656     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 657     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 658     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 659     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 660     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 661     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 662     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 663     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 664     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 665     i386dragonfly_vec)          tb="$tb i386dargonfly.lo aout32.lo" ;;
 666     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 667     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 668     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 669     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 670     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 671     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 672     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 673     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 674     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 675     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 676     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 677     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 678     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 679     ieee_vec)                   tb="$tb ieee.lo" ;;
 680     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 681     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 682     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 683     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 684     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 685     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 686     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 687     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 688     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 689     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 690     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 691     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 692     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 693     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 694     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 695     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 696     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 697     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 698     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 699     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 700     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 701     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 702     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 703     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 704     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 705     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 706     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 707     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 708     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo"; target_size=64 ;;
 709     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 710     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 711     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 712     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 713     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 714     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 715     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 716     som_vec)                    tb="$tb som.lo" ;;
 717     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 718     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 719     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 720     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 721     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 722     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 723     srec_vec)                   tb="$tb srec.lo" ;;
 724     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 725     symbolsrec_vec)             tb="$tb srec.lo" ;;
 726     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 727     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 728     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 729     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 730     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 731     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 732     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 733     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 734     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 735     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 736     versados_vec)               tb="$tb versados.lo" ;;
 737     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 738     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 739     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 740     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 741     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 742
 743     "")                 ;;
 744     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 745     esac
 746
 747     if test ${target_size} = 64; then
 748         target64=true
 749     fi
 750     if test x"${vec}" = x"${defvec}"; then
 751         bfd_default_target_size=${target_size}
 752     fi
 753 done
 754
 755 # Target architecture .o files.
 756 # A couple of CPUs use shorter file names to avoid problems on DOS
 757 # filesystems.
 758 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 759
 760 # Weed out duplicate .o files.
 761 f=""
 762 for i in $tb ; do
 763     case " $f " in
 764     *" $i "*) ;;
 765     *) f="$f $i" ;;
 766     esac
 767 done
 768 tb="$f"
 769
 770 f=""
 771 for i in $ta ; do
 772     case " $f " in
 773     *" $i "*) ;;
 774     *) f="$f $i" ;;
 775     esac
 776 done
 777 ta="$f"
 778
 779 bfd_backends="$tb"
 780 bfd_machines="$ta"
 781
 782 if test x${all_targets} = xtrue ; then
 783   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 784   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 785   selvecs=
 786   havevecs=
 787   selarchs=
 788 else    # all_targets is true
 789   # Only set these if they will be nonempty, for the clever echo.
 790   havevecs=
 791   test -n "$selvecs" &&
 792     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 793   test -n "$selvecs" &&
 794     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 795   test -n "$selarchs" &&
 796     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 797 fi      # all_targets is true
 798
 799 case ${host64}-${target64}-${want64} in
 800   *true*)
 801     wordsize=64
 802     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 803     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 804     if test -z "$GCC" && test "$BFD_HOST_64BIT_LONG" = "0" && test "$BFD_HOST_64_BIT_DEFINED" = "0"; then
 805       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 806       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 807     fi
 808     if test -n "$GCC" ; then
 809        bad_64bit_gcc=no;
 810        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 811        # Add more tests for gcc versions with non-working 64-bit support here.
 812        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 813                     bad_64bit_gcc=yes;
 814                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 815                     AC_MSG_RESULT(no))
 816        if test $bad_64bit_gcc = yes ; then
 817          AC_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 818        fi
 819     fi
 820     ;;
 821   false-false-false)
 822     wordsize=32
 823     bfd_libs='$(BFD32_LIBS)'
 824     all_backends='$(BFD32_BACKENDS)'
 825     ;;
 826 esac
 827
 828 AC_SUBST(wordsize)
 829 AC_SUBST(bfd_libs)
 830 AC_SUBST(all_backends)
 831 AC_SUBST(bfd_backends)
 832 AC_SUBST(bfd_machines)
 833 AC_SUBST(bfd_default_target_size)
 834
 835 tdefaults=""
 836 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 837 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 838 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 839 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 840 AC_SUBST(tdefaults)
 841
 842 dnl AC_CHECK_HEADERS(sys/mman.h)
 843 AC_FUNC_MMAP
 844 AC_CHECK_FUNCS(madvise mprotect)
 845 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 846   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 847 esac
 848
 849 rm -f doc/config.status
 850 AC_OUTPUT(Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in,
 851 [sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile])
 852