libexec/rtld-elf/amd64/rtld_start.S

   1 /*-
   2  * Copyright 1996-1998 John D. Polstra.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  15  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  16  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  17  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  18  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  19  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  20  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  21  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  22  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  23  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  24  *
  25  * $FreeBSD: src/libexec/rtld-elf/amd64/rtld_start.S,v 1.5 2004/03/21 01:43:39 peter Exp $
  26  * $DragonFly: src/libexec/rtld-elf/amd64/rtld_start.S,v 1.1 2006/07/27 00:40:35 corecode Exp $
  27  */
  28
  29         .text
  30         .align  4
  31         .globl  resident_start
  32         .globl  .rtld_start
  33         .type   .rtld_start,@function
  34 resident_start:
  35 .rtld_start:
  36         xorq    %rbp,%rbp               # Clear frame pointer for good form
  37         subq    $24,%rsp                # A place to store exit procedure addr
  38         movq    %rdi,%r12
  39         movq    %rsp,%rsi               # save address of exit proc
  40         movq    %rsp,%rdx               # construct address of obj_main
  41         addq    $8,%rdx
  42         call    _rtld@PLT               # Call rtld(sp); returns entry point
  43         popq    %rsi                    # Get exit procedure address
  44         movq    %r12,%rdi               # *ap
  45 /*
  46  * At this point, %rax contains the entry point of the main program, and
  47  * %rdx contains a pointer to a termination function that should be
  48  * registered with atexit().  (crt1.o registers it.)
  49  */
  50 .globl .rtld_goto_main
  51 .rtld_goto_main:        # This symbol exists just to make debugging easier.
  52         jmp     *%rax                   # Enter main program
  53
  54
  55 /*
  56  * Binder entry point.  Control is transferred to here by code in the PLT.
  57  * On entry, there are two arguments on the stack.  In ascending address
  58  * order, they are (1) "obj", a pointer to the calling object's Obj_Entry,
  59  * and (2) "reloff", the byte offset of the appropriate relocation entry
  60  * in the PLT relocation table.
  61  *
  62  * We are careful to preserve all registers, even the the caller-save
  63  * registers.  That is because this code may be invoked by low-level
  64  * assembly-language code that is not ABI-compliant.
  65  *
  66  * Stack map:
  67  * reloff       0x60
  68  * obj          0x58
  69  * spare        0x50
  70  * rflags       0x48
  71  * rax          0x40
  72  * rdx          0x38
  73  * rcx          0x30
  74  * rsi          0x28
  75  * rdi          0x20
  76  * r8           0x18
  77  * r9           0x10
  78  * r10          0x8
  79  * r11          0x0
  80  */
  81         .align  4
  82         .globl  _rtld_bind_start
  83         .type   _rtld_bind_start,@function
  84 _rtld_bind_start:
  85         subq    $8,%rsp
  86         pushfq                          # Save rflags
  87         pushq   %rax                    # Save %rax
  88         pushq   %rdx                    # Save %rdx
  89         pushq   %rcx                    # Save %rcx
  90         pushq   %rsi                    # Save %rsi
  91         pushq   %rdi                    # Save %rdi
  92         pushq   %r8                     # Save %r8
  93         pushq   %r9                     # Save %r9
  94         pushq   %r10                    # Save %r10
  95         pushq   %r11                    # Save %r11
  96
  97         movq    0x58(%rsp),%rdi         # Fetch obj argument
  98         movq    0x60(%rsp),%rsi         # Fetch reloff argument
  99         leaq    (%rsi,%rsi,2),%rsi      # multiply by 3
 100         leaq    (,%rsi,8),%rsi          # now 8, for 24 (sizeof Elf_Rela)
 101
 102         call    _rtld_bind@PLT          # Transfer control to the binder
 103         /* Now %rax contains the entry point of the function being called. */
 104
 105         movq    %rax,0x60(%rsp)         # Store target over reloff argument
 106         popq    %r11                    # Restore %r11
 107         popq    %r10                    # Restore %r10
 108         popq    %r9                     # Restore %r9
 109         popq    %r8                     # Restore %r8
 110         popq    %rdi                    # Restore %rdi
 111         popq    %rsi                    # Restore %rsi
 112         popq    %rcx                    # Restore %rcx
 113         popq    %rdx                    # Restore %rdx
 114         popq    %rax                    # Restore %rax
 115         popfq                           # Restore rflags
 116         leaq    16(%rsp),%rsp           # Discard spare, obj, do not change rflags
 117         ret                             # "Return" to target address