crypto/kerberosIV/cf/shared-libs.m4

   1 dnl
   2 dnl $Id: shared-libs.m4,v 1.4.14.3 2000/12/07 18:03:00 bg Exp $
   3 dnl
   4 dnl Shared library stuff has to be different everywhere
   5 dnl
   6
   7 AC_DEFUN(AC_SHARED_LIBS, [
   8
   9 dnl Check if we want to use shared libraries
  10 AC_ARG_ENABLE(shared,
  11 [  --enable-shared         create shared libraries for Kerberos])
  12
  13 AC_SUBST(CFLAGS)dnl
  14 AC_SUBST(LDFLAGS)dnl
  15
  16 case ${enable_shared} in
  17   yes ) enable_shared=yes;;
  18   no  ) enable_shared=no;;
  19   *   ) enable_shared=no;;
  20 esac
  21
  22 # NOTE: Building shared libraries may not work if you do not use gcc!
  23 #
  24 # OS            $SHLIBEXT
  25 # HP-UX         sl
  26 # Linux         so
  27 # NetBSD        so
  28 # FreeBSD       so
  29 # OSF           so
  30 # SunOS5        so
  31 # SunOS4        so.0.5
  32 # Irix          so
  33 #
  34 # LIBEXT is the extension we should build (.a or $SHLIBEXT)
  35 LINK='$(CC)'
  36 AC_SUBST(LINK)
  37 lib_deps=yes
  38 REAL_PICFLAGS="-fpic"
  39 LDSHARED='$(CC) $(PICFLAGS) -shared'
  40 LIBPREFIX=lib
  41 build_symlink_command=@true
  42 install_symlink_command=@true
  43 install_symlink_command2=@true
  44 REAL_SHLIBEXT=so
  45 changequote({,})dnl
  46 SHLIB_VERSION=`echo $VERSION | sed 's/\([0-9.]*\).*/\1/'`
  47 SHLIB_SONAME=`echo $VERSION | sed 's/\([0-9]*\).*/\1/'`
  48 changequote([,])dnl
  49 case "${host}" in
  50 *-*-hpux*)
  51         REAL_SHLIBEXT=sl
  52         REAL_LD_FLAGS='-Wl,+b$(libdir)'
  53         if test -z "$GCC"; then
  54                 LDSHARED="ld -b"
  55                 REAL_PICFLAGS="+z"
  56         fi
  57         lib_deps=no
  58         ;;
  59 *-*-linux*)
  60         LDSHARED='$(CC) -shared -Wl,-soname,$(LIBNAME).so.'"${SHLIB_SONAME}"
  61         REAL_LD_FLAGS='-Wl,-rpath,$(libdir)'
  62         REAL_SHLIBEXT=so.$SHLIB_VERSION
  63         build_symlink_command='$(LN_S) -f [$][@] $(LIBNAME).so'
  64         install_symlink_command='$(LN_S) -f $(LIB) $(DESTDIR)$(libdir)/$(LIBNAME).so.'"${SHLIB_SONAME}"';$(LN_S) -f $(LIB) $(DESTDIR)$(libdir)/$(LIBNAME).so'
  65         install_symlink_command2='$(LN_S) -f $(LIB2) $(DESTDIR)$(libdir)/$(LIBNAME2).so.'"${SHLIB_SONAME}"';$(LN_S) -f $(LIB2) $(DESTDIR)$(libdir)/$(LIBNAME2).so'
  66         ;;
  67 changequote(,)dnl
  68 *-*-freebsd[345]* | *-*-freebsdelf[345]*)
  69 changequote([,])dnl
  70         REAL_SHLIBEXT=so.$SHLIB_VERSION
  71         REAL_LD_FLAGS='-Wl,-R$(libdir)'
  72         build_symlink_command='$(LN_S) -f [$][@] $(LIBNAME).so'
  73         install_symlink_command='$(LN_S) -f $(LIB) $(DESTDIR)$(libdir)/$(LIBNAME).so'
  74         install_symlink_command2='$(LN_S) -f $(LIB2) $(DESTDIR)$(libdir)/$(LIBNAME2).so'
  75         ;;
  76 *-*-*bsd*)
  77         REAL_SHLIBEXT=so.$SHLIB_VERSION
  78         LDSHARED='ld -Bshareable'
  79         REAL_LD_FLAGS='-Wl,-R$(libdir)'
  80         ;;
  81 *-*-osf*)
  82         REAL_LD_FLAGS='-Wl,-rpath,$(libdir)'
  83         REAL_PICFLAGS=
  84         LDSHARED='ld -shared -expect_unresolved \*'
  85         ;;
  86 *-*-solaris2*)
  87         LDSHARED='$(CC) -shared -Wl,-h$(LIBNAME).so.'"${SHLIB_SONAME}"
  88         REAL_SHLIBEXT=so.$SHLIB_VERSION
  89         build_symlink_command='$(LN_S) [$][@] $(LIBNAME).so'
  90         install_symlink_command='$(LN_S) $(LIB) $(DESTDIR)$(libdir)/$(LIBNAME).so.'"${SHLIB_SONAME}"';$(LN_S) $(LIB) $(DESTDIR)$(libdir)/$(LIBNAME).so'
  91         install_symlink_command2='$(LN_S) $(LIB2) $(DESTDIR)$(libdir)/$(LIBNAME2).so.'"${SHLIB_SONAME}"';$(LN_S) $(LIB2) $(DESTDIR)$(libdir)/$(LIBNAME2).so'
  92         REAL_LD_FLAGS='-Wl,-R$(libdir)'
  93         if test -z "$GCC"; then
  94                 LDSHARED='$(CC) -G -h$(LIBNAME).so.'"${SHLIB_SONAME}"
  95                 REAL_PICFLAGS="-Kpic"
  96         fi
  97         ;;
  98 *-fujitsu-uxpv*)
  99         REAL_LD_FLAGS='' # really: LD_RUN_PATH=$(libdir) cc -o ...
 100         REAL_LINK='LD_RUN_PATH=$(libdir) $(CC)'
 101         LDSHARED='$(CC) -G'
 102         REAL_PICFLAGS="-Kpic"
 103         lib_deps=no # fails in mysterious ways
 104         ;;
 105 *-*-sunos*)
 106         REAL_SHLIBEXT=so.$SHLIB_VERSION
 107         REAL_LD_FLAGS='-Wl,-L$(libdir)'
 108         lib_deps=no
 109         ;;
 110 *-*-irix*)
 111         libdir="${libdir}${abilibdirext}"
 112         REAL_LD_FLAGS="${abi} -Wl,-rpath,\$(libdir)"
 113         LD_FLAGS="${abi} -Wl,-rpath,\$(libdir)"
 114         LDSHARED="\$(CC) -shared ${abi}"
 115         REAL_PICFLAGS=
 116         CFLAGS="${abi} ${CFLAGS}"
 117         ;;
 118 *-*-os2*)
 119         LIBPREFIX=
 120         EXECSUFFIX='.exe'
 121         RANLIB=EMXOMF
 122         LD_FLAGS=-Zcrtdll
 123         REAL_SHLIBEXT=nobuild
 124         ;;
 125 *-*-cygwin32*)
 126         EXECSUFFIX='.exe'
 127         REAL_SHLIBEXT=nobuild
 128         ;;
 129 *)      REAL_SHLIBEXT=nobuild
 130         REAL_PICFLAGS=
 131         ;;
 132 esac
 133
 134 if test "${enable_shared}" != "yes" ; then
 135  PICFLAGS=""
 136  SHLIBEXT="nobuild"
 137  LIBEXT="a"
 138  build_symlink_command=@true
 139  install_symlink_command=@true
 140  install_symlink_command2=@true
 141 else
 142  PICFLAGS="$REAL_PICFLAGS"
 143  SHLIBEXT="$REAL_SHLIBEXT"
 144  LIBEXT="$SHLIBEXT"
 145  AC_MSG_CHECKING(whether to use -rpath)
 146  case "$libdir" in
 147    /lib | /usr/lib | /usr/local/lib)
 148      AC_MSG_RESULT(no)
 149      REAL_LD_FLAGS=
 150      LD_FLAGS=
 151      ;;
 152    *)
 153      LD_FLAGS="$REAL_LD_FLAGS"
 154      test "$REAL_LINK" && LINK="$REAL_LINK"
 155      AC_MSG_RESULT($LD_FLAGS)
 156      ;;
 157    esac
 158 fi
 159
 160 if test "$lib_deps" = yes; then
 161         lib_deps_yes=""
 162         lib_deps_no="# "
 163 else
 164         lib_deps_yes="# "
 165         lib_deps_no=""
 166 fi
 167 AC_SUBST(lib_deps_yes)
 168 AC_SUBST(lib_deps_no)
 169
 170 # use supplied ld-flags, or none if `no'
 171 if test "$with_ld_flags" = no; then
 172         LD_FLAGS=
 173 elif test -n "$with_ld_flags"; then
 174         LD_FLAGS="$with_ld_flags"
 175 fi
 176
 177 AC_SUBST(REAL_PICFLAGS) dnl
 178 AC_SUBST(REAL_SHLIBEXT) dnl
 179 AC_SUBST(REAL_LD_FLAGS) dnl
 180
 181 AC_SUBST(PICFLAGS) dnl
 182 AC_SUBST(SHLIBEXT) dnl
 183 AC_SUBST(LDSHARED) dnl
 184 AC_SUBST(LD_FLAGS) dnl
 185 AC_SUBST(LIBEXT) dnl
 186 AC_SUBST(LIBPREFIX) dnl
 187 AC_SUBST(EXECSUFFIX) dnl
 188
 189 AC_SUBST(build_symlink_command)dnl
 190 AC_SUBST(install_symlink_command)dnl
 191 AC_SUBST(install_symlink_command2)dnl
 192 ])