libexec/rtld-aout/i386/mdprologue.S

   1 /*
   2  * Copyright (c) 1993 Paul Kranenburg
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Paul Kranenburg.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/libexec/rtld-aout/i386/mdprologue.S,v 1.9 1999/08/28 00:10:08 peter Exp $
  31  * $DragonFly: src/libexec/rtld-aout/i386/Attic/mdprologue.S,v 1.2 2003/06/17 04:27:08 dillon Exp $
  32  */
  33
  34 /*
  35  * i386 run-time link editor entry points.
  36  */
  37
  38 #include <sys/syscall.h>
  39
  40         .text
  41         .globl  _binder, _binder_entry
  42
  43 /*
  44  *      _rtl(int version, struct crt_ldso *crtp)
  45  */
  46
  47 _rtl:                                   # crt0 calls us here
  48         pushl   %ebp                    # Allocate stack frame
  49         movl    %esp,%ebp
  50         pushl   %ebx
  51
  52         call    1f                      # PIC function prologue
  53 1:
  54         popl    %ebx
  55         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b],%ebx
  56
  57         movl    12(%ebp),%eax           # Extract data from interface structure
  58         movl    (%eax),%eax             # base address of ld.so (first field)
  59                                         # setup arguments for rtld()
  60         movl    (%ebx),%ecx             # 1st entry in GOT is our __DYNAMIC
  61         addl    %eax,%ecx               #   add load address
  62         pushl   %ecx                    # 3rd arg
  63         pushl   12(%ebp)                # 2nd arg == &crt.
  64         pushl   8(%ebp)                 # 1st arg == version
  65         addl    _rtld@GOT(%ebx),%eax    # relocate address of function
  66         call    %eax                    # _rtld(version, crtp, DYNAMIC)
  67         addl    $12,%esp                # pop arguments
  68
  69         popl    %ebx
  70         leave                           # remove stack frame
  71         ret
  72
  73  # First call to a procedure generally comes through here for
  74  # binding.
  75
  76 _binder_entry:
  77         pushl   %ebp                    # setup a stack frame
  78         movl    %esp,%ebp
  79         pusha                           # save all regs
  80
  81         xorl    %eax,%eax               # clear
  82         movl    4(%ebp),%esi            # return address in PLT
  83         movw    (%esi),%ax              # get hold of relocation number
  84         subl    $6,%esi                 # make it point to the jmpslot
  85
  86         pushl   %eax                    # pushd arguments
  87         pushl   %esi                    #
  88         call    _binder@PLT             # _binder(rpc, index)
  89         addl    $8,%esp                 # pop arguments
  90         movl    %eax,4(%ebp)            # return value from _binder() == actual
  91                                         #  address of function
  92         popa                            # restore regs
  93         leave                           # remove our stack frame
  94         ret