contrib/libpcap/scanner.l

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  */
  22
  23 #ifndef lint
  24 static const char rcsid[] _U_ =
  25     "@(#) $Header: /tcpdump/master/libpcap/scanner.l,v 1.110.2.2 2008/02/06 10:21:47 guy Exp $ (LBL)";
  26 #endif
  27
  28 #ifdef HAVE_CONFIG_H
  29 #include "config.h"
  30 #endif
  31
  32 #include <ctype.h>
  33 #include <string.h>
  34
  35 #include "pcap-int.h"
  36
  37 #include "gencode.h"
  38 #ifdef INET6
  39 #ifdef WIN32
  40 #include <pcap-stdinc.h>
  41
  42 #ifdef __MINGW32__
  43 #include "IP6_misc.h"
  44 #endif
  45 #else /* WIN32 */
  46 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
  47 #include <netdb.h>      /* for "struct addrinfo" */
  48 #endif /* WIN32 */
  49
  50 /* Workaround for AIX 4.3 */
  51 #if !defined(AI_NUMERICHOST)
  52 #define AI_NUMERICHOST 0x04
  53 #endif
  54 #endif /*INET6*/
  55 #include <pcap/namedb.h>
  56 #include "tokdefs.h"
  57
  58 #ifdef HAVE_OS_PROTO_H
  59 #include "os-proto.h"
  60 #endif
  61
  62 static int stoi(char *);
  63 static inline int xdtoi(int);
  64
  65 #ifdef FLEX_SCANNER
  66 #define YY_NO_UNPUT
  67 #define YY_NO_INPUT
  68 static YY_BUFFER_STATE in_buffer;
  69 #else
  70 static char *in_buffer;
  71
  72 #undef getc
  73 #define getc(fp)  (*in_buffer == 0 ? EOF : *in_buffer++)
  74 #endif
  75
  76 #define yylval pcap_lval
  77 extern YYSTYPE yylval;
  78
  79 %}
  80
  81 N               ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
  82 B               ([0-9A-Fa-f][0-9A-Fa-f]?)
  83 B2              ([0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f])
  84 W               ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
  85
  86 %a 18400
  87 %o 21500
  88 %e 7600
  89 %k 4550
  90 %p 27600
  91 %n 2000
  92
  93 V680            {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
  94
  95 V670            ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
  96 V671            {W}::{W}:{W}:{W}:{W}:{W}:{W}
  97 V672            {W}:{W}::{W}:{W}:{W}:{W}:{W}
  98 V673            {W}:{W}:{W}::{W}:{W}:{W}:{W}
  99 V674            {W}:{W}:{W}:{W}::{W}:{W}:{W}
 100 V675            {W}:{W}:{W}:{W}:{W}::{W}:{W}
 101 V676            {W}:{W}:{W}:{W}:{W}:{W}::{W}
 102 V677            {W}:{W}:{W}:{W}:{W}:{W}:{W}::
 103
 104 V660            ::{W}:{W}:{W}:{W}:{W}:{W}
 105 V661            {W}::{W}:{W}:{W}:{W}:{W}
 106 V662            {W}:{W}::{W}:{W}:{W}:{W}
 107 V663            {W}:{W}:{W}::{W}:{W}:{W}
 108 V664            {W}:{W}:{W}:{W}::{W}:{W}
 109 V665            {W}:{W}:{W}:{W}:{W}::{W}
 110 V666            {W}:{W}:{W}:{W}:{W}:{W}::
 111
 112 V650            ::{W}:{W}:{W}:{W}:{W}
 113 V651            {W}::{W}:{W}:{W}:{W}
 114 V652            {W}:{W}::{W}:{W}:{W}
 115 V653            {W}:{W}:{W}::{W}:{W}
 116 V654            {W}:{W}:{W}:{W}::{W}
 117 V655            {W}:{W}:{W}:{W}:{W}::
 118
 119 V640            ::{W}:{W}:{W}:{W}
 120 V641            {W}::{W}:{W}:{W}
 121 V642            {W}:{W}::{W}:{W}
 122 V643            {W}:{W}:{W}::{W}
 123 V644            {W}:{W}:{W}:{W}::
 124
 125 V630            ::{W}:{W}:{W}
 126 V631            {W}::{W}:{W}
 127 V632            {W}:{W}::{W}
 128 V633            {W}:{W}:{W}::
 129
 130 V620            ::{W}:{W}
 131 V621            {W}::{W}
 132 V622            {W}:{W}::
 133
 134 V610            ::{W}
 135 V611            {W}::
 136
 137 V600            ::
 138
 139 V6604           {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 140
 141 V6504           ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 142 V6514           {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 143 V6524           {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 144 V6534           {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 145 V6544           {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 146 V6554           {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 147
 148 V6404           ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 149 V6414           {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 150 V6424           {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 151 V6434           {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 152 V6444           {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 153
 154 V6304           ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 155 V6314           {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 156 V6324           {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 157 V6334           {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 158
 159 V6204           ::{W}:{W}:{N}\.{N}\.{N}\.{N}
 160 V6214           {W}::{W}:{N}\.{N}\.{N}\.{N}
 161 V6224           {W}:{W}::{N}\.{N}\.{N}\.{N}
 162
 163 V6104           ::{W}:{N}\.{N}\.{N}\.{N}
 164 V6114           {W}::{N}\.{N}\.{N}\.{N}
 165
 166 V6004           ::{N}\.{N}\.{N}\.{N}
 167
 168
 169 V6              ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
 170
 171 MAC             ({B}:{B}:{B}:{B}:{B}:{B}|{B}\-{B}\-{B}\-{B}\-{B}\-{B}|{B}\.{B}\.{B}\.{B}\.{B}\.{B}|{B2}\.{B2}\.{B2}|{B2}{3})
 172
 173
 174
 175 %%
 176 dst             return DST;
 177 src             return SRC;
 178
 179 link|ether|ppp|slip  return LINK;
 180 fddi|tr|wlan    return LINK;
 181 arp             return ARP;
 182 rarp            return RARP;
 183 ip              return IP;
 184 sctp            return SCTP;
 185 tcp             return TCP;
 186 udp             return UDP;
 187 icmp            return ICMP;
 188 igmp            return IGMP;
 189 igrp            return IGRP;
 190 pim             return PIM;
 191 vrrp            return VRRP;
 192 radio           return RADIO;
 193
 194 ip6             {
 195 #ifdef INET6
 196                 return IPV6;
 197 #else
 198                 bpf_error("%s not supported", yytext);
 199 #endif
 200                 }
 201 icmp6           {
 202 #ifdef INET6
 203                 return ICMPV6;
 204 #else
 205                 bpf_error("%s not supported", yytext);
 206 #endif
 207                 }
 208 ah              return AH;
 209 esp             return ESP;
 210
 211 atalk           return ATALK;
 212 aarp            return AARP;
 213 decnet          return DECNET;
 214 lat             return LAT;
 215 sca             return SCA;
 216 moprc           return MOPRC;
 217 mopdl           return MOPDL;
 218
 219 iso             return ISO;
 220 esis            return ESIS;
 221 es-is           return ESIS;
 222 isis            return ISIS;
 223 is-is           return ISIS;
 224 l1              return L1;
 225 l2              return L2;
 226 iih             return IIH;
 227 lsp             return LSP;
 228 snp             return SNP;
 229 csnp            return CSNP;
 230 psnp            return PSNP;
 231
 232 clnp            return CLNP;
 233
 234 stp             return STP;
 235
 236 ipx             return IPX;
 237
 238 netbeui         return NETBEUI;
 239
 240 host            return HOST;
 241 net             return NET;
 242 mask            return NETMASK;
 243 port            return PORT;
 244 portrange       return PORTRANGE;
 245 proto           return PROTO;
 246 protochain      {
 247 #ifdef NO_PROTOCHAIN
 248                   bpf_error("%s not supported", yytext);
 249 #else
 250                   return PROTOCHAIN;
 251 #endif
 252                 }
 253
 254 gateway         return GATEWAY;
 255
 256 type            return TYPE;
 257 subtype         return SUBTYPE;
 258 direction|dir   return DIR;
 259 address1|addr1  return ADDR1;
 260 address2|addr2  return ADDR2;
 261 address3|addr3  return ADDR3;
 262 address4|addr4  return ADDR4;
 263
 264 less            return LESS;
 265 greater         return GREATER;
 266 byte            return CBYTE;
 267 broadcast       return TK_BROADCAST;
 268 multicast       return TK_MULTICAST;
 269
 270 and|"&&"        return AND;
 271 or|"||"         return OR;
 272 not             return '!';
 273
 274 len|length      return LEN;
 275 inbound         return INBOUND;
 276 outbound        return OUTBOUND;
 277
 278 vlan            return VLAN;
 279 mpls            return MPLS;
 280 pppoed          return PPPOED;
 281 pppoes          return PPPOES;
 282
 283 lane            return LANE;
 284 llc             return LLC;
 285 metac           return METAC;
 286 bcc             return BCC;
 287 oam             return OAM;
 288 oamf4           return OAMF4;
 289 oamf4ec         return OAMF4EC;
 290 oamf4sc         return OAMF4SC;
 291 sc              return SC;
 292 ilmic           return ILMIC;
 293 vpi             return VPI;
 294 vci             return VCI;
 295 connectmsg      return CONNECTMSG;
 296 metaconnect     return METACONNECT;
 297
 298 on|ifname       return PF_IFNAME;
 299 rset|ruleset    return PF_RSET;
 300 rnr|rulenum     return PF_RNR;
 301 srnr|subrulenum return PF_SRNR;
 302 reason          return PF_REASON;
 303 action          return PF_ACTION;
 304
 305 fisu            return FISU;
 306 lssu            return LSSU;
 307 lsu             return LSSU;
 308 msu             return MSU;
 309 sio             return SIO;
 310 opc             return OPC;
 311 dpc             return DPC;
 312 sls             return SLS;
 313
 314 [ \r\n\t]               ;
 315 [+\-*/:\[\]!<>()&|=]    return yytext[0];
 316 ">="                    return GEQ;
 317 "<="                    return LEQ;
 318 "!="                    return NEQ;
 319 "=="                    return '=';
 320 "<<"                    return LSH;
 321 ">>"                    return RSH;
 322 ${B}                    { yylval.e = pcap_ether_aton(((char *)yytext)+1);
 323                           return AID; }
 324 {MAC}                   { yylval.e = pcap_ether_aton((char *)yytext);
 325                           return EID; }
 326 {N}                     { yylval.i = stoi((char *)yytext); return NUM; }
 327 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
 328                         yylval.s = sdup((char *)yytext); return HID; }
 329 {V6}                    {
 330 #ifdef INET6
 331                           struct addrinfo hints, *res;
 332                           memset(&hints, 0, sizeof(hints));
 333                           hints.ai_family = AF_INET6;
 334                           hints.ai_flags = AI_NUMERICHOST;
 335                           if (getaddrinfo(yytext, NULL, &hints, &res))
 336                                 bpf_error("bogus IPv6 address %s", yytext);
 337                           else {
 338                                 yylval.s = sdup((char *)yytext); return HID6;
 339                           }
 340 #else
 341                           bpf_error("IPv6 address %s not supported", yytext);
 342 #endif /*INET6*/
 343                         }
 344 {B}:+({B}:+)+           { bpf_error("bogus ethernet address %s", yytext); }
 345 icmptype                { yylval.i = 0; return NUM; }
 346 icmpcode                { yylval.i = 1; return NUM; }
 347 icmp-echoreply          { yylval.i = 0; return NUM; }
 348 icmp-unreach            { yylval.i = 3; return NUM; }
 349 icmp-sourcequench       { yylval.i = 4; return NUM; }
 350 icmp-redirect           { yylval.i = 5; return NUM; }
 351 icmp-echo               { yylval.i = 8; return NUM; }
 352 icmp-routeradvert       { yylval.i = 9; return NUM; }
 353 icmp-routersolicit      { yylval.i = 10; return NUM; }
 354 icmp-timxceed           { yylval.i = 11; return NUM; }
 355 icmp-paramprob          { yylval.i = 12; return NUM; }
 356 icmp-tstamp             { yylval.i = 13; return NUM; }
 357 icmp-tstampreply        { yylval.i = 14; return NUM; }
 358 icmp-ireq               { yylval.i = 15; return NUM; }
 359 icmp-ireqreply          { yylval.i = 16; return NUM; }
 360 icmp-maskreq            { yylval.i = 17; return NUM; }
 361 icmp-maskreply          { yylval.i = 18; return NUM; }
 362 tcpflags                { yylval.i = 13; return NUM; }
 363 tcp-fin                 { yylval.i = 0x01; return NUM; }
 364 tcp-syn                 { yylval.i = 0x02; return NUM; }
 365 tcp-rst                 { yylval.i = 0x04; return NUM; }
 366 tcp-push                { yylval.i = 0x08; return NUM; }
 367 tcp-ack                 { yylval.i = 0x10; return NUM; }
 368 tcp-urg                 { yylval.i = 0x20; return NUM; }
 369 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
 370                          yylval.s = sdup((char *)yytext); return ID; }
 371 "\\"[^ !()\n\t]+        { yylval.s = sdup((char *)yytext + 1); return ID; }
 372 [^ \[\]\t\n\-_.A-Za-z0-9!<>()&|=]+ {
 373                         bpf_error("illegal token: %s", yytext); }
 374 .                       { bpf_error("illegal char '%c'", *yytext); }
 375 %%
 376 void
 377 lex_init(buf)
 378         const char *buf;
 379 {
 380 #ifdef FLEX_SCANNER
 381         in_buffer = yy_scan_string(buf);
 382 #else
 383         in_buffer = buf;
 384 #endif
 385 }
 386
 387 /*
 388  * Do any cleanup necessary after parsing.
 389  */
 390 void
 391 lex_cleanup()
 392 {
 393 #ifdef FLEX_SCANNER
 394         if (in_buffer != NULL)
 395                 yy_delete_buffer(in_buffer);
 396         in_buffer = NULL;
 397 #endif
 398 }
 399
 400 /*
 401  * Also define a yywrap.  Note that if we're using flex, it will
 402  * define a macro to map this identifier to pcap_wrap.
 403  */
 404 int
 405 yywrap()
 406 {
 407         return 1;
 408 }
 409
 410 /* Hex digit to integer. */
 411 static inline int
 412 xdtoi(c)
 413         register int c;
 414 {
 415         if (isdigit(c))
 416                 return c - '0';
 417         else if (islower(c))
 418                 return c - 'a' + 10;
 419         else
 420                 return c - 'A' + 10;
 421 }
 422
 423 /*
 424  * Convert string to integer.  Just like atoi(), but checks for
 425  * preceding 0x or 0 and uses hex or octal instead of decimal.
 426  */
 427 static int
 428 stoi(s)
 429         char *s;
 430 {
 431         int base = 10;
 432         int n = 0;
 433
 434         if (*s == '0') {
 435                 if (s[1] == 'x' || s[1] == 'X') {
 436                         s += 2;
 437                         base = 16;
 438                 }
 439                 else {
 440                         base = 8;
 441                         s += 1;
 442                 }
 443         }
 444         while (*s)
 445                 n = n * base + xdtoi(*s++);
 446
 447         return n;
 448 }