release/scripts/driver-remove.awk

   1 #!/usr/bin/awk -f
   2 #
   3 # Copyright (c) 2000  "HOSOKAWA, Tatsumi" <hosokawa@FreeBSD.org>
   4 # Copyright (c) 2002  Ruslan Ermilov <ru@FreeBSD.org>
   5 # All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions
   9 # are met:
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in the
  14 #    documentation and/or other materials provided with the distribution.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  17 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  19 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  22 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  23 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  24 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  25 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  26 # SUCH DAMAGE.
  27 #
  28 # $FreeBSD: src/release/scripts/driver-remove.awk,v 1.2.2.1 2002/08/08 08:38:18 ru Exp $
  29 # $DragonFly: src/release/scripts/Attic/driver-remove.awk,v 1.2 2003/06/17 04:27:21 dillon Exp $
  30 #
  31
  32 function usage()
  33 {
  34         print "usage: driver-remove.awk config_file BOOTMFS" > "/dev/stderr";
  35         exit 1;
  36 }
  37
  38 function err(eval, fmt, what)
  39 {
  40         printf "driver-remove.awk: " fmt "\n", what > "/dev/stderr";
  41         exit eval;
  42 }
  43
  44 function readconfig()
  45 {
  46         while ((r = (getline < config)) > 0) {
  47                 sub("#.*$", "");
  48                 if (sub(/^[[:alnum:]_]+[ \t]+[[:alnum:]_]+[ \t]+[0-9]+[ \t]+[[:alnum:]_]+[ \t]+\".*\"[ \t]*$/, "&")) {
  49                         sub(/[ \t]+/, "#");
  50                         sub(/[ \t]+/, "#");
  51                         sub(/[ \t]+/, "#");
  52                         sub(/[ \t]+/, "#");
  53                         sub(/\"/, "");
  54                         sub(/\"/, "");
  55                         split($0, arg, "#");
  56                         if (arg[4] == "options")
  57                                 options[arg[1]] = 1;
  58                         else
  59                                 drivers[arg[1]] = 1;
  60                 }
  61         }
  62         if (r == -1)
  63                 err(1, "error reading %s", config);
  64         close(config);
  65 }
  66
  67 BEGIN {
  68         if (ARGC != 3)
  69                 usage();
  70
  71         config = ARGV[1];
  72         bootmfs = ARGV[2];
  73
  74         readconfig();
  75
  76         lines = 0;
  77         while ((r = (getline < bootmfs)) > 0) {
  78                 if (/^device[ \t]+[[:alnum:]_]+/) {
  79                         dev = $0;
  80                         sub(/^device[ \t]+/, "", dev);
  81                         sub(/[ \t]+.*$/, "", dev);
  82                         if (dev in drivers)
  83                                 continue;
  84                 } else if (/^options[ \t]+[[:alnum:]_]+/) {
  85                         opt = $0;
  86                         sub(/^options[ \t]+/, "", opt);
  87                         sub(/[ \t]+.*$/, "", opt);
  88                         if (opt in options)
  89                                 continue;
  90                 }
  91                 line[lines++] = $0;
  92         }
  93         if (r == -1)
  94                 err(1, "error reading %s", bootmfs);
  95         close(bootmfs);
  96         printf "" > bootmfs;
  97         for (i = 0; i < lines; i++)
  98                 print line[i] >> bootmfs;
  99         close(bootmfs);
 100 }