style(9) cleanup:
[dragonfly.git] / usr.sbin / config / config.y
1 %union {
2         char    *str;
3         int     val;
4         struct  file_list *file;
5 }
6
7 %token  ANY
8 %token  ARCH
9 %token  AT
10 %token  BUS
11 %token  COMMA
12 %token  CONFIG
13 %token  CONFLICTS
14 %token  CONTROLLER
15 %token  CPU
16 %token  DEVICE
17 %token  DISABLE
18 %token  DISK
19 %token  DRIVE
20 %token  DRQ
21 %token  EQUALS
22 %token  FLAGS
23 %token  IDENT
24 %token  IOMEM
25 %token  IOSIZ
26 %token  IRQ
27 %token  MAXUSERS
28 %token  MINUS
29 %token  NEXUS
30 %token  OPTIONS
31 %token  MAKEOPTIONS
32 %token  PORT
33 %token  PSEUDO_DEVICE
34 %token  SEMICOLON
35 %token  TAPE
36 %token  TARGET
37 %token  TTY
38 %token  UNIT
39 %token  VECTOR
40
41 %token  <str>   ID
42 %token  <val>   NUMBER
43 %token  <val>   FPNUMBER
44
45 %type   <str>   Save_id
46 %type   <str>   Opt_value
47 %type   <str>   Dev
48 %type   <str>   device_name
49
50 %{
51
52 /*
53  * Copyright (c) 1988, 1993
54  *      The Regents of the University of California.  All rights reserved.
55  *
56  * Redistribution and use in source and binary forms, with or without
57  * modification, are permitted provided that the following conditions
58  * are met:
59  * 1. Redistributions of source code must retain the above copyright
60  *    notice, this list of conditions and the following disclaimer.
61  * 2. Redistributions in binary form must reproduce the above copyright
62  *    notice, this list of conditions and the following disclaimer in the
63  *    documentation and/or other materials provided with the distribution.
64  * 3. All advertising materials mentioning features or use of this software
65  *    must display the following acknowledgement:
66  *      This product includes software developed by the University of
67  *      California, Berkeley and its contributors.
68  * 4. Neither the name of the University nor the names of its contributors
69  *    may be used to endorse or promote products derived from this software
70  *    without specific prior written permission.
71  *
72  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
73  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
74  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
75  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
76  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
77  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
78  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
79  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
80  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
81  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
82  * SUCH DAMAGE.
83  *
84  *      @(#)config.y    8.1 (Berkeley) 6/6/93
85  * $FreeBSD: src/usr.sbin/config/config.y,v 1.42.2.1 2001/01/23 00:09:32 peter Exp $
86  * $DragonFly: src/usr.sbin/config/config.y,v 1.5 2004/03/04 20:29:45 eirikn Exp $
87  */
88
89 #include <ctype.h>
90 #include <err.h>
91 #include <stdio.h>
92 #include <string.h>
93
94 #include "config.h"
95
96 static struct   device cur;
97 static struct   device *curp = 0;
98
99 struct  device *dtab;
100 char    *ident;
101 int     yyline;
102 struct  file_list *ftab;
103 char    errbuf[80];
104 int     maxusers;
105
106 #define ns(s)   strdup(s)
107
108 static int connect(char *, int);
109 static void yyerror(char *s);
110
111
112 %}
113 %%
114 Configuration:
115         Many_specs
116                 ;
117
118 Many_specs:
119         Many_specs Spec
120                 |
121         /* lambda */
122                 ;
123
124 Spec:
125         Device_spec SEMICOLON
126               = { newdev(&cur); } |
127         Config_spec SEMICOLON
128                 |
129         SEMICOLON
130                 |
131         error SEMICOLON
132                 ;
133
134 Config_spec:
135         ARCH Save_id
136             = {
137                 if (machinename != NULL) {
138                     errx(1, "%d: only one machine directive is allowed",
139                         yyline);
140                 }
141                 machinename = $2;
142               } |
143         CPU Save_id
144               = {
145                 struct cputype *cp =
146                     (struct cputype *)malloc(sizeof (struct cputype));
147                 memset(cp, 0, sizeof(*cp));
148                 cp->cpu_name = $2;
149                 cp->cpu_next = cputype;
150                 cputype = cp;
151               } |
152         OPTIONS Opt_list
153                 |
154         MAKEOPTIONS Mkopt_list
155                 |
156         IDENT ID
157               = { ident = $2; } |
158         System_spec
159                 |
160         MAXUSERS NUMBER
161               = { maxusers = $2; };
162
163 System_spec:
164         CONFIG System_id System_parameter_list
165           = { errx(1,"line %d: root/dump/swap specifications obsolete", yyline);}
166           |
167         CONFIG System_id
168           ;
169
170 System_id:
171         Save_id
172               = {
173                 struct opt *op = (struct opt *)malloc(sizeof (struct opt));
174                 memset(op, 0, sizeof(*op));
175                 op->op_name = ns("KERNEL");
176                 op->op_ownfile = 0;
177                 op->op_next = mkopt;
178                 op->op_value = $1;
179                 op->op_line = yyline + 1;
180                 mkopt = op;
181               };
182
183 System_parameter_list:
184           System_parameter_list ID
185         | ID
186         ;
187
188 device_name:
189           Save_id
190                 = { $$ = $1; }
191         | Save_id NUMBER
192                 = {
193                         char buf[80];
194
195                         (void) snprintf(buf, sizeof(buf), "%s%d", $1, $2);
196                         $$ = ns(buf); free($1);
197                 }
198         | Save_id NUMBER ID
199                 = {
200                         char buf[80];
201
202                         (void) snprintf(buf, sizeof(buf), "%s%d%s", $1, $2, $3);
203                         $$ = ns(buf); free($1);
204                 }
205         | Save_id NUMBER ID NUMBER
206                 = {
207                         char buf[80];
208
209                         (void) snprintf(buf, sizeof(buf), "%s%d%s%d",
210                              $1, $2, $3, $4);
211                         $$ = ns(buf); free($1);
212                 }
213         | Save_id NUMBER ID NUMBER ID
214                 = {
215                         char buf[80];
216
217                         (void) snprintf(buf, sizeof(buf), "%s%d%s%d%s",
218                              $1, $2, $3, $4, $5);
219                         $$ = ns(buf); free($1);
220                 }
221         ;
222
223 Opt_list:
224         Opt_list COMMA Option
225                 |
226         Option
227                 ;
228
229 Option:
230         Save_id
231               = {
232                 struct opt *op = (struct opt *)malloc(sizeof (struct opt));
233                 char *s;
234                 memset(op, 0, sizeof(*op));
235                 op->op_name = $1;
236                 op->op_next = opt;
237                 op->op_value = 0;
238                 /*
239                  * op->op_line is 1-based; yyline is 0-based but is now 1
240                  * larger than when `Save_id' was lexed.
241                  */
242                 op->op_line = yyline;
243                 opt = op;
244                 if ((s = strchr(op->op_name, '=')))
245                         errx(1, "line %d: The `=' in options should not be quoted", yyline);
246               } |
247         Save_id EQUALS Opt_value
248               = {
249                 struct opt *op = (struct opt *)malloc(sizeof (struct opt));
250                 memset(op, 0, sizeof(*op));
251                 op->op_name = $1;
252                 op->op_next = opt;
253                 op->op_value = $3;
254                 op->op_line = yyline + 1;
255                 opt = op;
256               } ;
257
258 Opt_value:
259         ID
260                 = { $$ = $1; } |
261         NUMBER
262                 = {
263                         char buf[80];
264
265                         (void) snprintf(buf, sizeof(buf), "%d", $1);
266                         $$ = ns(buf);
267                 } ;
268
269 Save_id:
270         ID
271               = { $$ = $1; }
272         ;
273
274 Mkopt_list:
275         Mkopt_list COMMA Mkoption
276                 |
277         Mkoption
278                 ;
279
280 Mkoption:
281         Save_id EQUALS Opt_value
282               = {
283                 struct opt *op = (struct opt *)malloc(sizeof (struct opt));
284                 memset(op, 0, sizeof(*op));
285                 op->op_name = $1;
286                 op->op_ownfile = 0;     /* for now */
287                 op->op_next = mkopt;
288                 op->op_value = $3;
289                 op->op_line = yyline + 1;
290                 mkopt = op;
291               } ;
292
293 Dev:
294         ID
295               = { $$ = $1; }
296         ;
297
298 Device_spec:
299         DEVICE Dev_spec
300               = { cur.d_type = DEVICE; } |
301         DISK Dev_spec
302               = {
303                 errx(1, "line %d: Obsolete keyword 'disk' found - use 'device'", yyline);
304                 } |
305         TAPE Dev_spec
306               = {
307                 errx(1, "line %d: Obsolete keyword 'tape' found - use 'device'", yyline);
308                 } |
309         CONTROLLER Dev_spec
310               = {
311                 errx(1, "line %d: Obsolete keyword 'controller' found - use 'device'", yyline);
312                 } |
313         PSEUDO_DEVICE Init_dev Dev
314               = {
315                 cur.d_name = $3;
316                 cur.d_type = PSEUDO_DEVICE;
317                 } |
318         PSEUDO_DEVICE Init_dev Dev NUMBER
319               = {
320                 cur.d_name = $3;
321                 cur.d_type = PSEUDO_DEVICE;
322                 cur.d_count = $4;
323                 } ;
324
325 Dev_spec:
326         Init_dev Dev
327               = {
328                 cur.d_name = $2;
329                 cur.d_unit = UNKNOWN;
330                 } |
331         Init_dev Dev NUMBER Dev_info
332               = {
333                 cur.d_name = $2;
334                 cur.d_unit = $3;
335                 };
336
337 Init_dev:
338         /* lambda */
339               = { init_dev(&cur); };
340
341 Dev_info:
342         Con_info Info_list
343                 |
344         /* lambda */
345                 ;
346
347 Con_info:
348         AT Dev NUMBER
349               = {
350                 connect($2, $3);
351                 cur.d_conn = $2;
352                 cur.d_connunit = $3;
353                 } |
354         AT NEXUS NUMBER
355               = {
356                 cur.d_conn = "nexus";
357                 cur.d_connunit = 0;
358                 };
359     
360 Info_list:
361         Info_list Info
362                 |
363         /* lambda */
364                 ;
365
366 Info:
367         BUS NUMBER      /* device scbus1 at ahc0 bus 1 - twin channel */
368               = { cur.d_bus = $2; } |
369         TARGET NUMBER
370               = { cur.d_target = $2; } |
371         UNIT NUMBER
372               = { cur.d_lun = $2; } |
373         DRIVE NUMBER
374               = { cur.d_drive = $2; } |
375         IRQ NUMBER
376               = { cur.d_irq = $2; } |
377         DRQ NUMBER
378               = { cur.d_drq = $2; } |
379         IOMEM NUMBER
380               = { cur.d_maddr = $2; } |
381         IOSIZ NUMBER
382               = { cur.d_msize = $2; } |
383         PORT device_name
384               = { cur.d_port = $2; } |
385         PORT NUMBER
386               = { cur.d_portn = $2; } |
387         FLAGS NUMBER
388               = { cur.d_flags = $2; } |
389         DISABLE 
390               = { cur.d_disabled = 1; } |
391         CONFLICTS
392               = {
393                 errx(1, "line %d: Obsolete keyword 'conflicts' found", yyline);
394                 };
395
396 %%
397
398 static void
399 yyerror(char *s)
400 {
401
402         errx(1, "line %d: %s", yyline + 1, s);
403 }
404
405 /*
406  * add a device to the list of devices
407  */
408 static void
409 newdev(struct device *dp)
410 {
411         struct device *np, *xp;
412
413         if (dp->d_unit >= 0) {
414                 for (xp = dtab; xp != 0; xp = xp->d_next) {
415                         if ((xp->d_unit == dp->d_unit) &&
416                             eq(xp->d_name, dp->d_name)) {
417                                 errx(1, "line %d: already seen device %s%d",
418                                     yyline, xp->d_name, xp->d_unit);
419                         }
420                 }
421         }
422         np = (struct device *) malloc(sizeof *np);
423         memset(np, 0, sizeof(*np));
424         *np = *dp;
425         np->d_next = 0;
426         if (curp == 0)
427                 dtab = np;
428         else
429                 curp->d_next = np;
430         curp = np;
431 }
432
433
434 /*
435  * find the pointer to connect to the given device and number.
436  * returns 0 if no such device and prints an error message
437  */
438 static int
439 connect(char *dev, int num)
440 {
441         struct device *dp;
442
443         if (num == QUES) {
444                 for (dp = dtab; dp != 0; dp = dp->d_next)
445                         if (eq(dp->d_name, dev))
446                                 break;
447                 if (dp == 0) {
448                         (void) snprintf(errbuf, sizeof(errbuf),
449                             "no %s's to wildcard", dev);
450                         yyerror(errbuf);
451                         return (0);
452                 }
453                 return (1);
454         }
455         for (dp = dtab; dp != 0; dp = dp->d_next) {
456                 if ((num != dp->d_unit) || !eq(dev, dp->d_name))
457                         continue;
458                 if (dp->d_type != DEVICE) {
459                         (void) snprintf(errbuf, sizeof(errbuf), 
460                             "%s connected to non-device", dev);
461                         yyerror(errbuf);
462                         return (0);
463                 }
464                 return (1);
465         }
466         (void) snprintf(errbuf, sizeof(errbuf), "%s %d not defined", dev, num);
467         yyerror(errbuf);
468         return (0);
469 }
470
471 void
472 init_dev(struct device *dp)
473 {
474
475         dp->d_name = "OHNO!!!";
476         dp->d_type = DEVICE;
477         dp->d_conn = 0;
478         dp->d_disabled = 0;
479         dp->d_flags = 0;
480         dp->d_bus = dp->d_lun = dp->d_target = dp->d_drive = dp->d_unit = \
481                 dp->d_count = UNKNOWN;
482         dp->d_port = (char *)0;
483         dp->d_portn = -1;
484         dp->d_irq = -1;
485         dp->d_drq = -1;
486         dp->d_maddr = 0;
487         dp->d_msize = 0;
488 }