contrib/libpcap-0.8.3/scanner.l

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  */
  22
  23 #ifndef lint
  24 static const char rcsid[] _U_ =
  25     "@(#) $Header: /tcpdump/master/libpcap/scanner.l,v 1.95.2.3 2004/03/28 21:45:33 fenner Exp $ (LBL)";
  26 #endif
  27
  28 #ifdef HAVE_CONFIG_H
  29 #include "config.h"
  30 #endif
  31
  32 #include <ctype.h>
  33 #include <string.h>
  34
  35 #include "pcap-int.h"
  36
  37 #include "gencode.h"
  38 #ifdef INET6
  39 #ifdef WIN32
  40 #include <pcap-stdinc.h>
  41
  42 #ifdef __MINGW32__
  43 #include "IP6_misc.h"
  44 #endif
  45 #else /* WIN32 */
  46 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
  47 #include <netdb.h>      /* for "struct addrinfo" */
  48 #endif /* WIN32 */
  49
  50 /* Workaround for AIX 4.3 */
  51 #if !defined(AI_NUMERICHOST)
  52 #define AI_NUMERICHOST 0x04
  53 #endif
  54 #endif /*INET6*/
  55 #include <pcap-namedb.h>
  56 #include "tokdefs.h"
  57
  58 #ifdef HAVE_OS_PROTO_H
  59 #include "os-proto.h"
  60 #endif
  61
  62 static int stoi(char *);
  63 static inline int xdtoi(int);
  64
  65 #ifdef FLEX_SCANNER
  66 #define YY_NO_UNPUT
  67 static YY_BUFFER_STATE in_buffer;
  68 #else
  69 static char *in_buffer;
  70
  71 #undef getc
  72 #define getc(fp)  (*in_buffer == 0 ? EOF : *in_buffer++)
  73 #endif
  74
  75 #define yylval pcap_lval
  76 extern YYSTYPE yylval;
  77
  78 %}
  79
  80 N               ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
  81 B               ([0-9A-Fa-f][0-9A-Fa-f]?)
  82 W               ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
  83
  84 %a 16000
  85 %o 19000
  86 %e 6000
  87 %k 4000
  88 %p 25000
  89 %n 2000
  90
  91 V680            {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
  92
  93 V670            ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
  94 V671            {W}::{W}:{W}:{W}:{W}:{W}:{W}
  95 V672            {W}:{W}::{W}:{W}:{W}:{W}:{W}
  96 V673            {W}:{W}:{W}::{W}:{W}:{W}:{W}
  97 V674            {W}:{W}:{W}:{W}::{W}:{W}:{W}
  98 V675            {W}:{W}:{W}:{W}:{W}::{W}:{W}
  99 V676            {W}:{W}:{W}:{W}:{W}:{W}::{W}
 100 V677            {W}:{W}:{W}:{W}:{W}:{W}:{W}::
 101
 102 V660            ::{W}:{W}:{W}:{W}:{W}:{W}
 103 V661            {W}::{W}:{W}:{W}:{W}:{W}
 104 V662            {W}:{W}::{W}:{W}:{W}:{W}
 105 V663            {W}:{W}:{W}::{W}:{W}:{W}
 106 V664            {W}:{W}:{W}:{W}::{W}:{W}
 107 V665            {W}:{W}:{W}:{W}:{W}::{W}
 108 V666            {W}:{W}:{W}:{W}:{W}:{W}::
 109
 110 V650            ::{W}:{W}:{W}:{W}:{W}
 111 V651            {W}::{W}:{W}:{W}:{W}
 112 V652            {W}:{W}::{W}:{W}:{W}
 113 V653            {W}:{W}:{W}::{W}:{W}
 114 V654            {W}:{W}:{W}:{W}::{W}
 115 V655            {W}:{W}:{W}:{W}:{W}::
 116
 117 V640            ::{W}:{W}:{W}:{W}
 118 V641            {W}::{W}:{W}:{W}
 119 V642            {W}:{W}::{W}:{W}
 120 V643            {W}:{W}:{W}::{W}
 121 V644            {W}:{W}:{W}:{W}::
 122
 123 V630            ::{W}:{W}:{W}
 124 V631            {W}::{W}:{W}
 125 V632            {W}:{W}::{W}
 126 V633            {W}:{W}:{W}::
 127
 128 V620            ::{W}:{W}
 129 V621            {W}::{W}
 130 V622            {W}:{W}::
 131
 132 V610            ::{W}
 133 V611            {W}::
 134
 135 V600            ::
 136
 137 V6604           {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 138
 139 V6504           ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 140 V6514           {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 141 V6524           {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 142 V6534           {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 143 V6544           {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 144 V6554           {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 145
 146 V6404           ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 147 V6414           {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 148 V6424           {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 149 V6434           {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 150 V6444           {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 151
 152 V6304           ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 153 V6314           {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 154 V6324           {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 155 V6334           {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 156
 157 V6204           ::{W}:{W}:{N}\.{N}\.{N}\.{N}
 158 V6214           {W}::{W}:{N}\.{N}\.{N}\.{N}
 159 V6224           {W}:{W}::{N}\.{N}\.{N}\.{N}
 160
 161 V6104           ::{W}:{N}\.{N}\.{N}\.{N}
 162 V6114           {W}::{N}\.{N}\.{N}\.{N}
 163
 164 V6004           ::{N}\.{N}\.{N}\.{N}
 165
 166
 167 V6              ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
 168
 169 %%
 170 dst             return DST;
 171 src             return SRC;
 172
 173 link|ether|ppp|slip  return LINK;
 174 fddi|tr|wlan    return LINK;
 175 arp             return ARP;
 176 rarp            return RARP;
 177 ip              return IP;
 178 sctp            return SCTP;
 179 tcp             return TCP;
 180 udp             return UDP;
 181 icmp            return ICMP;
 182 igmp            return IGMP;
 183 igrp            return IGRP;
 184 pim             return PIM;
 185 vrrp            return VRRP;
 186
 187 ip6             {
 188 #ifdef INET6
 189                 return IPV6;
 190 #else
 191                 bpf_error("%s not supported", yytext);
 192 #endif
 193                 }
 194 icmp6           {
 195 #ifdef INET6
 196                 return ICMPV6;
 197 #else
 198                 bpf_error("%s not supported", yytext);
 199 #endif
 200                 }
 201 ah              return AH;
 202 esp             return ESP;
 203
 204 atalk           return ATALK;
 205 aarp            return AARP;
 206 decnet          return DECNET;
 207 lat             return LAT;
 208 sca             return SCA;
 209 moprc           return MOPRC;
 210 mopdl           return MOPDL;
 211
 212 iso             return ISO;
 213 esis            return ESIS;
 214 es-is           return ESIS;
 215 isis            return ISIS;
 216 is-is           return ISIS;
 217 l1              return L1;
 218 l2              return L2;
 219 iih             return IIH;
 220 lsp             return LSP;
 221 snp             return SNP;
 222 csnp            return CSNP;
 223 psnp            return PSNP;
 224
 225 clnp            return CLNP;
 226
 227 stp             return STP;
 228
 229 ipx             return IPX;
 230
 231 netbeui         return NETBEUI;
 232
 233 host            return HOST;
 234 net             return NET;
 235 mask            return NETMASK;
 236 port            return PORT;
 237 proto           return PROTO;
 238 protochain      {
 239 #ifdef NO_PROTOCHAIN
 240                   bpf_error("%s not supported", yytext);
 241 #else
 242                   return PROTOCHAIN;
 243 #endif
 244                 }
 245
 246 gateway         return GATEWAY;
 247
 248 less            return LESS;
 249 greater         return GREATER;
 250 byte            return CBYTE;
 251 broadcast       return TK_BROADCAST;
 252 multicast       return TK_MULTICAST;
 253
 254 and|"&&"        return AND;
 255 or|"||"         return OR;
 256 not             return '!';
 257
 258 len|length      return LEN;
 259 inbound         return INBOUND;
 260 outbound        return OUTBOUND;
 261
 262 vlan            return VLAN;
 263
 264 lane            return LANE;
 265 llc             return LLC;
 266 metac           return METAC;
 267 bcc             return BCC;
 268 oam             return OAM;
 269 oamf4           return OAMF4;
 270 oamf4ec         return OAMF4EC;
 271 oamf4sc         return OAMF4SC;
 272 sc              return SC;
 273 ilmic           return ILMIC;
 274 vpi             return VPI;
 275 vci             return VCI;
 276 connectmsg      return CONNECTMSG;
 277 metaconnect     return METACONNECT;
 278
 279 on|ifname       return PF_IFNAME;
 280 rset|ruleset    return PF_RSET;
 281 rnr|rulenum     return PF_RNR;
 282 srnr|subrulenum return PF_SRNR;
 283 reason          return PF_REASON;
 284 action          return PF_ACTION;
 285
 286 [ \r\n\t]               ;
 287 [+\-*/:\[\]!<>()&|=]    return yytext[0];
 288 ">="                    return GEQ;
 289 "<="                    return LEQ;
 290 "!="                    return NEQ;
 291 "=="                    return '=';
 292 "<<"                    return LSH;
 293 ">>"                    return RSH;
 294 ${B}                    { yylval.e = pcap_ether_aton(((char *)yytext)+1);
 295                           return AID; }
 296 {N}                     { yylval.i = stoi((char *)yytext); return NUM; }
 297 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
 298                         yylval.s = sdup((char *)yytext); return HID; }
 299 {B}:{B}:{B}:{B}:{B}:{B} { yylval.e = pcap_ether_aton((char *)yytext);
 300                           return EID; }
 301 {V6}                    {
 302 #ifdef INET6
 303                           struct addrinfo hints, *res;
 304                           memset(&hints, 0, sizeof(hints));
 305                           hints.ai_family = AF_INET6;
 306                           hints.ai_flags = AI_NUMERICHOST;
 307                           if (getaddrinfo(yytext, NULL, &hints, &res))
 308                                 bpf_error("bogus IPv6 address %s", yytext);
 309                           else {
 310                                 yylval.s = sdup((char *)yytext); return HID6;
 311                           }
 312 #else
 313                           bpf_error("IPv6 address %s not supported", yytext);
 314 #endif /*INET6*/
 315                         }
 316 {B}:+({B}:+)+           { bpf_error("bogus ethernet address %s", yytext); }
 317 icmptype                { yylval.i = 0; return NUM; }
 318 icmpcode                { yylval.i = 1; return NUM; }
 319 icmp-echoreply          { yylval.i = 0; return NUM; }
 320 icmp-unreach            { yylval.i = 3; return NUM; }
 321 icmp-sourcequench       { yylval.i = 4; return NUM; }
 322 icmp-redirect           { yylval.i = 5; return NUM; }
 323 icmp-echo               { yylval.i = 8; return NUM; }
 324 icmp-routeradvert       { yylval.i = 9; return NUM; }
 325 icmp-routersolicit      { yylval.i = 10; return NUM; }
 326 icmp-timxceed           { yylval.i = 11; return NUM; }
 327 icmp-paramprob          { yylval.i = 12; return NUM; }
 328 icmp-tstamp             { yylval.i = 13; return NUM; }
 329 icmp-tstampreply        { yylval.i = 14; return NUM; }
 330 icmp-ireq               { yylval.i = 15; return NUM; }
 331 icmp-ireqreply          { yylval.i = 16; return NUM; }
 332 icmp-maskreq            { yylval.i = 17; return NUM; }
 333 icmp-maskreply          { yylval.i = 18; return NUM; }
 334 tcpflags                { yylval.i = 13; return NUM; }
 335 tcp-fin                 { yylval.i = 0x01; return NUM; }
 336 tcp-syn                 { yylval.i = 0x02; return NUM; }
 337 tcp-rst                 { yylval.i = 0x04; return NUM; }
 338 tcp-push                { yylval.i = 0x08; return NUM; }
 339 tcp-ack                 { yylval.i = 0x10; return NUM; }
 340 tcp-urg                 { yylval.i = 0x20; return NUM; }
 341 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
 342                          yylval.s = sdup((char *)yytext); return ID; }
 343 "\\"[^ !()\n\t]+        { yylval.s = sdup((char *)yytext + 1); return ID; }
 344 [^ \[\]\t\n\-_.A-Za-z0-9!<>()&|=]+ {
 345                         bpf_error("illegal token: %s", yytext); }
 346 .                       { bpf_error("illegal char '%c'", *yytext); }
 347 %%
 348 void
 349 lex_init(buf)
 350         char *buf;
 351 {
 352 #ifdef FLEX_SCANNER
 353         in_buffer = yy_scan_string(buf);
 354 #else
 355         in_buffer = buf;
 356 #endif
 357 }
 358
 359 /*
 360  * Do any cleanup necessary after parsing.
 361  */
 362 void
 363 lex_cleanup()
 364 {
 365 #ifdef FLEX_SCANNER
 366         if (in_buffer != NULL)
 367                 yy_delete_buffer(in_buffer);
 368         in_buffer = NULL;
 369 #endif
 370 }
 371
 372 /*
 373  * Also define a yywrap.  Note that if we're using flex, it will
 374  * define a macro to map this identifier to pcap_wrap.
 375  */
 376 int
 377 yywrap()
 378 {
 379         return 1;
 380 }
 381
 382 /* Hex digit to integer. */
 383 static inline int
 384 xdtoi(c)
 385         register int c;
 386 {
 387         if (isdigit(c))
 388                 return c - '0';
 389         else if (islower(c))
 390                 return c - 'a' + 10;
 391         else
 392                 return c - 'A' + 10;
 393 }
 394
 395 /*
 396  * Convert string to integer.  Just like atoi(), but checks for
 397  * preceding 0x or 0 and uses hex or octal instead of decimal.
 398  */
 399 static int
 400 stoi(s)
 401         char *s;
 402 {
 403         int base = 10;
 404         int n = 0;
 405
 406         if (*s == '0') {
 407                 if (s[1] == 'x' || s[1] == 'X') {
 408                         s += 2;
 409                         base = 16;
 410                 }
 411                 else {
 412                         base = 8;
 413                         s += 1;
 414                 }
 415         }
 416         while (*s)
 417                 n = n * base + xdtoi(*s++);
 418
 419         return n;
 420 }