contrib/libpcap/scanner.l

   1 %{
   2 /*
   3  * Copyright (c) 1988, 1989, 1990, 1991, 1992, 1993, 1994, 1995, 1996, 1997
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that: (1) source code distributions
   8  * retain the above copyright notice and this paragraph in its entirety, (2)
   9  * distributions including binary code include the above copyright notice and
  10  * this paragraph in its entirety in the documentation or other materials
  11  * provided with the distribution, and (3) all advertising materials mentioning
  12  * features or use of this software display the following acknowledgement:
  13  * ``This product includes software developed by the University of California,
  14  * Lawrence Berkeley Laboratory and its contributors.'' Neither the name of
  15  * the University nor the names of its contributors may be used to endorse
  16  * or promote products derived from this software without specific prior
  17  * written permission.
  18  * THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
  19  * WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
  20  * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  21  */
  22
  23 #ifndef lint
  24 static const char rcsid[] _U_ =
  25     "@(#) $Header: /tcpdump/master/libpcap/scanner.l,v 1.112 2008-02-06 10:21:30 guy Exp $ (LBL)";
  26 #endif
  27
  28 #ifdef HAVE_CONFIG_H
  29 #include "config.h"
  30 #endif
  31
  32 #ifdef WIN32
  33 #include <pcap-stdinc.h>
  34 #else /* WIN32 */
  35 #if HAVE_INTTYPES_H
  36 #include <inttypes.h>
  37 #elif HAVE_STDINT_H
  38 #include <stdint.h>
  39 #endif
  40 #ifdef HAVE_SYS_BITYPES_H
  41 #include <sys/bitypes.h>
  42 #endif
  43 #include <sys/types.h>
  44 #endif /* WIN32 */
  45
  46 #include <ctype.h>
  47 #include <string.h>
  48
  49 #include "pcap-int.h"
  50
  51 #include "gencode.h"
  52 #ifdef INET6
  53 #ifdef WIN32
  54 #include <pcap-stdinc.h>
  55
  56 #ifdef __MINGW32__
  57 #include "ip6_misc.h"
  58 #endif
  59 #else /* WIN32 */
  60 #include <sys/socket.h> /* for "struct sockaddr" in "struct addrinfo" */
  61 #include <netdb.h>      /* for "struct addrinfo" */
  62 #endif /* WIN32 */
  63
  64 /* Workaround for AIX 4.3 */
  65 #if !defined(AI_NUMERICHOST)
  66 #define AI_NUMERICHOST 0x04
  67 #endif
  68 #endif /*INET6*/
  69 #include <pcap/namedb.h>
  70 #include "tokdefs.h"
  71
  72 #ifdef HAVE_OS_PROTO_H
  73 #include "os-proto.h"
  74 #endif
  75
  76 static int stoi(char *);
  77 static inline int xdtoi(int);
  78
  79 #ifdef FLEX_SCANNER
  80 static YY_BUFFER_STATE in_buffer;
  81 #else
  82 static const char *in_buffer;
  83
  84 #undef getc
  85 #define getc(fp)  (*in_buffer == 0 ? EOF : *in_buffer++)
  86 #endif
  87
  88 #define yylval pcap_lval
  89 extern YYSTYPE yylval;
  90
  91 %}
  92
  93 N               ([0-9]+|(0X|0x)[0-9A-Fa-f]+)
  94 B               ([0-9A-Fa-f][0-9A-Fa-f]?)
  95 B2              ([0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f][0-9A-Fa-f])
  96 W               ([0-9A-Fa-f][0-9A-Fa-f]?[0-9A-Fa-f]?[0-9A-Fa-f]?)
  97
  98 %a 18400
  99 %o 21500
 100 %e 7600
 101 %k 4550
 102 %p 27600
 103 %n 2000
 104
 105 V680            {W}:{W}:{W}:{W}:{W}:{W}:{W}:{W}
 106
 107 V670            ::{W}:{W}:{W}:{W}:{W}:{W}:{W}
 108 V671            {W}::{W}:{W}:{W}:{W}:{W}:{W}
 109 V672            {W}:{W}::{W}:{W}:{W}:{W}:{W}
 110 V673            {W}:{W}:{W}::{W}:{W}:{W}:{W}
 111 V674            {W}:{W}:{W}:{W}::{W}:{W}:{W}
 112 V675            {W}:{W}:{W}:{W}:{W}::{W}:{W}
 113 V676            {W}:{W}:{W}:{W}:{W}:{W}::{W}
 114 V677            {W}:{W}:{W}:{W}:{W}:{W}:{W}::
 115
 116 V660            ::{W}:{W}:{W}:{W}:{W}:{W}
 117 V661            {W}::{W}:{W}:{W}:{W}:{W}
 118 V662            {W}:{W}::{W}:{W}:{W}:{W}
 119 V663            {W}:{W}:{W}::{W}:{W}:{W}
 120 V664            {W}:{W}:{W}:{W}::{W}:{W}
 121 V665            {W}:{W}:{W}:{W}:{W}::{W}
 122 V666            {W}:{W}:{W}:{W}:{W}:{W}::
 123
 124 V650            ::{W}:{W}:{W}:{W}:{W}
 125 V651            {W}::{W}:{W}:{W}:{W}
 126 V652            {W}:{W}::{W}:{W}:{W}
 127 V653            {W}:{W}:{W}::{W}:{W}
 128 V654            {W}:{W}:{W}:{W}::{W}
 129 V655            {W}:{W}:{W}:{W}:{W}::
 130
 131 V640            ::{W}:{W}:{W}:{W}
 132 V641            {W}::{W}:{W}:{W}
 133 V642            {W}:{W}::{W}:{W}
 134 V643            {W}:{W}:{W}::{W}
 135 V644            {W}:{W}:{W}:{W}::
 136
 137 V630            ::{W}:{W}:{W}
 138 V631            {W}::{W}:{W}
 139 V632            {W}:{W}::{W}
 140 V633            {W}:{W}:{W}::
 141
 142 V620            ::{W}:{W}
 143 V621            {W}::{W}
 144 V622            {W}:{W}::
 145
 146 V610            ::{W}
 147 V611            {W}::
 148
 149 V600            ::
 150
 151 V6604           {W}:{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 152
 153 V6504           ::{W}:{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 154 V6514           {W}::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 155 V6524           {W}:{W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 156 V6534           {W}:{W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 157 V6544           {W}:{W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 158 V6554           {W}:{W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 159
 160 V6404           ::{W}:{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 161 V6414           {W}::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 162 V6424           {W}:{W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 163 V6434           {W}:{W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 164 V6444           {W}:{W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 165
 166 V6304           ::{W}:{W}:{W}:{N}\.{N}\.{N}\.{N}
 167 V6314           {W}::{W}:{W}:{N}\.{N}\.{N}\.{N}
 168 V6324           {W}:{W}::{W}:{N}\.{N}\.{N}\.{N}
 169 V6334           {W}:{W}:{W}::{N}\.{N}\.{N}\.{N}
 170
 171 V6204           ::{W}:{W}:{N}\.{N}\.{N}\.{N}
 172 V6214           {W}::{W}:{N}\.{N}\.{N}\.{N}
 173 V6224           {W}:{W}::{N}\.{N}\.{N}\.{N}
 174
 175 V6104           ::{W}:{N}\.{N}\.{N}\.{N}
 176 V6114           {W}::{N}\.{N}\.{N}\.{N}
 177
 178 V6004           ::{N}\.{N}\.{N}\.{N}
 179
 180
 181 V6              ({V680}|{V670}|{V671}|{V672}|{V673}|{V674}|{V675}|{V676}|{V677}|{V660}|{V661}|{V662}|{V663}|{V664}|{V665}|{V666}|{V650}|{V651}|{V652}|{V653}|{V654}|{V655}|{V640}|{V641}|{V642}|{V643}|{V644}|{V630}|{V631}|{V632}|{V633}|{V620}|{V621}|{V622}|{V610}|{V611}|{V600}|{V6604}|{V6504}|{V6514}|{V6524}|{V6534}|{V6544}|{V6554}|{V6404}|{V6414}|{V6424}|{V6434}|{V6444}|{V6304}|{V6314}|{V6324}|{V6334}|{V6204}|{V6214}|{V6224}|{V6104}|{V6114}|{V6004})
 182
 183 MAC             ({B}:{B}:{B}:{B}:{B}:{B}|{B}\-{B}\-{B}\-{B}\-{B}\-{B}|{B}\.{B}\.{B}\.{B}\.{B}\.{B}|{B2}\.{B2}\.{B2}|{B2}{3})
 184
 185
 186 %option nounput
 187 %option noinput
 188
 189 %%
 190 dst             return DST;
 191 src             return SRC;
 192
 193 link|ether|ppp|slip  return LINK;
 194 fddi|tr|wlan    return LINK;
 195 arp             return ARP;
 196 rarp            return RARP;
 197 ip              return IP;
 198 sctp            return SCTP;
 199 tcp             return TCP;
 200 udp             return UDP;
 201 icmp            return ICMP;
 202 igmp            return IGMP;
 203 igrp            return IGRP;
 204 pim             return PIM;
 205 vrrp            return VRRP;
 206 carp            return CARP;
 207 radio           return RADIO;
 208
 209 ip6             {
 210 #ifdef INET6
 211                 return IPV6;
 212 #else
 213                 bpf_error("%s not supported", yytext);
 214 #endif
 215                 }
 216 icmp6           {
 217 #ifdef INET6
 218                 return ICMPV6;
 219 #else
 220                 bpf_error("%s not supported", yytext);
 221 #endif
 222                 }
 223 ah              return AH;
 224 esp             return ESP;
 225
 226 atalk           return ATALK;
 227 aarp            return AARP;
 228 decnet          return DECNET;
 229 lat             return LAT;
 230 sca             return SCA;
 231 moprc           return MOPRC;
 232 mopdl           return MOPDL;
 233
 234 iso             return ISO;
 235 esis            return ESIS;
 236 es-is           return ESIS;
 237 isis            return ISIS;
 238 is-is           return ISIS;
 239 l1              return L1;
 240 l2              return L2;
 241 iih             return IIH;
 242 lsp             return LSP;
 243 snp             return SNP;
 244 csnp            return CSNP;
 245 psnp            return PSNP;
 246
 247 clnp            return CLNP;
 248
 249 stp             return STP;
 250
 251 ipx             return IPX;
 252
 253 netbeui         return NETBEUI;
 254
 255 host            return HOST;
 256 net             return NET;
 257 mask            return NETMASK;
 258 port            return PORT;
 259 portrange       return PORTRANGE;
 260 proto           return PROTO;
 261 protochain      {
 262 #ifdef NO_PROTOCHAIN
 263                   bpf_error("%s not supported", yytext);
 264 #else
 265                   return PROTOCHAIN;
 266 #endif
 267                 }
 268
 269 gateway         return GATEWAY;
 270
 271 type            return TYPE;
 272 subtype         return SUBTYPE;
 273 direction|dir   return DIR;
 274 address1|addr1  return ADDR1;
 275 address2|addr2  return ADDR2;
 276 address3|addr3  return ADDR3;
 277 address4|addr4  return ADDR4;
 278 ra              return RA;
 279 ta              return TA;
 280
 281 less            return LESS;
 282 greater         return GREATER;
 283 byte            return CBYTE;
 284 broadcast       return TK_BROADCAST;
 285 multicast       return TK_MULTICAST;
 286
 287 and|"&&"        return AND;
 288 or|"||"         return OR;
 289 not             return '!';
 290
 291 len|length      return LEN;
 292 inbound         return INBOUND;
 293 outbound        return OUTBOUND;
 294
 295 vlan            return VLAN;
 296 mpls            return MPLS;
 297 pppoed          return PPPOED;
 298 pppoes          return PPPOES;
 299
 300 lane            return LANE;
 301 llc             return LLC;
 302 metac           return METAC;
 303 bcc             return BCC;
 304 oam             return OAM;
 305 oamf4           return OAMF4;
 306 oamf4ec         return OAMF4EC;
 307 oamf4sc         return OAMF4SC;
 308 sc              return SC;
 309 ilmic           return ILMIC;
 310 vpi             return VPI;
 311 vci             return VCI;
 312 connectmsg      return CONNECTMSG;
 313 metaconnect     return METACONNECT;
 314
 315 on|ifname       return PF_IFNAME;
 316 rset|ruleset    return PF_RSET;
 317 rnr|rulenum     return PF_RNR;
 318 srnr|subrulenum return PF_SRNR;
 319 reason          return PF_REASON;
 320 action          return PF_ACTION;
 321
 322 fisu            return FISU;
 323 lssu            return LSSU;
 324 lsu             return LSSU;
 325 msu             return MSU;
 326 sio             return SIO;
 327 opc             return OPC;
 328 dpc             return DPC;
 329 sls             return SLS;
 330
 331 [ \r\n\t]               ;
 332 [+\-*/:\[\]!<>()&|=]    return yytext[0];
 333 ">="                    return GEQ;
 334 "<="                    return LEQ;
 335 "!="                    return NEQ;
 336 "=="                    return '=';
 337 "<<"                    return LSH;
 338 ">>"                    return RSH;
 339 ${B}                    { yylval.e = pcap_ether_aton(((char *)yytext)+1);
 340                           return AID; }
 341 {MAC}                   { yylval.e = pcap_ether_aton((char *)yytext);
 342                           return EID; }
 343 {N}                     { yylval.i = stoi((char *)yytext); return NUM; }
 344 ({N}\.{N})|({N}\.{N}\.{N})|({N}\.{N}\.{N}\.{N}) {
 345                         yylval.s = sdup((char *)yytext); return HID; }
 346 {V6}                    {
 347 #ifdef INET6
 348                           struct addrinfo hints, *res;
 349                           memset(&hints, 0, sizeof(hints));
 350                           hints.ai_family = AF_INET6;
 351                           hints.ai_flags = AI_NUMERICHOST;
 352                           if (getaddrinfo(yytext, NULL, &hints, &res))
 353                                 bpf_error("bogus IPv6 address %s", yytext);
 354                           else {
 355                                 freeaddrinfo(res);
 356                                 yylval.s = sdup((char *)yytext); return HID6;
 357                           }
 358 #else
 359                           bpf_error("IPv6 address %s not supported", yytext);
 360 #endif /*INET6*/
 361                         }
 362 {B}:+({B}:+)+           { bpf_error("bogus ethernet address %s", yytext); }
 363 icmptype                { yylval.i = 0; return NUM; }
 364 icmpcode                { yylval.i = 1; return NUM; }
 365 icmp-echoreply          { yylval.i = 0; return NUM; }
 366 icmp-unreach            { yylval.i = 3; return NUM; }
 367 icmp-sourcequench       { yylval.i = 4; return NUM; }
 368 icmp-redirect           { yylval.i = 5; return NUM; }
 369 icmp-echo               { yylval.i = 8; return NUM; }
 370 icmp-routeradvert       { yylval.i = 9; return NUM; }
 371 icmp-routersolicit      { yylval.i = 10; return NUM; }
 372 icmp-timxceed           { yylval.i = 11; return NUM; }
 373 icmp-paramprob          { yylval.i = 12; return NUM; }
 374 icmp-tstamp             { yylval.i = 13; return NUM; }
 375 icmp-tstampreply        { yylval.i = 14; return NUM; }
 376 icmp-ireq               { yylval.i = 15; return NUM; }
 377 icmp-ireqreply          { yylval.i = 16; return NUM; }
 378 icmp-maskreq            { yylval.i = 17; return NUM; }
 379 icmp-maskreply          { yylval.i = 18; return NUM; }
 380 tcpflags                { yylval.i = 13; return NUM; }
 381 tcp-fin                 { yylval.i = 0x01; return NUM; }
 382 tcp-syn                 { yylval.i = 0x02; return NUM; }
 383 tcp-rst                 { yylval.i = 0x04; return NUM; }
 384 tcp-push                { yylval.i = 0x08; return NUM; }
 385 tcp-ack                 { yylval.i = 0x10; return NUM; }
 386 tcp-urg                 { yylval.i = 0x20; return NUM; }
 387 [A-Za-z0-9]([-_.A-Za-z0-9]*[.A-Za-z0-9])? {
 388                          yylval.s = sdup((char *)yytext); return ID; }
 389 "\\"[^ !()\n\t]+        { yylval.s = sdup((char *)yytext + 1); return ID; }
 390 [^ \[\]\t\n\-_.A-Za-z0-9!<>()&|=]+ {
 391                         bpf_error("illegal token: %s", yytext); }
 392 .                       { bpf_error("illegal char '%c'", *yytext); }
 393 %%
 394 void
 395 lex_init(buf)
 396         const char *buf;
 397 {
 398 #ifdef FLEX_SCANNER
 399         in_buffer = yy_scan_string(buf);
 400 #else
 401         in_buffer = buf;
 402 #endif
 403 }
 404
 405 /*
 406  * Do any cleanup necessary after parsing.
 407  */
 408 void
 409 lex_cleanup()
 410 {
 411 #ifdef FLEX_SCANNER
 412         if (in_buffer != NULL)
 413                 yy_delete_buffer(in_buffer);
 414         in_buffer = NULL;
 415 #endif
 416 }
 417
 418 /*
 419  * Also define a yywrap.  Note that if we're using flex, it will
 420  * define a macro to map this identifier to pcap_wrap.
 421  */
 422 int
 423 yywrap()
 424 {
 425         return 1;
 426 }
 427
 428 /* Hex digit to integer. */
 429 static inline int
 430 xdtoi(c)
 431         register int c;
 432 {
 433         if (isdigit(c))
 434                 return c - '0';
 435         else if (islower(c))
 436                 return c - 'a' + 10;
 437         else
 438                 return c - 'A' + 10;
 439 }
 440
 441 /*
 442  * Convert string to integer.  Just like atoi(), but checks for
 443  * preceding 0x or 0 and uses hex or octal instead of decimal.
 444  */
 445 static int
 446 stoi(s)
 447         char *s;
 448 {
 449         int base = 10;
 450         int n = 0;
 451
 452         if (*s == '0') {
 453                 if (s[1] == 'x' || s[1] == 'X') {
 454                         s += 2;
 455                         base = 16;
 456                 }
 457                 else {
 458                         base = 8;
 459                         s += 1;
 460                 }
 461         }
 462         while (*s)
 463                 n = n * base + xdtoi(*s++);
 464
 465         return n;
 466 }