lib/libcr/alpha/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.3 1997/12/05 02:06:27 thorpej Exp $       */
   2
   3 /*
   4  * Copyright (c) 1994, 1995 Carnegie-Mellon University.
   5  * All rights reserved.
   6  *
   7  * Author: Chris G. Demetriou
   8  *
   9  * Permission to use, copy, modify and distribute this software and
  10  * its documentation is hereby granted, provided that both the copyright
  11  * notice and this permission notice appear in all copies of the
  12  * software, derivative works or modified versions, and any portions
  13  * thereof, and that both notices appear in supporting documentation.
  14  *
  15  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  16  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND
  17  * FOR ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  18  *
  19  * Carnegie Mellon requests users of this software to return to
  20  *
  21  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  22  *  School of Computer Science
  23  *  Carnegie Mellon University
  24  *  Pittsburgh PA 15213-3890
  25  *
  26  * any improvements or extensions that they make and grant Carnegie the
  27  * rights to redistribute these changes.
  28  *
  29  * $FreeBSD: src/lib/libc/alpha/gen/setjmp.S,v 1.11.2.3 2002/11/13 06:08:44 fjoe Exp $
  30  */
  31
  32 #include "SYS.h"
  33
  34 /*
  35  * C library -- setjmp, longjmp
  36  *
  37  *      longjmp(a,v)
  38  * will generate a "return(v)" from
  39  * the last call to
  40  *      setjmp(a)
  41  * by restoring registers from the stack,
  42  * and the previous signal state.
  43  */
  44
  45         .set    noreorder
  46
  47 LEAF(setjmp, 1)
  48         LDGP(pv)
  49         stq     ra, (2 * 8)(a0)                 /* sc_pc = return address */
  50         stq     s0, (( 9 + 4) * 8)(a0)          /* saved bits of sc_regs */
  51         stq     s1, ((10 + 4) * 8)(a0)
  52         stq     s2, ((11 + 4) * 8)(a0)
  53         stq     s3, ((12 + 4) * 8)(a0)
  54         stq     s4, ((13 + 4) * 8)(a0)
  55         stq     s5, ((14 + 4) * 8)(a0)
  56         stq     s6, ((15 + 4) * 8)(a0)
  57         stq     ra, ((26 + 4) * 8)(a0)
  58         stq     t12,((27 + 4) * 8)(a0)
  59         stq     sp, ((30 + 4) * 8)(a0)
  60
  61         /*
  62          * get signal information
  63          */
  64         mov     a0, s0                          /* squirrel away ptr to sc */
  65
  66         /* see what's blocked */
  67         lda     a2, (71 * 8)(a0)                /* oset: sc_reserved */
  68         mov     zero, a1                        /* set:  NULL */
  69         addq    a1, 1, a0                       /* how:  SIG_BLOCK */
  70         PCALL(sigprocmask)                      /* see what's blocked */
  71
  72         lda     sp, -24(sp)                     /* sizeof struct sigaltstack */
  73         mov     zero, a0
  74         mov     sp, a1
  75         CALL(sigaltstack)
  76         ldl     t0, 16(sp)                      /* offset of ss_flags */
  77         lda     sp, 24(sp)                      /* sizeof struct sigaltstack */
  78         ldq     ra, ((26 + 4) * 8)(s0)          /* restore return address */
  79         blt     v0, botch                       /* check for error */
  80         and     t0, 0x1, t0                     /* get SA_ONSTACK flag */
  81         stq     t0, (0 * 8)(s0)                 /* and save it in sc_onstack */
  82         /*
  83          * Restore old s0 and a0, and continue saving registers
  84          */
  85         mov     s0, a0
  86         ldq     s0, (( 9 + 4) * 8)(a0)
  87
  88         ldiq    t0, 0xacedbade                  /* sigcontext magic number */
  89         stq     t0, ((31 + 4) * 8)(a0)          /* magic in sc_regs[31] */
  90         /* Too bad we can't check if we actually used FP */
  91         ldiq    t0, 1
  92         stq     t0, (36 * 8)(a0)                /* say we've used FP.  */
  93         stt     fs0, ((2 + 37) * 8)(a0)         /* saved bits of sc_fpregs */
  94         stt     fs1, ((3 + 37) * 8)(a0)
  95         stt     fs2, ((4 + 37) * 8)(a0)
  96         stt     fs3, ((5 + 37) * 8)(a0)
  97         stt     fs4, ((6 + 37) * 8)(a0)
  98         stt     fs5, ((7 + 37) * 8)(a0)
  99         stt     fs6, ((8 + 37) * 8)(a0)
 100         stt     fs7, ((9 + 37) * 8)(a0)
 101         mf_fpcr ft0                             /* get FP control reg */
 102         stt     ft0, (69 * 8)(a0)               /* and store it in sc_fpcr */
 103         stq     zero, (70 * 8)(a0)              /* FP software control XXX */
 104         stq     zero, (71 * 8)(a0)              /* sc_reserved[0] */
 105         stq     zero, (72 * 8)(a0)              /* sc_reserved[1] */
 106         stq     zero, (73 * 8)(a0)              /* sc_xxx[0] */
 107         stq     zero, (74 * 8)(a0)              /* sc_xxx[1] */
 108         stq     zero, (75 * 8)(a0)              /* sc_xxx[2] */
 109         stq     zero, (76 * 8)(a0)              /* sc_xxx[3] */
 110         stq     zero, (77 * 8)(a0)              /* sc_xxx[4] */
 111         stq     zero, (78 * 8)(a0)              /* sc_xxx[5] */
 112         stq     zero, (79 * 8)(a0)              /* sc_xxx[6] */
 113         stq     zero, (80 * 8)(a0)              /* sc_xxx[7] */
 114
 115         mov     zero, v0                        /* return zero */
 116         RET
 117 END(setjmp)
 118
 119 #ifdef _THREAD_SAFE
 120 LEAF(__longjmp, 2)
 121 #else
 122 XLEAF(__longjmp, 2)
 123 LEAF(longjmp, 2)
 124 #endif
 125         LDGP(pv)
 126         stq     a1, (( 0 + 4) * 8)(a0)          /* save return value */
 127         CALL(sigreturn)                         /* use sigreturn to return */
 128
 129 botch:
 130         CALL(longjmperror)
 131         CALL(abort)
 132         RET                                     /* "can't" get here... */
 133 #ifdef _THREAD_SAFE
 134 END(__longjmp)
 135 #else
 136 END(longjmp)
 137 #endif