crypto/kerberosIV/cf/krb-func-getcwd-broken.m4

   1 dnl $Id: krb-func-getcwd-broken.m4,v 1.2 1999/03/01 13:03:32 joda Exp $
   2 dnl
   3 dnl
   4 dnl test for broken getcwd in (SunOS braindamage)
   5 dnl
   6
   7 AC_DEFUN(AC_KRB_FUNC_GETCWD_BROKEN, [
   8 if test "$ac_cv_func_getcwd" = yes; then
   9 AC_MSG_CHECKING(if getcwd is broken)
  10 AC_CACHE_VAL(ac_cv_func_getcwd_broken, [
  11 ac_cv_func_getcwd_broken=no
  12
  13 AC_TRY_RUN([
  14 #include <errno.h>
  15 char *getcwd(char*, int);
  16
  17 void *popen(char *cmd, char *mode)
  18 {
  19         errno = ENOTTY;
  20         return 0;
  21 }
  22
  23 int main()
  24 {
  25         char *ret;
  26         ret = getcwd(0, 1024);
  27         if(ret == 0 && errno == ENOTTY)
  28                 return 0;
  29         return 1;
  30 }
  31 ], ac_cv_func_getcwd_broken=yes,:,:)
  32 ])
  33 if test "$ac_cv_func_getcwd_broken" = yes; then
  34         AC_DEFINE(BROKEN_GETCWD, 1, [Define if getcwd is broken (like in SunOS 4).])dnl
  35         LIBOBJS="$LIBOBJS getcwd.o"
  36         AC_SUBST(LIBOBJS)dnl
  37         AC_MSG_RESULT($ac_cv_func_getcwd_broken)
  38 else
  39         AC_MSG_RESULT([seems ok])
  40 fi
  41 fi
  42 ])