lib/libcr/alpha/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.2 1996/10/17 03:08:03 cgd Exp $  */
   2
   3 /*
   4  * Copyright (c) 1994, 1995 Carnegie-Mellon University.
   5  * All rights reserved.
   6  *
   7  * Author: Chris G. Demetriou
   8  *
   9  * Permission to use, copy, modify and distribute this software and
  10  * its documentation is hereby granted, provided that both the copyright
  11  * notice and this permission notice appear in all copies of the
  12  * software, derivative works or modified versions, and any portions
  13  * thereof, and that both notices appear in supporting documentation.
  14  *
  15  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  16  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND
  17  * FOR ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  18  *
  19  * Carnegie Mellon requests users of this software to return to
  20  *
  21  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  22  *  School of Computer Science
  23  *  Carnegie Mellon University
  24  *  Pittsburgh PA 15213-3890
  25  *
  26  * any improvements or extensions that they make and grant Carnegie the
  27  * rights to redistribute these changes.
  28  *
  29  * $FreeBSD: src/lib/libc/alpha/gen/_setjmp.S,v 1.4.2.3 2001/12/30 19:52:20 deischen Exp $
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 /*
  35  * C library -- _setjmp, _longjmp
  36  *
  37  *      _longjmp(a,v)
  38  * will generate a "return(v)" from
  39  * the last call to
  40  *      _setjmp(a)
  41  * by restoring registers from the stack,
  42  * The previous signal state is NOT restored.
  43  */
  44
  45         .set    noreorder
  46
  47 LEAF(_setjmp, 1)
  48         LDGP(pv)
  49         stq     ra, (2 * 8)(a0)                 /* sc_pc = return address */
  50         stq     s0, (( 9 + 4) * 8)(a0)          /* saved bits of sc_regs */
  51         stq     s1, ((10 + 4) * 8)(a0)
  52         stq     s2, ((11 + 4) * 8)(a0)
  53         stq     s3, ((12 + 4) * 8)(a0)
  54         stq     s4, ((13 + 4) * 8)(a0)
  55         stq     s5, ((14 + 4) * 8)(a0)
  56         stq     s6, ((15 + 4) * 8)(a0)
  57         stq     ra, ((26 + 4) * 8)(a0)
  58         stq     t12,((27 + 4) * 8)(a0)
  59         stq     sp, ((30 + 4) * 8)(a0)
  60         ldiq    t0, 0xacedbadd                  /* sigcontext magic number */
  61         stq     t0, ((31 + 4) * 8)(a0)          /* magic in sc_regs[31] */
  62         /* Too bad we can't check if we actually used FP */
  63         ldiq    t0, 1
  64         stq     t0, (36 * 8)(a0)                /* say we've used FP.  */
  65         stt     fs0, ((2 + 37) * 8)(a0)         /* saved bits of sc_fpregs */
  66         stt     fs1, ((3 + 37) * 8)(a0)
  67         stt     fs2, ((4 + 37) * 8)(a0)
  68         stt     fs3, ((5 + 37) * 8)(a0)
  69         stt     fs4, ((6 + 37) * 8)(a0)
  70         stt     fs5, ((7 + 37) * 8)(a0)
  71         stt     fs6, ((8 + 37) * 8)(a0)
  72         stt     fs7, ((9 + 37) * 8)(a0)
  73         mf_fpcr ft0                             /* get FP control reg */
  74         stt     ft0, (69 * 8)(a0)               /* and store it in sc_fpcr */
  75         stq     zero, (70 * 8)(a0)              /* FP software control XXX */
  76         stq     zero, (71 * 8)(a0)              /* sc_reserved[0] */
  77         stq     zero, (72 * 8)(a0)              /* sc_reserved[1] */
  78         stq     zero, (73 * 8)(a0)              /* sc_xxx[0] */
  79         stq     zero, (74 * 8)(a0)              /* sc_xxx[1] */
  80         stq     zero, (75 * 8)(a0)              /* sc_xxx[2] */
  81         stq     zero, (76 * 8)(a0)              /* sc_xxx[3] */
  82         stq     zero, (77 * 8)(a0)              /* sc_xxx[4] */
  83         stq     zero, (78 * 8)(a0)              /* sc_xxx[5] */
  84         stq     zero, (79 * 8)(a0)              /* sc_xxx[6] */
  85         stq     zero, (80 * 8)(a0)              /* sc_xxx[7] */
  86
  87         mov     zero, v0                        /* return zero */
  88         RET
  89 END(_setjmp)
  90
  91 #ifdef _THREAD_SAFE
  92 LEAF(___longjmp, 2)
  93 #else
  94 XLEAF(___longjmp, 2)
  95 LEAF(_longjmp, 2)
  96 #endif
  97         LDGP(pv)
  98         ldq     t0, ((31 + 4) * 8)(a0)          /* magic in sc_regs[31] */
  99         ldiq    t1, 0xacedbadd
 100         cmpeq   t0, t1, t0
 101         beq     t0, botch                       /* If the magic was bad, punt */
 102
 103         ldq     ra, (2 * 8)(a0)                 /* sc_pc = return address */
 104         ldq     s0, (( 9 + 4) * 8)(a0)          /* saved bits of sc_regs */
 105         ldq     s1, ((10 + 4) * 8)(a0)
 106         ldq     s2, ((11 + 4) * 8)(a0)
 107         ldq     s3, ((12 + 4) * 8)(a0)
 108         ldq     s4, ((13 + 4) * 8)(a0)
 109         ldq     s5, ((14 + 4) * 8)(a0)
 110         ldq     s6, ((15 + 4) * 8)(a0)
 111         /* ldq  ra, ((26 + 4) * 8)(a0)          set above */
 112         ldq     t12,((27 + 4) * 8)(a0)
 113         ldq     sp, ((30 + 4) * 8)(a0)
 114         ldt     fs0, ((2 + 37) * 8)(a0)         /* saved bits of sc_fpregs */
 115         ldt     fs1, ((3 + 37) * 8)(a0)
 116         ldt     fs2, ((4 + 37) * 8)(a0)
 117         ldt     fs3, ((5 + 37) * 8)(a0)
 118         ldt     fs4, ((6 + 37) * 8)(a0)
 119         ldt     fs5, ((7 + 37) * 8)(a0)
 120         ldt     fs6, ((8 + 37) * 8)(a0)
 121         ldt     fs7, ((9 + 37) * 8)(a0)
 122         ldt     ft0, (69 * 8)(a0)               /* get sc_fpcr */
 123         mt_fpcr ft0                             /* and restore it. */
 124
 125         mov     a1, v0                          /* return second arg */
 126         RET
 127
 128 botch:
 129         CALL(longjmperror)
 130         CALL(abort)
 131         RET                                     /* "can't" get here... */
 132 #ifdef _THREAD_SAFE
 133 END(___longjmp)
 134 #else
 135 END(_longjmp)
 136 #endif