lib/libcr/i386/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD: src/lib/libc/i386/gen/sigsetjmp.S,v 1.19.2.2 2001/07/06 12:41:44 deischen Exp $
  37  */
  38
  39 #if defined(LIBC_RCS) && !defined(lint)
  40         .text
  41         .asciz "$FreeBSD: src/lib/libc/i386/gen/sigsetjmp.S,v 1.19.2.2 2001/07/06 12:41:44 deischen Exp $"
  42 #endif /* LIBC_RCS and not lint */
  43
  44 #include "DEFS.h"
  45 #include "SYS.h"
  46
  47 /*-
  48  * TODO:
  49  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  50  *      remove the other *jmp functions and define everything in terms
  51  *      of the renamed functions.  This requires compiler support for
  52  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  53  *      only supported *jmp with 0 or 1 leading underscores).
  54  *
  55  *      Use sigprocmask() instead of sigblock() and sigsetmask(), and
  56  *      check for and handle errors.
  57  *
  58  *      Restore _all_ the registers and the signal mask atomically.  Can
  59  *      use sigreturn() if sigreturn() works.
  60  */
  61
  62 ENTRY(sigsetjmp)
  63         movl    8(%esp),%eax
  64         movl    4(%esp),%ecx
  65         movl    %eax,44(%ecx)
  66         testl   %eax,%eax
  67         jz      2f
  68         PIC_PROLOGUE
  69         leal    28(%ecx), %eax
  70         pushl   %eax                    /* (sigset_t*)oset */
  71         pushl   $0                      /* (sigset_t*)set  */
  72         pushl   $1                      /* SIG_BLOCK       */
  73         call    PIC_PLT(CNAME(sigprocmask))
  74         addl    $12,%esp
  75         PIC_EPILOGUE
  76         movl    4(%esp),%ecx
  77 2:      movl    0(%esp),%edx
  78         movl    %edx, 0(%ecx)
  79         movl    %ebx, 4(%ecx)
  80         movl    %esp, 8(%ecx)
  81         movl    %ebp,12(%ecx)
  82         movl    %esi,16(%ecx)
  83         movl    %edi,20(%ecx)
  84         fnstcw  24(%ecx)
  85         xorl    %eax,%eax
  86         ret
  87
  88 #ifndef _THREAD_SAFE
  89 .weak CNAME(siglongjmp);
  90 .set CNAME(siglongjmp),CNAME(__siglongjmp);
  91 #endif
  92 ENTRY(__siglongjmp);
  93         movl    4(%esp),%edx
  94         cmpl    $0,44(%edx)
  95         jz      2f
  96         PIC_PROLOGUE
  97         pushl   $0                      /* (sigset_t*)oset */
  98         leal    28(%edx), %eax
  99         pushl   %eax                    /* (sigset_t*)set  */
 100         pushl   $3                      /* SIG_SETMASK     */
 101         call    PIC_PLT(CNAME(sigprocmask))
 102         addl    $12,%esp
 103         PIC_EPILOGUE
 104         movl    4(%esp),%edx
 105 2:      movl    8(%esp),%eax
 106         movl    0(%edx),%ecx
 107         movl    4(%edx),%ebx
 108         movl    8(%edx),%esp
 109         movl    12(%edx),%ebp
 110         movl    16(%edx),%esi
 111         movl    20(%edx),%edi
 112         fninit
 113         fldcw   24(%edx)
 114         testl   %eax,%eax
 115         jnz     1f
 116         incl    %eax
 117 1:      movl    %ecx,0(%esp)
 118         ret