sys/i386/i386/locore.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  * $FreeBSD: src/sys/i386/i386/locore.s,v 1.132.2.10 2003/02/03 20:54:49 jhb Exp $
  38  * $DragonFly: src/sys/i386/i386/Attic/locore.s,v 1.9 2003/11/12 22:08:01 dillon Exp $
  39  *
  40  *              originally from: locore.s, by William F. Jolitz
  41  *
  42  *              Substantially rewritten by David Greenman, Rod Grimes,
  43  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  44  *                      and many others.
  45  */
  46
  47 #include "opt_bootp.h"
  48 #include "opt_nfsroot.h"
  49
  50 #include <sys/syscall.h>
  51 #include <sys/reboot.h>
  52
  53 #include <machine/asmacros.h>
  54 #include <machine/cputypes.h>
  55 #include <machine/psl.h>
  56 #include <machine/pmap.h>
  57 #include <machine/specialreg.h>
  58
  59 #include "assym.s"
  60
  61 /*
  62  *      XXX
  63  *
  64  * Note: This version greatly munged to avoid various assembler errors
  65  * that may be fixed in newer versions of gas. Perhaps newer versions
  66  * will have more pleasant appearance.
  67  */
  68
  69 /*
  70  * PTmap is recursive pagemap at top of virtual address space.
  71  * Within PTmap, the page directory can be found (third indirection).
  72  */
  73         .globl  PTmap,PTD,PTDpde
  74         .set    PTmap,(PTDPTDI << PDRSHIFT)
  75         .set    PTD,PTmap + (PTDPTDI * PAGE_SIZE)
  76         .set    PTDpde,PTD + (PTDPTDI * PDESIZE)
  77
  78 /*
  79  * APTmap, APTD is the alternate recursive pagemap.
  80  * It's used when modifying another process's page tables.
  81  */
  82         .globl  APTmap,APTD,APTDpde
  83         .set    APTmap,APTDPTDI << PDRSHIFT
  84         .set    APTD,APTmap + (APTDPTDI * PAGE_SIZE)
  85         .set    APTDpde,PTD + (APTDPTDI * PDESIZE)
  86
  87 /*
  88  * Compiled KERNBASE location
  89  */
  90         .globl  kernbase
  91         .set    kernbase,KERNBASE
  92
  93 /*
  94  * Globals
  95  */
  96         .data
  97         ALIGN_DATA              /* just to be sure */
  98
  99         .globl  .tmpstk
 100         .space  0x2000          /* space for tmpstk - temporary stack */
 101 .tmpstk:
 102
 103         .globl  boothowto,bootdev
 104
 105         .globl  cpu,cpu_vendor,cpu_id,bootinfo
 106         .globl  cpu_high, cpu_feature, cpu_procinfo
 107
 108 cpu:            .long   0                       /* are we 386, 386sx, or 486 */
 109 cpu_id:         .long   0                       /* stepping ID */
 110 cpu_high:       .long   0                       /* highest arg to CPUID */
 111 cpu_feature:    .long   0                       /* features */
 112 cpu_procinfo:   .long   0                       /* brand index / HTT info */
 113 cpu_vendor:     .space  20                      /* CPU origin code */
 114 bootinfo:       .space  BOOTINFO_SIZE           /* bootinfo buffer space */
 115
 116 KERNend:        .long   0                       /* phys addr end of kernel (just after bss) */
 117 physfree:       .long   0                       /* phys addr of next free page */
 118
 119                 .globl  cpu0prvpage
 120 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 121 cpu0prvpage:    .long   0                       /* relocated version */
 122 cpu0idlestk:    .long   0                       /* stack for the idle thread */
 123
 124                 .globl  SMPpt
 125 SMPptpa:        .long   0                       /* phys addr SMP page table */
 126 SMPpt:          .long   0                       /* relocated version */
 127
 128         .globl  IdlePTD
 129 IdlePTD:        .long   0                       /* phys addr of kernel PTD */
 130
 131         .globl  KPTphys
 132 KPTphys:        .long   0                       /* PA of kernel page tables */
 133
 134         .globl  proc0paddr
 135 proc0paddr:     .long   0                       /* VA of proc 0 address space */
 136 p0upa:          .long   0                       /* PA of proc0's UPAGES */
 137
 138 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 139
 140         .globl  vm86paddr, vm86pa
 141 vm86paddr:      .long   0                       /* address of vm86 region */
 142 vm86pa:         .long   0                       /* phys addr of vm86 region */
 143
 144 #ifdef BDE_DEBUGGER
 145         .globl  bdb_exists                      /* BDE debugger is present */
 146 bdb_exists:     .long   0
 147 #endif
 148
 149 #ifdef PC98
 150         .globl  pc98_system_parameter
 151 pc98_system_parameter:
 152         .space  0x240
 153 #endif
 154
 155 /**********************************************************************
 156  *
 157  * Some handy macros
 158  *
 159  */
 160
 161 #define R(foo) ((foo)-KERNBASE)
 162
 163 #define ALLOCPAGES(foo)                                 \
 164         movl    R(physfree), %esi ;                     \
 165         movl    $((foo)*PAGE_SIZE), %eax ;              \
 166         addl    %esi, %eax ;                            \
 167         movl    %eax, R(physfree) ;                     \
 168         movl    %esi, %edi ;                            \
 169         movl    $((foo)*PAGE_SIZE),%ecx ;               \
 170         xorl    %eax,%eax ;                             \
 171         cld ;                                           \
 172         rep ;                                           \
 173         stosb
 174
 175 /*
 176  * fillkpt
 177  *      eax = page frame address
 178  *      ebx = index into page table
 179  *      ecx = how many pages to map
 180  *      base = base address of page dir/table
 181  *      prot = protection bits
 182  */
 183 #define fillkpt(base, prot)               \
 184         shll    $2,%ebx                 ; \
 185         addl    base,%ebx               ; \
 186         orl     $PG_V,%eax              ; \
 187         orl     prot,%eax               ; \
 188 1:      movl    %eax,(%ebx)             ; \
 189         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 190         addl    $4,%ebx                 ; /* next pte */ \
 191         loop    1b
 192
 193 /*
 194  * fillkptphys(prot)
 195  *      eax = physical address
 196  *      ecx = how many pages to map
 197  *      prot = protection bits
 198  */
 199 #define fillkptphys(prot)                 \
 200         movl    %eax, %ebx              ; \
 201         shrl    $PAGE_SHIFT, %ebx       ; \
 202         fillkpt(R(KPTphys), prot)
 203
 204         .text
 205 /**********************************************************************
 206  *
 207  * This is where the bootblocks start us, set the ball rolling...
 208  *
 209  */
 210 NON_GPROF_ENTRY(btext)
 211
 212 #ifdef PC98
 213         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 214         movl    $0xa1400,%esi
 215         movl    $R(pc98_system_parameter),%edi
 216         movl    $0x0240,%ecx
 217         cld
 218         rep
 219         movsb
 220 #else   /* IBM-PC */
 221 #ifdef BDE_DEBUGGER
 222 #ifdef BIOS_STEALS_3K
 223         cmpl    $0x0375c339,0x95504
 224 #else
 225         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 226 #endif
 227         jne     1f
 228         movb    $1,R(bdb_exists)
 229 1:
 230 #endif
 231 /* Tell the bios to warmboot next time */
 232         movw    $0x1234,0x472
 233 #endif  /* PC98 */
 234
 235 /* Set up a real frame in case the double return in newboot is executed. */
 236         pushl   %ebp
 237         movl    %esp, %ebp
 238
 239 /* Don't trust what the BIOS gives for eflags. */
 240         pushl   $PSL_KERNEL
 241         popfl
 242
 243 /*
 244  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 245  * to set %cs, %ds, %es and %ss.
 246  */
 247         mov     %ds, %ax
 248         mov     %ax, %fs
 249         mov     %ax, %gs
 250
 251 /*
 252  * Clear the bss.  Not all boot programs do it, and it is our job anyway.
 253  *
 254  * XXX we don't check that there is memory for our bss and page tables
 255  * before using it.
 256  *
 257  * Note: we must be careful to not overwrite an active gdt or idt.  They
 258  * inactive from now until we switch to new ones, since we don't load any
 259  * more segment registers or permit interrupts until after the switch.
 260  */
 261         movl    $R(_end),%ecx
 262         movl    $R(_edata),%edi
 263         subl    %edi,%ecx
 264         xorl    %eax,%eax
 265         cld
 266         rep
 267         stosb
 268
 269         call    recover_bootinfo
 270
 271 /* Get onto a stack that we can trust. */
 272 /*
 273  * XXX this step is delayed in case recover_bootinfo needs to return via
 274  * the old stack, but it need not be, since recover_bootinfo actually
 275  * returns via the old frame.
 276  */
 277         movl    $R(.tmpstk),%esp
 278
 279 #ifdef PC98
 280         /* pc98_machine_type & M_EPSON_PC98 */
 281         testb   $0x02,R(_pc98_system_parameter)+220
 282         jz      3f
 283         /* epson_machine_id <= 0x0b */
 284         cmpb    $0x0b,R(_pc98_system_parameter)+224
 285         ja      3f
 286
 287         /* count up memory */
 288         movl    $0x100000,%eax          /* next, talley remaining memory */
 289         movl    $0xFFF-0x100,%ecx
 290 1:      movl    0(%eax),%ebx            /* save location to check */
 291         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 292         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 293         jne     2f
 294         movl    %ebx,0(%eax)            /* restore memory */
 295         addl    $PAGE_SIZE,%eax
 296         loop    1b
 297 2:      subl    $0x100000,%eax
 298         shrl    $17,%eax
 299         movb    %al,R(_pc98_system_parameter)+1
 300 3:
 301
 302         movw    R(_pc98_system_parameter+0x86),%ax
 303         movw    %ax,R(cpu_id)
 304 #endif
 305
 306         call    identify_cpu
 307
 308         call    create_pagetables
 309
 310 /*
 311  * If the CPU has support for VME, turn it on.
 312  */
 313         testl   $CPUID_VME, R(cpu_feature)
 314         jz      1f
 315         movl    %cr4, %eax
 316         orl     $CR4_VME, %eax
 317         movl    %eax, %cr4
 318 1:
 319
 320 #ifdef BDE_DEBUGGER
 321 /*
 322  * Adjust as much as possible for paging before enabling paging so that the
 323  * adjustments can be traced.
 324  */
 325         call    bdb_prepare_paging
 326 #endif
 327
 328 /* Now enable paging */
 329         movl    R(IdlePTD), %eax
 330         movl    %eax,%cr3                       /* load ptd addr into mmu */
 331         movl    %cr0,%eax                       /* get control word */
 332         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 333         movl    %eax,%cr0                       /* and let's page NOW! */
 334
 335
 336 #ifdef BDE_DEBUGGER
 337 /*
 338  * Complete the adjustments for paging so that we can keep tracing through
 339  * initi386() after the low (physical) addresses for the gdt and idt become
 340  * invalid.
 341  */
 342         call    bdb_commit_paging
 343 #endif
 344
 345         pushl   $begin                          /* jump to high virtualized address */
 346         ret
 347
 348 /* now running relocated at KERNBASE where the system is linked to run */
 349 begin:
 350
 351         /*
 352          * set up the bootstrap stack.  The pcb sits at the end of the
 353          * bootstrap stack.
 354          */
 355         /* set up bootstrap stack */
 356         movl    proc0paddr,%esp /* location of in-kernel pages */
 357         addl    $UPAGES*PAGE_SIZE-PCB_SIZE,%esp
 358         xorl    %eax,%eax               /* mark end of frames */
 359         movl    %eax,%ebp
 360         /*movl  proc0paddr,%eax*/
 361         movl    IdlePTD, %esi
 362         movl    %esi,PCB_CR3(%esp)
 363
 364         testl   $CPUID_PGE, R(cpu_feature)
 365         jz      1f
 366         movl    %cr4, %eax
 367         orl     $CR4_PGE, %eax
 368         movl    %eax, %cr4
 369 1:
 370
 371         movl    physfree, %esi
 372         pushl   %esi                    /* value of first for init386(first) */
 373
 374         call    init386                 /* wire 386 chip for unix operation */
 375         popl    %esi
 376
 377         call    mi_startup              /* autoconfiguration, mountroot etc */
 378
 379         hlt             /* never returns to here */
 380
 381 /*
 382  * Signal trampoline, copied to top of user stack
 383  */
 384 NON_GPROF_ENTRY(sigcode)
 385         call    *SIGF_HANDLER(%esp)             /* call signal handler */
 386         lea     SIGF_UC(%esp),%eax              /* get ucontext_t */
 387         pushl   %eax
 388         testl   $PSL_VM,UC_EFLAGS(%eax)
 389         jne     9f
 390         movl    UC_GS(%eax),%gs                 /* restore %gs */
 391 9:
 392         movl    $SYS_sigreturn,%eax
 393         pushl   %eax                            /* junk to fake return addr. */
 394         int     $0x80                           /* enter kernel with args */
 395 0:      jmp     0b
 396
 397         ALIGN_TEXT
 398 esigcode:
 399
 400         .data
 401         .globl  szsigcode
 402 szsigcode:
 403         .long   esigcode - sigcode
 404         .text
 405
 406 /**********************************************************************
 407  *
 408  * Recover the bootinfo passed to us from the boot program
 409  *
 410  */
 411 recover_bootinfo:
 412         /*
 413          * This code is called in different ways depending on what loaded
 414          * and started the kernel.  This is used to detect how we get the
 415          * arguments from the other code and what we do with them.
 416          *
 417          * Old disk boot blocks:
 418          *      (*btext)(howto, bootdev, cyloffset, esym);
 419          *      [return address == 0, and can NOT be returned to]
 420          *      [cyloffset was not supported by the FreeBSD boot code
 421          *       and always passed in as 0]
 422          *      [esym is also known as total in the boot code, and
 423          *       was never properly supported by the FreeBSD boot code]
 424          *
 425          * Old diskless netboot code:
 426          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 427          *      [return address != 0, and can NOT be returned to]
 428          *      If we are being booted by this code it will NOT work,
 429          *      so we are just going to halt if we find this case.
 430          *
 431          * New uniform boot code:
 432          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 433          *      [return address != 0, and can be returned to]
 434          *
 435          * There may seem to be a lot of wasted arguments in here, but
 436          * that is so the newer boot code can still load very old kernels
 437          * and old boot code can load new kernels.
 438          */
 439
 440         /*
 441          * The old style disk boot blocks fake a frame on the stack and
 442          * did an lret to get here.  The frame on the stack has a return
 443          * address of 0.
 444          */
 445         cmpl    $0,4(%ebp)
 446         je      olddiskboot
 447
 448         /*
 449          * We have some form of return address, so this is either the
 450          * old diskless netboot code, or the new uniform code.  That can
 451          * be detected by looking at the 5th argument, if it is 0
 452          * we are being booted by the new uniform boot code.
 453          */
 454         cmpl    $0,24(%ebp)
 455         je      newboot
 456
 457         /*
 458          * Seems we have been loaded by the old diskless boot code, we
 459          * don't stand a chance of running as the diskless structure
 460          * changed considerably between the two, so just halt.
 461          */
 462          hlt
 463
 464         /*
 465          * We have been loaded by the new uniform boot code.
 466          * Let's check the bootinfo version, and if we do not understand
 467          * it we return to the loader with a status of 1 to indicate this error
 468          */
 469 newboot:
 470         movl    28(%ebp),%ebx           /* &bootinfo.version */
 471         movl    BI_VERSION(%ebx),%eax
 472         cmpl    $1,%eax                 /* We only understand version 1 */
 473         je      1f
 474         movl    $1,%eax                 /* Return status */
 475         leave
 476         /*
 477          * XXX this returns to our caller's caller (as is required) since
 478          * we didn't set up a frame and our caller did.
 479          */
 480         ret
 481
 482 1:
 483         /*
 484          * If we have a kernelname copy it in
 485          */
 486         movl    BI_KERNELNAME(%ebx),%esi
 487         cmpl    $0,%esi
 488         je      2f                      /* No kernelname */
 489         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 490         movl    $R(kernelname),%edi
 491         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 492         je      1f
 493         movb    $'/',(%edi)
 494         incl    %edi
 495         decl    %ecx
 496 1:
 497         cld
 498         rep
 499         movsb
 500
 501 2:
 502         /*
 503          * Determine the size of the boot loader's copy of the bootinfo
 504          * struct.  This is impossible to do properly because old versions
 505          * of the struct don't contain a size field and there are 2 old
 506          * versions with the same version number.
 507          */
 508         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 509         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 510         je      got_bi_size             /* no, sizeless version */
 511         movl    BI_SIZE(%ebx),%ecx
 512 got_bi_size:
 513
 514         /*
 515          * Copy the common part of the bootinfo struct
 516          */
 517         movl    %ebx,%esi
 518         movl    $R(bootinfo),%edi
 519         cmpl    $BOOTINFO_SIZE,%ecx
 520         jbe     got_common_bi_size
 521         movl    $BOOTINFO_SIZE,%ecx
 522 got_common_bi_size:
 523         cld
 524         rep
 525         movsb
 526
 527 #ifdef NFS_ROOT
 528 #ifndef BOOTP_NFSV3
 529         /*
 530          * If we have a nfs_diskless structure copy it in
 531          */
 532         movl    BI_NFS_DISKLESS(%ebx),%esi
 533         cmpl    $0,%esi
 534         je      olddiskboot
 535         movl    $R(nfs_diskless),%edi
 536         movl    $NFSDISKLESS_SIZE,%ecx
 537         cld
 538         rep
 539         movsb
 540         movl    $R(nfs_diskless_valid),%edi
 541         movl    $1,(%edi)
 542 #endif
 543 #endif
 544
 545         /*
 546          * The old style disk boot.
 547          *      (*btext)(howto, bootdev, cyloffset, esym);
 548          * Note that the newer boot code just falls into here to pick
 549          * up howto and bootdev, cyloffset and esym are no longer used
 550          */
 551 olddiskboot:
 552         movl    8(%ebp),%eax
 553         movl    %eax,R(boothowto)
 554         movl    12(%ebp),%eax
 555         movl    %eax,R(bootdev)
 556
 557         ret
 558
 559
 560 /**********************************************************************
 561  *
 562  * Identify the CPU and initialize anything special about it
 563  *
 564  */
 565 identify_cpu:
 566
 567         /* Try to toggle alignment check flag; does not exist on 386. */
 568         pushfl
 569         popl    %eax
 570         movl    %eax,%ecx
 571         orl     $PSL_AC,%eax
 572         pushl   %eax
 573         popfl
 574         pushfl
 575         popl    %eax
 576         xorl    %ecx,%eax
 577         andl    $PSL_AC,%eax
 578         pushl   %ecx
 579         popfl
 580
 581         testl   %eax,%eax
 582         jnz     try486
 583
 584         /* NexGen CPU does not have aligment check flag. */
 585         pushfl
 586         movl    $0x5555, %eax
 587         xorl    %edx, %edx
 588         movl    $2, %ecx
 589         clc
 590         divl    %ecx
 591         jz      trynexgen
 592         popfl
 593         movl    $CPU_386,R(cpu)
 594         jmp     3f
 595
 596 trynexgen:
 597         popfl
 598         movl    $CPU_NX586,R(cpu)
 599         movl    $0x4778654e,R(cpu_vendor)       # store vendor string
 600         movl    $0x72446e65,R(cpu_vendor+4)
 601         movl    $0x6e657669,R(cpu_vendor+8)
 602         movl    $0,R(cpu_vendor+12)
 603         jmp     3f
 604
 605 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 606         pushfl
 607         popl    %eax
 608         movl    %eax,%ecx
 609         xorl    $PSL_ID,%eax
 610         pushl   %eax
 611         popfl
 612         pushfl
 613         popl    %eax
 614         xorl    %ecx,%eax
 615         andl    $PSL_ID,%eax
 616         pushl   %ecx
 617         popfl
 618
 619         testl   %eax,%eax
 620         jnz     trycpuid
 621         movl    $CPU_486,R(cpu)
 622
 623         /*
 624          * Check Cyrix CPU
 625          * Cyrix CPUs do not change the undefined flags following
 626          * execution of the divide instruction which divides 5 by 2.
 627          *
 628          * Note: CPUID is enabled on M2, so it passes another way.
 629          */
 630         pushfl
 631         movl    $0x5555, %eax
 632         xorl    %edx, %edx
 633         movl    $2, %ecx
 634         clc
 635         divl    %ecx
 636         jnc     trycyrix
 637         popfl
 638         jmp     3f              /* You may use Intel CPU. */
 639
 640 trycyrix:
 641         popfl
 642         /*
 643          * IBM Bluelighting CPU also doesn't change the undefined flags.
 644          * Because IBM doesn't disclose the information for Bluelighting
 645          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 646          * brand of Cyrix CPUs).
 647          */
 648         movl    $0x69727943,R(cpu_vendor)       # store vendor string
 649         movl    $0x736e4978,R(cpu_vendor+4)
 650         movl    $0x64616574,R(cpu_vendor+8)
 651         jmp     3f
 652
 653 trycpuid:       /* Use the `cpuid' instruction. */
 654         xorl    %eax,%eax
 655         cpuid                                   # cpuid 0
 656         movl    %eax,R(cpu_high)                # highest capability
 657         movl    %ebx,R(cpu_vendor)              # store vendor string
 658         movl    %edx,R(cpu_vendor+4)
 659         movl    %ecx,R(cpu_vendor+8)
 660         movb    $0,R(cpu_vendor+12)
 661
 662         movl    $1,%eax
 663         cpuid                                   # cpuid 1
 664         movl    %eax,R(cpu_id)                  # store cpu_id
 665         movl    %ebx,R(cpu_procinfo)            # store cpu_procinfo
 666         movl    %edx,R(cpu_feature)             # store cpu_feature
 667         rorl    $8,%eax                         # extract family type
 668         andl    $15,%eax
 669         cmpl    $5,%eax
 670         jae     1f
 671
 672         /* less than Pentium; must be 486 */
 673         movl    $CPU_486,R(cpu)
 674         jmp     3f
 675 1:
 676         /* a Pentium? */
 677         cmpl    $5,%eax
 678         jne     2f
 679         movl    $CPU_586,R(cpu)
 680         jmp     3f
 681 2:
 682         /* Greater than Pentium...call it a Pentium Pro */
 683         movl    $CPU_686,R(cpu)
 684 3:
 685         ret
 686
 687
 688 /**********************************************************************
 689  *
 690  * Create the first page directory and its page tables.
 691  *
 692  */
 693
 694 create_pagetables:
 695
 696 /* Find end of kernel image (rounded up to a page boundary). */
 697         movl    $R(end),%esi
 698
 699 /* Include symbols, if any. */
 700         movl    R(bootinfo+BI_ESYMTAB),%edi
 701         testl   %edi,%edi
 702         je      over_symalloc
 703         movl    %edi,%esi
 704         movl    $KERNBASE,%edi
 705         addl    %edi,R(bootinfo+BI_SYMTAB)
 706         addl    %edi,R(bootinfo+BI_ESYMTAB)
 707 over_symalloc:
 708
 709 /* If we are told where the end of the kernel space is, believe it. */
 710         movl    R(bootinfo+BI_KERNEND),%edi
 711         testl   %edi,%edi
 712         je      no_kernend
 713         movl    %edi,%esi
 714 no_kernend:
 715
 716         addl    $PAGE_MASK,%esi
 717         andl    $~PAGE_MASK,%esi
 718         movl    %esi,R(KERNend)         /* save end of kernel */
 719         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 720
 721
 722 /* Allocate Kernel Page Tables */
 723         ALLOCPAGES(NKPT)
 724         movl    %esi,R(KPTphys)
 725
 726 /* Allocate Page Table Directory */
 727         ALLOCPAGES(1)
 728         movl    %esi,R(IdlePTD)
 729
 730 /* Allocate UPAGES */
 731         ALLOCPAGES(UPAGES)
 732         movl    %esi,R(p0upa)
 733         addl    $KERNBASE, %esi
 734         movl    %esi, R(proc0paddr)
 735
 736         ALLOCPAGES(1)                   /* vm86/bios stack */
 737         movl    %esi,R(vm86phystk)
 738
 739         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 740         movl    %esi,R(vm86pa)
 741         addl    $KERNBASE, %esi
 742         movl    %esi, R(vm86paddr)
 743
 744 /* Allocate cpu0's private data page */
 745         ALLOCPAGES(1)
 746         movl    %esi,R(cpu0pp)
 747         addl    $KERNBASE, %esi
 748         movl    %esi, R(cpu0prvpage)    /* relocated to KVM space */
 749
 750 /* Allocate cpu0's idle stack */
 751         ALLOCPAGES(UPAGES)
 752         movl    %esi,R(cpu0idlestk)
 753
 754 /* Allocate SMP page table page */
 755         ALLOCPAGES(1)
 756         movl    %esi,R(SMPptpa)
 757         addl    $KERNBASE, %esi
 758         movl    %esi, R(SMPpt)          /* relocated to KVM space */
 759
 760 /* Map read-only from zero to the end of the kernel text section */
 761         xorl    %eax, %eax
 762 #ifdef BDE_DEBUGGER
 763 /* If the debugger is present, actually map everything read-write. */
 764         cmpl    $0,R(bdb_exists)
 765         jne     map_read_write
 766 #endif
 767         xorl    %edx,%edx
 768
 769 #if !defined(SMP)
 770         testl   $CPUID_PGE, R(cpu_feature)
 771         jz      2f
 772         orl     $PG_G,%edx
 773 #endif
 774
 775 2:      movl    $R(etext),%ecx
 776         addl    $PAGE_MASK,%ecx
 777         shrl    $PAGE_SHIFT,%ecx
 778         fillkptphys(%edx)
 779
 780 /* Map read-write, data, bss and symbols */
 781         movl    $R(etext),%eax
 782         addl    $PAGE_MASK, %eax
 783         andl    $~PAGE_MASK, %eax
 784 map_read_write:
 785         movl    $PG_RW,%edx
 786 #if !defined(SMP)
 787         testl   $CPUID_PGE, R(cpu_feature)
 788         jz      1f
 789         orl     $PG_G,%edx
 790 #endif
 791
 792 1:      movl    R(KERNend),%ecx
 793         subl    %eax,%ecx
 794         shrl    $PAGE_SHIFT,%ecx
 795         fillkptphys(%edx)
 796
 797 /* Map page directory. */
 798         movl    R(IdlePTD), %eax
 799         movl    $1, %ecx
 800         fillkptphys($PG_RW)
 801
 802 /* Map proc0's UPAGES in the physical way ... */
 803         movl    R(p0upa), %eax
 804         movl    $UPAGES, %ecx
 805         fillkptphys($PG_RW)
 806
 807 /* Map ISA hole */
 808         movl    $ISA_HOLE_START, %eax
 809         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 810         fillkptphys($PG_RW)
 811
 812 /* Map space for the vm86 region */
 813         movl    R(vm86phystk), %eax
 814         movl    $4, %ecx
 815         fillkptphys($PG_RW)
 816
 817 /* Map page 0 into the vm86 page table */
 818         movl    $0, %eax
 819         movl    $0, %ebx
 820         movl    $1, %ecx
 821         fillkpt(R(vm86pa), $PG_RW|PG_U)
 822
 823 /* ...likewise for the ISA hole */
 824         movl    $ISA_HOLE_START, %eax
 825         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 826         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 827         fillkpt(R(vm86pa), $PG_RW|PG_U)
 828
 829 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 830         movl    R(cpu0pp), %eax
 831         movl    $1, %ecx
 832         fillkptphys($PG_RW)
 833
 834 /* Map SMP page table page into global kmem FWIW */
 835         movl    R(SMPptpa), %eax
 836         movl    $1, %ecx
 837         fillkptphys($PG_RW)
 838
 839 /* Map the private page into the SMP page table */
 840         movl    R(cpu0pp), %eax
 841         movl    $0, %ebx                /* pte offset = 0 */
 842         movl    $1, %ecx                /* one private page coming right up */
 843         fillkpt(R(SMPptpa), $PG_RW)
 844
 845 /* Map the cpu0's idle thread stack */
 846         movl    R(cpu0idlestk), %eax
 847         movl    $PS_IDLESTACK_PAGE, %ebx
 848         movl    $UPAGES, %ecx
 849         fillkpt(R(SMPptpa), $PG_RW)
 850
 851 /* ... and put the page table table in the pde. */
 852         movl    R(SMPptpa), %eax
 853         movl    $MPPTDI, %ebx
 854         movl    $1, %ecx
 855         fillkpt(R(IdlePTD), $PG_RW)
 856
 857 /* Fakeup VA for the local apic to allow early traps. */
 858         ALLOCPAGES(1)
 859         movl    %esi, %eax
 860         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 861         movl    $1, %ecx                /* one private pt coming right up */
 862         fillkpt(R(SMPptpa), $PG_RW)
 863
 864 #ifdef SMP
 865 /* Initialize mp lock to allow early traps */
 866         movl    $0, R(mp_lock)
 867 #endif  /* SMP */
 868
 869 /* install a pde for temporary double map of bottom of VA */
 870         movl    R(KPTphys), %eax
 871         xorl    %ebx, %ebx
 872         movl    $NKPT, %ecx
 873         fillkpt(R(IdlePTD), $PG_RW)
 874
 875 /* install pde's for pt's */
 876         movl    R(KPTphys), %eax
 877         movl    $KPTDI, %ebx
 878         movl    $NKPT, %ecx
 879         fillkpt(R(IdlePTD), $PG_RW)
 880
 881 /* install a pde recursively mapping page directory as a page table */
 882         movl    R(IdlePTD), %eax
 883         movl    $PTDPTDI, %ebx
 884         movl    $1,%ecx
 885         fillkpt(R(IdlePTD), $PG_RW)
 886
 887         ret
 888
 889 #ifdef BDE_DEBUGGER
 890 bdb_prepare_paging:
 891         cmpl    $0,R(bdb_exists)
 892         je      bdb_prepare_paging_exit
 893
 894         subl    $6,%esp
 895
 896         /*
 897          * Copy and convert debugger entries from the bootstrap gdt and idt
 898          * to the kernel gdt and idt.  Everything is still in low memory.
 899          * Tracing continues to work after paging is enabled because the
 900          * low memory addresses remain valid until everything is relocated.
 901          * However, tracing through the setidt() that initializes the trace
 902          * trap will crash.
 903          */
 904         sgdt    (%esp)
 905         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 906         movl    $R(gdt),%edi
 907         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 908         movl    $8*18/4,%ecx
 909         cld
 910         rep                             /* copy gdt */
 911         movsl
 912         movl    $R(gdt),-8+2(%edi)      /* adjust gdt self-ptr */
 913         movb    $0x92,-8+5(%edi)
 914         lgdt    (%esp)
 915
 916         sidt    (%esp)
 917         movl    2(%esp),%esi            /* base address of current idt */
 918         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 919         movw    8(%esi),%ax
 920         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 921         movl    8+2(%esi),%eax
 922         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 923         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 924         movw    24(%esi),%ax
 925         movl    %eax,R(bdb_bpt_ljmp+1)
 926         movl    24+2(%esi),%eax
 927         movw    %ax,R(bdb_bpt_ljmp+5)
 928         movl    R(idt),%edi
 929         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 930         movl    $8*4/4,%ecx
 931         cld
 932         rep                             /* copy idt */
 933         movsl
 934         lidt    (%esp)
 935
 936         addl    $6,%esp
 937
 938 bdb_prepare_paging_exit:
 939         ret
 940
 941 /* Relocate debugger gdt entries and gdt and idt pointers. */
 942 bdb_commit_paging:
 943         cmpl    $0,_bdb_exists
 944         je      bdb_commit_paging_exit
 945
 946         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 947         movl    $9,%ecx
 948 reloc_gdt:
 949         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
 950         addl    $8,%eax                 /* now KERNBASE>>24 */
 951         loop    reloc_gdt
 952
 953         subl    $6,%esp
 954         sgdt    (%esp)
 955         addl    $KERNBASE,2(%esp)
 956         lgdt    (%esp)
 957         sidt    (%esp)
 958         addl    $KERNBASE,2(%esp)
 959         lidt    (%esp)
 960         addl    $6,%esp
 961
 962         int     $3
 963
 964 bdb_commit_paging_exit:
 965         ret
 966
 967 #endif /* BDE_DEBUGGER */