contrib/sendmail-8.13.8/devtools/M4/UNIX/all.m4

   1 divert(-1)
   2 #
   3 # Copyright (c) 1999-2000 Sendmail, Inc. and its suppliers.
   4 #       All rights reserved.
   5 #
   6 # By using this file, you agree to the terms and conditions set
   7 # forth in the LICENSE file which can be found at the top level of
   8 # the sendmail distribution.
   9 #
  10 #
  11 #  Definitions for Makefile construction for sendmail
  12 #
  13 #       $Id: all.m4,v 8.13 2000/12/27 18:34:26 ca Exp $
  14 #
  15 divert(0)dnl
  16 ALL=${BEFORE} ${LINKS} bldTARGETS
  17
  18 all: ${ALL}
  19
  20 clean: bldCLEAN_TARGETS
  21
  22 define(`bldADD_SRC', ${$1SRCS} )dnl
  23 SRCS=bldFOREACH(`bldADD_SRC(', bldC_PRODUCTS)
  24 define(`bldADD_OBJS', ${$1OBJS} )dnl
  25 OBJS=bldFOREACH(`bldADD_OBJS(', bldC_PRODUCTS)
  26
  27 ifdef(`bldNO_INSTALL', `divert(-1)')
  28 install: bldINSTALL_TARGETS
  29
  30 install-strip: bldINSTALL_TARGETS ifdef(`bldSTRIP_TARGETS', `bldSTRIP_TARGETS')
  31 ifdef(`bldNO_INSTALL', `divert(0)')
  32
  33 ifdef(`confREQUIRE_LIBSM',`
  34 ifdef(`confSM_OS_HEADER',
  35 `sm_os.h: ${SRCDIR}/inc`'lude/sm/os/confSM_OS_HEADER.h
  36         ${RM} ${RMOPTS} sm_os.h
  37         ${LN} ${LNOPTS} ${SRCDIR}/inc`'lude/sm/os/confSM_OS_HEADER.h sm_os.h',
  38 `sm_os.h:
  39         ${CP} /dev/null sm_os.h')')
  40
  41 divert(bldDEPENDENCY_SECTION)
  42 ################  Dependency scripts
  43 include(confBUILDTOOLSDIR/M4/depend/ifdef(`confDEPEND_TYPE', `confDEPEND_TYPE',
  44 `generic').m4)dnl
  45 ################  End of dependency scripts
  46 divert(0)