contrib/gcc-4.4/gcc/optc-gen.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicate options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         n_target_save = 0
  32         quote = "\042"
  33         comma = ","
  34         FS=SUBSEP
  35         # Default the name of header created from opth-gen.awk to options.h
  36         if (header_name == "") header_name="options.h"
  37 }
  38
  39 # Collect the text and flags of each option into an array
  40         {
  41                 if ($1 == "Language") {
  42                         langs[n_langs] = $2
  43                         n_langs++;
  44                 }
  45                 else if ($1 == "TargetSave") {
  46                         # Make sure the declarations are put in source order
  47                         target_save_decl[n_target_save] = $2
  48                         n_target_save++
  49                 }
  50                 else {
  51                         name = opt_args("Mask", $1)
  52                         if (name == "") {
  53                                 opts[n_opts]  = $1
  54                                 flags[n_opts] = $2
  55                                 help[n_opts]  = $3
  56                                 for (i = 4; i <= NF; i++)
  57                                         help[n_opts] = help[n_opts] " " $i
  58                                 n_opts++;
  59                         }
  60                 }
  61         }
  62
  63 # Dump that array of options into a C file.
  64 END {
  65 print "/* This file is auto-generated by optc-gen.awk.  */"
  66 print ""
  67 n_headers = split(header_name, headers, " ")
  68 for (i = 1; i <= n_headers; i++)
  69         print "#include " quote headers[i] quote
  70 print "#include " quote "opts.h" quote
  71 print "#include " quote "intl.h" quote
  72 print ""
  73 print "#ifdef GCC_DRIVER"
  74 print "int target_flags;"
  75 print "#else"
  76 print "#include " quote "flags.h" quote
  77 print "#include " quote "target.h" quote
  78 print "#endif /* GCC_DRIVER */"
  79 print ""
  80
  81 have_save = 0;
  82 for (i = 0; i < n_opts; i++) {
  83         if (flag_set_p("Save", flags[i]))
  84                 have_save = 1;
  85
  86         name = var_name(flags[i]);
  87         if (name == "")
  88                 continue;
  89
  90         if (flag_set_p("VarExists", flags[i])) {
  91                 # Need it for the gcc driver.
  92                 if (name in var_seen)
  93                         continue;
  94                 init = ""
  95                 gcc_driver = 1
  96         }
  97         else {
  98                 init = opt_args("Init", flags[i])
  99                 if (init != "")
 100                         init = " = " init;
 101                 else if (name in var_seen)
 102                         continue;
 103                 gcc_driver = 0
 104         }
 105
 106         if (gcc_driver == 1)
 107                 print "#ifdef GCC_DRIVER"
 108         print "/* Set by -" opts[i] "."
 109         print "   " help[i] "  */"
 110         print var_type(flags[i]) name init ";"
 111         if (gcc_driver == 1)
 112                 print "#endif /* GCC_DRIVER */"
 113         print ""
 114
 115         var_seen[name] = 1;
 116 }
 117
 118 print ""
 119 print "/* Local state variables.  */"
 120 for (i = 0; i < n_opts; i++) {
 121         name = static_var(opts[i], flags[i]);
 122         if (name != "")
 123                 print "static " var_type(flags[i]) name ";"
 124 }
 125 print ""
 126
 127 print "const char * const lang_names[] =\n{"
 128 for (i = 0; i < n_langs; i++) {
 129         macros[i] = "CL_" langs[i]
 130         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 131         s = substr("         ", length (macros[i]))
 132         print "  " quote langs[i] quote ","
 133     }
 134
 135 print "  0\n};\n"
 136 print "const unsigned int cl_options_count = N_OPTS;\n"
 137 print "const unsigned int cl_lang_count = " n_langs ";\n"
 138
 139 print "const struct cl_option cl_options[] =\n{"
 140
 141 j = 0
 142 for (i = 0; i < n_opts; i++) {
 143         back_chain[i] = "N_OPTS";
 144         indices[opts[i]] = j;
 145         # Combine the flags of identical switches.  Switches
 146         # appear many times if they are handled by many front
 147         # ends, for example.
 148         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 149                 flags[i + 1] = flags[i] " " flags[i + 1];
 150                 if (help[i + 1] == "")
 151                         help[i + 1] = help[i]
 152                 i++;
 153                 back_chain[i] = "N_OPTS";
 154                 indices[opts[i]] = j;
 155         }
 156         j++;
 157 }
 158
 159 for (i = 0; i < n_opts; i++) {
 160         # With identical flags, pick only the last one.  The
 161         # earlier loop ensured that it has all flags merged,
 162         # and a nonempty help text if one of the texts was nonempty.
 163         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 164                 i++;
 165         }
 166
 167         len = length (opts[i]);
 168         enum = "OPT_" opts[i]
 169         if (opts[i] == "finline-limit=" || opts[i] == "Wlarger-than=")
 170                 enum = enum "eq"
 171         gsub ("[^A-Za-z0-9]", "_", enum)
 172
 173         # If this switch takes joined arguments, back-chain all
 174         # subsequent switches to it for which it is a prefix.  If
 175         # a later switch S is a longer prefix of a switch T, T
 176         # will be back-chained to S in a later iteration of this
 177         # for() loop, which is what we want.
 178         if (flag_set_p("Joined.*", flags[i])) {
 179                 for (j = i + 1; j < n_opts; j++) {
 180                         if (substr (opts[j], 1, len) != opts[i])
 181                                 break;
 182                         back_chain[j] = enum;
 183                 }
 184         }
 185
 186         s = substr("                                  ", length (opts[i]))
 187         if (i + 1 == n_opts)
 188                 comma = ""
 189
 190         if (help[i] == "")
 191                 hlp = "0"
 192         else
 193                 hlp = quote help[i] quote;
 194
 195         neg = opt_args("Negative", flags[i]);
 196         if (neg != "")
 197                 idx = indices[neg]
 198         else {
 199                 if (flag_set_p("RejectNegative", flags[i]))
 200                         idx = -1;
 201                 else {
 202                         if (opts[i] ~ "^[Wfm]")
 203                                 idx = indices[opts[i]];
 204                         else
 205                                 idx = -1;
 206                 }
 207         }
 208         # Split the printf after %u to work around an ia64-hp-hpux11.23
 209         # awk bug.
 210         printf("  { %c-%s%c,\n    %s,\n    %s, %u,",
 211                quote, opts[i], quote, hlp, back_chain[i], len)
 212         printf(" %d,\n", idx)
 213         condition = opt_args("Condition", flags[i])
 214         cl_flags = switch_flags(flags[i])
 215         if (condition != "")
 216                 printf("#if %s\n" \
 217                        "    %s,\n" \
 218                        "#else\n" \
 219                        "    CL_DISABLED,\n" \
 220                        "#endif\n",
 221                        condition, cl_flags, cl_flags)
 222         else
 223                 printf("    %s,\n", cl_flags)
 224         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 225                var_set(flags[i]), comma)
 226 }
 227
 228 print "};"
 229
 230 print "";
 231 print "#if !defined(GCC_DRIVER) && !defined(IN_LIBGCC2) && !defined(IN_TARGET_LIBS)"
 232 print "";
 233 print "/* Save optimization variables into a structure.  */"
 234 print "void";
 235 print "cl_optimization_save (struct cl_optimization *ptr)";
 236 print "{";
 237
 238 n_opt_char = 2;
 239 n_opt_short = 0;
 240 n_opt_int = 0;
 241 n_opt_other = 0;
 242 var_opt_char[0] = "optimize";
 243 var_opt_char[1] = "optimize_size";
 244 var_opt_range["optimize"] = "0, 255";
 245 var_opt_range["optimize_size"] = "0, 255";
 246
 247 # Sort by size to mimic how the structure is laid out to be friendlier to the
 248 # cache.
 249
 250 for (i = 0; i < n_opts; i++) {
 251         if (flag_set_p("Optimization", flags[i])) {
 252                 name = var_name(flags[i])
 253                 if(name == "")
 254                         continue;
 255
 256                 if(name in var_opt_seen)
 257                         continue;
 258
 259                 var_opt_seen[name]++;
 260                 otype = var_type_struct(flags[i]);
 261                 if (otype ~ "^((un)?signed +)?int *$")
 262                         var_opt_int[n_opt_int++] = name;
 263
 264                 else if (otype ~ "^((un)?signed +)?short *$")
 265                         var_opt_short[n_opt_short++] = name;
 266
 267                 else if (otype ~ "^((un)?signed +)?char *$") {
 268                         var_opt_char[n_opt_char++] = name;
 269                         if (otype ~ "^unsigned +char *$")
 270                                 var_opt_range[name] = "0, 255"
 271                         else if (otype ~ "^signed +char *$")
 272                                 var_opt_range[name] = "-128, 127"
 273                 }
 274                 else
 275                         var_opt_other[n_opt_other++] = name;
 276         }
 277 }
 278
 279 for (i = 0; i < n_opt_char; i++) {
 280         name = var_opt_char[i];
 281         if (var_opt_range[name] != "")
 282                 print "  gcc_assert (IN_RANGE (" name ", " var_opt_range[name] "));";
 283 }
 284
 285 print "";
 286 for (i = 0; i < n_opt_other; i++) {
 287         print "  ptr->" var_opt_other[i] " = " var_opt_other[i] ";";
 288 }
 289
 290 for (i = 0; i < n_opt_int; i++) {
 291         print "  ptr->" var_opt_int[i] " = " var_opt_int[i] ";";
 292 }
 293
 294 for (i = 0; i < n_opt_short; i++) {
 295         print "  ptr->" var_opt_short[i] " = " var_opt_short[i] ";";
 296 }
 297
 298 for (i = 0; i < n_opt_char; i++) {
 299         print "  ptr->" var_opt_char[i] " = " var_opt_char[i] ";";
 300 }
 301
 302 print "}";
 303
 304 print "";
 305 print "/* Restore optimization options from a structure.  */";
 306 print "void";
 307 print "cl_optimization_restore (struct cl_optimization *ptr)";
 308 print "{";
 309
 310 for (i = 0; i < n_opt_other; i++) {
 311         print "  " var_opt_other[i] " = ptr->" var_opt_other[i] ";";
 312 }
 313
 314 for (i = 0; i < n_opt_int; i++) {
 315         print "  " var_opt_int[i] " = ptr->" var_opt_int[i] ";";
 316 }
 317
 318 for (i = 0; i < n_opt_short; i++) {
 319         print "  " var_opt_short[i] " = ptr->" var_opt_short[i] ";";
 320 }
 321
 322 for (i = 0; i < n_opt_char; i++) {
 323         print "  " var_opt_char[i] " = ptr->" var_opt_char[i] ";";
 324 }
 325
 326 print "}";
 327
 328 print "";
 329 print "/* Print optimization options from a structure.  */";
 330 print "void";
 331 print "cl_optimization_print (FILE *file,";
 332 print "                       int indent_to,";
 333 print "                       struct cl_optimization *ptr)";
 334 print "{";
 335
 336 print "  fputs (\"\\n\", file);";
 337 for (i = 0; i < n_opt_other; i++) {
 338         print "  if (ptr->" var_opt_other[i] ")";
 339         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 340         print "             indent_to, \"\",";
 341         print "             \"" var_opt_other[i] "\",";
 342         print "             (unsigned long)ptr->" var_opt_other[i] ");";
 343         print "";
 344 }
 345
 346 for (i = 0; i < n_opt_int; i++) {
 347         print "  if (ptr->" var_opt_int[i] ")";
 348         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 349         print "             indent_to, \"\",";
 350         print "             \"" var_opt_int[i] "\",";
 351         print "             ptr->" var_opt_int[i] ");";
 352         print "";
 353 }
 354
 355 for (i = 0; i < n_opt_short; i++) {
 356         print "  if (ptr->" var_opt_short[i] ")";
 357         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 358         print "             indent_to, \"\",";
 359         print "             \"" var_opt_short[i] "\",";
 360         print "             ptr->" var_opt_short[i] ");";
 361         print "";
 362 }
 363
 364 for (i = 0; i < n_opt_char; i++) {
 365         print "  if (ptr->" var_opt_char[i] ")";
 366         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 367         print "             indent_to, \"\",";
 368         print "             \"" var_opt_char[i] "\",";
 369         print "             ptr->" var_opt_char[i] ");";
 370         print "";
 371 }
 372
 373 print "}";
 374
 375 print "";
 376 print "/* Save selected option variables into a structure.  */"
 377 print "void";
 378 print "cl_target_option_save (struct cl_target_option *ptr)";
 379 print "{";
 380
 381 n_target_char = 0;
 382 n_target_short = 0;
 383 n_target_int = 0;
 384 n_target_other = 0;
 385
 386 if (have_save) {
 387         for (i = 0; i < n_opts; i++) {
 388                 if (flag_set_p("Save", flags[i])) {
 389                         name = var_name(flags[i])
 390                         if(name == "")
 391                                 name = "target_flags";
 392
 393                         if(name in var_save_seen)
 394                                 continue;
 395
 396                         var_save_seen[name]++;
 397                         otype = var_type_struct(flags[i])
 398                         if (otype ~ "^((un)?signed +)?int *$")
 399                                 var_target_int[n_target_int++] = name;
 400
 401                         else if (otype ~ "^((un)?signed +)?short *$")
 402                                 var_target_short[n_target_short++] = name;
 403
 404                         else if (otype ~ "^((un)?signed +)?char *$") {
 405                                 var_target_char[n_target_char++] = name;
 406                                 if (otype ~ "^unsigned +char *$")
 407                                         var_target_range[name] = "0, 255"
 408                                 else if (otype ~ "^signed +char *$")
 409                                         var_target_range[name] = "-128, 127"
 410                         }
 411                         else
 412                                 var_target_other[n_target_other++] = name;
 413                 }
 414         }
 415 } else {
 416         var_target_int[n_target_int++] = "target_flags";
 417 }
 418
 419 have_assert = 0;
 420 for (i = 0; i < n_target_char; i++) {
 421         name = var_target_char[i];
 422         if (var_target_range[name] != "") {
 423                 have_assert = 1;
 424                 print "  gcc_assert (IN_RANGE (" name ", " var_target_range[name] "));";
 425         }
 426 }
 427
 428 if (have_assert)
 429         print "";
 430
 431 print "  if (targetm.target_option.save)";
 432 print "    targetm.target_option.save (ptr);";
 433 print "";
 434
 435 for (i = 0; i < n_target_other; i++) {
 436         print "  ptr->" var_target_other[i] " = " var_target_other[i] ";";
 437 }
 438
 439 for (i = 0; i < n_target_int; i++) {
 440         print "  ptr->" var_target_int[i] " = " var_target_int[i] ";";
 441 }
 442
 443 for (i = 0; i < n_target_short; i++) {
 444         print "  ptr->" var_target_short[i] " = " var_target_short[i] ";";
 445 }
 446
 447 for (i = 0; i < n_target_char; i++) {
 448         print "  ptr->" var_target_char[i] " = " var_target_char[i] ";";
 449 }
 450
 451 print "}";
 452
 453 print "";
 454 print "/* Restore selected current options from a structure.  */";
 455 print "void";
 456 print "cl_target_option_restore (struct cl_target_option *ptr)";
 457 print "{";
 458
 459 for (i = 0; i < n_target_other; i++) {
 460         print "  " var_target_other[i] " = ptr->" var_target_other[i] ";";
 461 }
 462
 463 for (i = 0; i < n_target_int; i++) {
 464         print "  " var_target_int[i] " = ptr->" var_target_int[i] ";";
 465 }
 466
 467 for (i = 0; i < n_target_short; i++) {
 468         print "  " var_target_short[i] " = ptr->" var_target_short[i] ";";
 469 }
 470
 471 for (i = 0; i < n_target_char; i++) {
 472         print "  " var_target_char[i] " = ptr->" var_target_char[i] ";";
 473 }
 474
 475 # This must occur after the normal variables in case the code depends on those
 476 # variables.
 477 print "";
 478 print "  if (targetm.target_option.restore)";
 479 print "    targetm.target_option.restore (ptr);";
 480
 481 print "}";
 482
 483 print "";
 484 print "/* Print optimization options from a structure.  */";
 485 print "void";
 486 print "cl_target_option_print (FILE *file,";
 487 print "                        int indent,";
 488 print "                        struct cl_target_option *ptr)";
 489 print "{";
 490
 491 print "  fputs (\"\\n\", file);";
 492 for (i = 0; i < n_target_other; i++) {
 493         print "  if (ptr->" var_target_other[i] ")";
 494         print "    fprintf (file, \"%*s%s (0x%lx)\\n\",";
 495         print "             indent, \"\",";
 496         print "             \"" var_target_other[i] "\",";
 497         print "             (unsigned long)ptr->" var_target_other[i] ");";
 498         print "";
 499 }
 500
 501 for (i = 0; i < n_target_int; i++) {
 502         print "  if (ptr->" var_target_int[i] ")";
 503         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 504         print "             indent, \"\",";
 505         print "             \"" var_target_int[i] "\",";
 506         print "             ptr->" var_target_int[i] ");";
 507         print "";
 508 }
 509
 510 for (i = 0; i < n_target_short; i++) {
 511         print "  if (ptr->" var_target_short[i] ")";
 512         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 513         print "             indent, \"\",";
 514         print "             \"" var_target_short[i] "\",";
 515         print "             ptr->" var_target_short[i] ");";
 516         print "";
 517 }
 518
 519 for (i = 0; i < n_target_char; i++) {
 520         print "  if (ptr->" var_target_char[i] ")";
 521         print "    fprintf (file, \"%*s%s (0x%x)\\n\",";
 522         print "             indent, \"\",";
 523         print "             \"" var_target_char[i] "\",";
 524         print "             ptr->" var_target_char[i] ");";
 525         print "";
 526 }
 527
 528 print "";
 529 print "  if (targetm.target_option.print)";
 530 print "    targetm.target_option.print (file, indent, ptr);";
 531
 532 print "}";
 533 print "#endif";
 534
 535 }